[MIRROR] Refactors plane masters a bit and introduces plane master controllers (#3228)

* Refactors plane masters a bit and introduces plane master controllers (#56717)

* plane master controllers

* small adjustments

* bro its a comment CHILL OUT

* powerful

* Refactors plane masters a bit and introduces plane master controllers

Co-authored-by: Qustinnus <Floydje123@hotmail.com>

code/__DEFINES/layers.dm

@@ -155,3 +155,6 @@
 #define SPLASHSCREEN_LAYER 54
 #define SPLASHSCREEN_PLANE 54
 #define SPLASHSCREEN_RENDER_TARGET "SPLASHSCREEN_PLANE"
+
+///Plane master controller keys
+#define PLANE_MASTERS_GAME "plane_masters_game"

code/_onclick/hud/hud.dm

@@ -51,6 +51,9 @@ GLOBAL_LIST_INIT(available_ui_styles, list(
 	var/list/inv_slots[SLOTS_AMT] // /atom/movable/screen/inventory objects, ordered by their slot ID.
 	var/list/hand_slots // /atom/movable/screen/inventory/hand objects, assoc list of "[held_index]" = object
 	var/list/atom/movable/screen/plane_master/plane_masters = list() // see "appearance_flags" in the ref, assoc list of "[plane]" = object
+	///Assoc list of controller groups, associated with key string group name with value of the plane master controller ref
+	var/list/atom/movable/plane_master_controller/plane_master_controllers = list()
+
 
 	var/atom/movable/screen/movable/action_button/hide_toggle/hide_actions_toggle
 	var/action_buttons_hidden = FALSE
@@ -82,6 +85,10 @@ GLOBAL_LIST_INIT(available_ui_styles, list(
 		plane_masters["[instance.plane]"] = instance
 		instance.backdrop(mymob)
 
+	for(var/mytype in subtypesof(/atom/movable/plane_master_controller))
+		var/atom/movable/plane_master_controller/controller_instance = new mytype(src)
+		plane_master_controllers[controller_instance.name] = controller_instance
+
 	owner.overlay_fullscreen("see_through_darkness", /atom/movable/screen/fullscreen/see_through_darkness)
 
 /datum/hud/Destroy()
@@ -115,6 +122,7 @@ GLOBAL_LIST_INIT(available_ui_styles, list(
 	combo_display = null
 
 	QDEL_LIST_ASSOC_VAL(plane_masters)
+	QDEL_LIST_ASSOC_VAL(plane_master_controllers)
 	QDEL_LIST(screenoverlays)
 	mymob = null
 

code/_onclick/hud/plane_master.dm

@@ -37,10 +37,6 @@
 	appearance_flags = PLANE_MASTER
 	blend_mode = BLEND_OVERLAY
 
-/atom/movable/screen/plane_master/floor/backdrop(mob/mymob)
-	clear_filters()
-	if(istype(mymob) && mymob.eye_blurry)
-		add_filter("eye_blur", 1, gauss_blur_filter(clamp(mymob.eye_blurry * 0.1, 0.6, 3)))
 
 ///Contains most things in the game world
 /atom/movable/screen/plane_master/game_world
@@ -50,12 +46,8 @@
 	blend_mode = BLEND_OVERLAY
 
 /atom/movable/screen/plane_master/game_world/backdrop(mob/mymob)
-	clear_filters()
 	if(istype(mymob) && mymob.client && mymob.client.prefs && mymob.client.prefs.ambientocclusion)
 		add_filter("AO", 1, drop_shadow_filter(x = 0, y = -2, size = 4, color = "#04080FAA"))
-	if(istype(mymob) && mymob.eye_blurry)
-		add_filter("eye_blur", 1, gauss_blur_filter(clamp(mymob.eye_blurry * 0.1, 0.6, 3)))
-
 
 ///Contains all lighting objects
 /atom/movable/screen/plane_master/lighting

code/_onclick/hud/plane_master_controller.dm

@@ -0,0 +1,79 @@
+///Atom that manages and controls multiple planes. It's an atom so we can hook into add_filter etc. Multiple controllers can control one plane.
+/atom/movable/plane_master_controller
+	///List of planes in this controllers control. Initially this is a normal list, but becomes an assoc list of plane numbers as strings | plane instance
+	var/list/controlled_planes = list()
+	///hud that owns this controller
+	var/datum/hud/owner_hud
+
+///Ensures that all the planes are correctly in the controlled_planes list.
+/atom/movable/plane_master_controller/New(hud)
+	. = ..()
+	owner_hud = hud
+	var/assoc_controlled_planes = list()
+	for(var/i in controlled_planes)
+		var/atom/movable/screen/plane_master/instance = owner_hud.plane_masters["[i]"]
+		assoc_controlled_planes["[i]"] = instance
+	controlled_planes = assoc_controlled_planes
+
+///Full override so we can just use filterrific
+/atom/movable/plane_master_controller/add_filter(name, priority, list/params)
+	. = ..()
+	for(var/i in controlled_planes)
+		var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
+		pm_iterator.add_filter(name, priority, params)
+
+///Full override so we can just use filterrific
+/atom/movable/plane_master_controller/remove_filter(name_or_names)
+	. = ..()
+	for(var/i in controlled_planes)
+		var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
+		pm_iterator.remove_filter(name_or_names)
+
+/atom/movable/plane_master_controller/update_filters()
+	. = ..()
+	for(var/i in controlled_planes)
+		var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
+		pm_iterator.update_filters()
+
+///Gets all filters for this controllers plane masters
+/atom/movable/plane_master_controller/proc/get_filters(name)
+	. = list()
+	for(var/i in controlled_planes)
+		var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
+		. += pm_iterator.get_filter(name)
+
+///Transitions all filters owned by this plane master controller
+/atom/movable/plane_master_controller/transition_filter(name, time, list/new_params, easing, loop)
+	. = ..()
+	for(var/i in controlled_planes)
+		var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
+		pm_iterator.transition_filter(name, time, new_params, easing, loop)
+
+///Full override so we can just use filterrific
+/atom/movable/plane_master_controller/add_atom_colour(coloration, colour_priority)
+	. = ..()
+	for(var/i in controlled_planes)
+		var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
+		pm_iterator.add_atom_colour(coloration, colour_priority)
+
+
+///Removes an instance of colour_type from the atom's atom_colours list
+/atom/movable/plane_master_controller/remove_atom_colour(colour_priority, coloration)
+	. = ..()
+	for(var/i in controlled_planes)
+		var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
+		pm_iterator.remove_atom_colour(colour_priority, coloration)
+
+
+///Resets the atom's color to null, and then sets it to the highest priority colour available
+/atom/movable/plane_master_controller/update_atom_colour()
+	for(var/i in controlled_planes)
+		var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
+		pm_iterator.update_atom_colour()
+
+
+/atom/movable/plane_master_controller/game
+	name = PLANE_MASTERS_GAME
+	controlled_planes = list(FLOOR_PLANE, GAME_PLANE, LIGHTING_PLANE, EMISSIVE_PLANE, EMISSIVE_UNBLOCKABLE_PLANE)
+
+

code/modules/mob/status_procs.dm

@@ -94,10 +94,11 @@
 /mob/proc/update_eye_blur()
 	if(!client)
 		return
-	var/atom/movable/screen/plane_master/floor/OT = locate(/atom/movable/screen/plane_master/floor) in client.screen
-	var/atom/movable/screen/plane_master/game_world/GW = locate(/atom/movable/screen/plane_master/game_world) in client.screen
-	GW.backdrop(src)
-	OT.backdrop(src)
+	var/atom/movable/plane_master_controller/game_plane_master_controller = hud_used.plane_master_controllers[PLANE_MASTERS_GAME]
+	if(eye_blurry)
+		game_plane_master_controller.add_filter("eye_blur", 1, gauss_blur_filter(clamp(eye_blurry * 0.1, 0.6, 3)))
+	else
+		game_plane_master_controller.remove_filter("eye_blur")
 
 ///Adjust the drugginess of a mob
 /mob/proc/adjust_drugginess(amount)

code/modules/reagents/chemistry/reagents/toxin_reagents.dm

@@ -808,18 +808,19 @@
 /datum/reagent/toxin/rotatium/on_mob_life(mob/living/carbon/M)
 	if(M.hud_used)
 		if(current_cycle >= 20 && current_cycle%20 == 0)
-			var/list/screens = list(M.hud_used.plane_masters["[FLOOR_PLANE]"], M.hud_used.plane_masters["[GAME_PLANE]"], M.hud_used.plane_masters["[LIGHTING_PLANE]"])
+			var/atom/movable/plane_master_controller/pm_controller = M.hud_used.plane_master_controllers[PLANE_MASTERS_GAME]
+
 			var/rotation = min(round(current_cycle/20), 89) // By this point the player is probably puking and quitting anyway
-			for(var/whole_screen in screens)
-				animate(whole_screen, transform = matrix(rotation, MATRIX_ROTATE), time = 5, easing = QUAD_EASING, loop = -1)
+			for(var/key in pm_controller.controlled_planes)
+				animate(pm_controller.controlled_planes[key], transform = matrix(rotation, MATRIX_ROTATE), time = 5, easing = QUAD_EASING, loop = -1)
 				animate(transform = matrix(-rotation, MATRIX_ROTATE), time = 5, easing = QUAD_EASING)
 	return ..()
 
 /datum/reagent/toxin/rotatium/on_mob_end_metabolize(mob/living/M)
 	if(M?.hud_used)
-		var/list/screens = list(M.hud_used.plane_masters["[FLOOR_PLANE]"], M.hud_used.plane_masters["[GAME_PLANE]"], M.hud_used.plane_masters["[LIGHTING_PLANE]"])
-		for(var/whole_screen in screens)
-			animate(whole_screen, transform = matrix(), time = 5, easing = QUAD_EASING)
+		var/atom/movable/plane_master_controller/pm_controller = M.hud_used.plane_master_controllers[PLANE_MASTERS_GAME]
+		for(var/key in pm_controller.controlled_planes)
+			animate(pm_controller.controlled_planes[key], transform = matrix(), time = 5, easing = QUAD_EASING)
 	..()
 
 /datum/reagent/toxin/anacea

tgstation.dme

@@ -277,6 +277,7 @@
 #include "code\_onclick\hud\parallax.dm"
 #include "code\_onclick\hud\picture_in_picture.dm"
 #include "code\_onclick\hud\plane_master.dm"
+#include "code\_onclick\hud\plane_master_controller.dm"
 #include "code\_onclick\hud\radial.dm"
 #include "code\_onclick\hud\radial_persistent.dm"
 #include "code\_onclick\hud\revenanthud.dm"