[READY] Ammunition management for ballistic mech weapons, and a nerf to mech missiles (#44529)

About The Pull Request Adds an ammo system and printable ammunition to most mech weapons with a "rearm" function. Replaces the old system of generating ammo at a power cost. With the exception of the missile launcher and clusterbang launcher, all affected weapons have a storage capacity of ammunition equal to four-times the amount of ammo that the weapon can load (though the storage cache starts with only one full reload when printed from the mechfab). Ammo boxes are printed from the mechfab and also are available in the Sec protolathe, and each box will carry exactly one full reload. Ammo boxes are not terribly expensive, but reloading requires either an ally on foot to pop the ammo box in, or for you to hop out and do it yourself. Missile tubes and the clusterbang launcher do not have an ammo storage cache, and so reloading them will reload the tubes directly. This is not the full extent of nerfs that the missiles need (I will do those in a separate PR since I suspect this one will be controversial) (read below), but removing the ability to reload missile pods without an ally or exiting the mech may help a bit. The SRM-8 has been replaced with the new BRM-6 in tech webs. The BRM carries a smaller explosion and does not explode unless hitting a wall, door, shutter, or another mech, and only has six shots. The SRM-8 remains on the Mauler mech. If the BRM missile does not explode, it will deal 30 brute damage instead, and break. Why It's Good For The Game Currently, mech ballistic weapons function like reloadable lasers. You have an ammo counter, but it's one hundred percent based on your energy cell. This gives some flavor to ballistic weapons, making them actually feel different, and gives them a mini-niche in the form of good choices to use alongside an energy-draining mech ability (like the Gygax speed). Use lasers when you won't need to worry about power and/or need burn damage. Use ballistics when you want to save power and/or need brute damage. The SRM-8 to BRM-6 change is being done here so that I don't have to wait until this PR is merged before starting it. The idea is to keep the reasons why you'd want to build a missile launcher (wall breaking and mech fighting) without also outclassing most other weapons burst damage potential. I'm not truly happy that the explosions deal zero damage to surrounding people even one tile away, but dealing no damage is better than the massive damage + stun that the current missile launcher does. Nuke Mauler has the old launcher, since I believe the consensus is that Nukie Mechs are already not generally worth the money. Changelog cl balance: Mecha ballistics weapons now require ammo created from an Exosuit Fabricator or the Security Protolathe, though they will start with a full magazine and in most cases enough for one full reload. Reloading these weapons no longer chunks your power cell. Clown (and mime) mecha equipment have not changed. balance: The SRM-8 Missile Launcher has been replaced with the BRM-6 Breaching Missile Launcher in techwebs (Nukie Mauler remains equipped with the SRM-8). balance: Both Missile Launchers and the Clusterbang Launcher do not have an ammo cache, and cannot be reloaded by the pilot. Once the initial loaded ammo has been spent, you can use the appropriate ammo box to load the weapon directly. add: Utility mechs that have a clamp equipped can load ammo from their own cargo hold into other mechs. add: Nuke Ops can purchase spare ammo duffel bags for their mecha weapons, should they run low. /cl To-Do: Add ammo to security protolathe Get better ammo box sprites (hopefully) Possibly adjust ammo counts for balance. Might make the flashbang launcher and/or cluster launcher behave like the missile pod. Add functionality for the utility mechs to use clamps to load ammo from their cargo hold into another mech. Ammo counts, for anyone wondering: Weapon Magazine Size Total ammo at start* Maximum total ammo* Scattershot† 40 (10) 80 (20) 200 (50) Hades 24 48 120 Ultra AC 2† 300 (100) 600 (200) 1500 (500) BRM-6 Missile Rack 6 6 6 SRM-8 Missile Rack 8 8 8 Flashbang Launcher 6 12 30 Cluster Launcher 3 3 3 *Total ammo is the amount in the weapon's magazine plus the stored ammo. †The Scattershot lists its ammo as 40, but uses four per shot. So in reality, a single full reload gives you ten shots. Similarly, the UAC2 fires in three-round bursts, and so 300 rounds is 100 bursts. Clown weapons (and the mime weapon) are all unaffected by this change.
2026-08-27 15:17:01 +01:00 · 2019-06-27 20:03:31 +12:00
parent 1ef9a34fc7
commit f01e2704e1
18 changed files with 380 additions and 27 deletions
@@ -5,4 +5,10 @@
 	armor = list("melee" = 30, "bullet" = 30, "laser" = 15, "energy" = 20, "bomb" = 20, "bio" = 0, "rad" = 0, "fire" = 100, "acid" = 100)
 	mouse_pointer = 'icons/mecha/mecha_mouse.dmi'
 	destruction_sleep_duration = 40
-	exit_delay = 40
+	exit_delay = 40
+
+/obj/mecha/combat/proc/max_ammo() //Max the ammo stored for Nuke Ops mechs, or anyone else that calls this
+	for(var/obj/item/I in equipment)
+		if(istype(I, /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/))
+			var/obj/item/mecha_parts/mecha_equipment/weapon/ballistic/gun = I
+			gun.projectiles_cache = gun.projectiles_cache_max
@@ -39,6 +39,7 @@
 	ME.attach(src)
 	ME = new /obj/item/mecha_parts/mecha_equipment/tesla_energy_relay
 	ME.attach(src)
+	max_ammo()

 /obj/mecha/combat/gygax/dark/add_cell(obj/item/stock_parts/cell/C=null)
 	if(C)
@@ -40,6 +40,7 @@
 	ME.attach(src)
 	ME = new /obj/item/mecha_parts/mecha_equipment/antiproj_armor_booster(src)
 	ME.attach(src)
+	max_ammo()

 /obj/mecha/combat/marauder/seraph
 	desc = "Heavy-duty, command-type exosuit. This is a custom model, utilized only by high-ranking military personnel."
@@ -66,6 +67,7 @@
 	ME.attach(src)
 	ME = new /obj/item/mecha_parts/mecha_equipment/antiproj_armor_booster(src)
 	ME.attach(src)
+	max_ammo()

 /obj/mecha/combat/marauder/mauler
 	desc = "Heavy-duty, combat exosuit, developed off of the existing Marauder model."
@@ -89,5 +91,6 @@
 	ME.attach(src)
 	ME = new /obj/item/mecha_parts/mecha_equipment/antiproj_armor_booster(src)
 	ME.attach(src)
+	max_ammo()


@@ -32,6 +32,19 @@
 		return
 	if(!cargo_holder)
 		return
+	if(ismecha(target))
+		var/obj/mecha/M = target
+		var/have_ammo
+		for(var/obj/item/mecha_ammo/box in cargo_holder.cargo)
+			if(istype(box, /obj/item/mecha_ammo) && box.rounds)
+				have_ammo = TRUE
+				if(M.ammo_resupply(box, chassis.occupant, TRUE))
+					return
+		if(have_ammo)
+			to_chat(chassis.occupant, "No further supplies can be provided to [M].")
+		else
+			to_chat(chassis.occupant, "No providable supplies found in cargo hold")
+		return
 	if(isobj(target))
 		var/obj/O = target
 		if(istype(O, /obj/machinery/door/firedoor))
@@ -0,0 +1,94 @@
+/obj/item/mecha_ammo
+	name = "generic ammo box"
+	desc = "A box of ammo for an unknown weapon."
+	w_class = WEIGHT_CLASS_BULKY
+	icon = 'icons/mecha/mecha_ammo.dmi'
+	icon_state = "empty"
+	lefthand_file = 'icons/mob/inhands/equipment/medical_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/equipment/medical_righthand.dmi'
+	var/rounds = 0
+	var/round_term = "round"
+	var/direct_load //For weapons where we re-load the weapon itself rather than adding to the ammo storage.
+	var/load_audio = "sound/weapons/gun_magazine_insert_empty_1.ogg"
+	var/ammo_type
+
+/obj/item/mecha_ammo/proc/update_name()
+	if(!rounds)
+		name = "empty ammo box"
+		desc = "An exosuit ammuniton box that has since been emptied. Please recycle."
+		icon_state = "empty"
+
+/obj/item/mecha_ammo/attack_self(mob/user)
+	..()
+	if(rounds)
+		to_chat(user, "<span class='warning'>You cannot flatten the ammo box until it's empty!</span>")
+		return
+
+	to_chat(user, "<span class='notice'>You fold [src] flat.</span>")
+	var/I = new /obj/item/stack/sheet/metal(user.loc)
+	qdel(src)
+	user.put_in_hands(I)
+
+/obj/item/mecha_ammo/examine(mob/user)
+	. = ..()
+	if(rounds)
+		. += "There [rounds > 1?"are":"is"] [rounds] [round_term][rounds > 1?"s":""] left."
+
+/obj/item/mecha_ammo/incendiary
+	name = "incendiary ammo"
+	desc = "A box of incendiary ammunition for use with exosuit weapons."
+	icon_state = "incendiary"
+	rounds = 24
+	ammo_type = "incendiary"
+
+/obj/item/mecha_ammo/scattershot
+	name = "scattershot ammo"
+	desc = "A box of scaled-up buckshot, for use in exosuit shotguns."
+	icon_state = "scattershot"
+	rounds = 40
+	ammo_type = "scattershot"
+
+/obj/item/mecha_ammo/lmg
+	name = "machine gun ammo"
+	desc = "A box of linked ammunition, designed for the Ultra AC 2 exosuit weapon."
+	icon_state = "lmg"
+	rounds = 300
+	ammo_type = "lmg"
+
+/obj/item/mecha_ammo/missiles_br
+	name = "breaching missiles"
+	desc = "A box of large missiles, ready for loading into a BRM-6 exosuit missile rack."
+	icon_state = "missile_br"
+	rounds = 6
+	round_term = "missile"
+	direct_load = TRUE
+	load_audio = "sound/weapons/bulletinsert.ogg"
+	ammo_type = "missiles_br"
+
+/obj/item/mecha_ammo/missiles_he
+	name = "anti-armor missiles"
+	desc = "A box of large missiles, ready for loading into an SRM-8 exosuit missile rack."
+	icon_state = "missile_he"
+	rounds = 8
+	round_term = "missile"
+	direct_load = TRUE
+	load_audio = "sound/weapons/bulletinsert.ogg"
+	ammo_type = "missiles_he"
+
+
+/obj/item/mecha_ammo/flashbang
+	name = "launchable flashbangs"
+	desc = "A box of smooth flashbangs, for use with a large exosuit launcher. Cannot be primed by hand."
+	icon_state = "flashbang"
+	rounds = 6
+	round_term = "grenade"
+	ammo_type = "flashbang"
+
+/obj/item/mecha_ammo/clusterbang
+	name = "launchable flashbang clusters"
+	desc = "A box of clustered flashbangs, for use with a specialized exosuit cluster launcher. Cannot be primed by hand."
+	icon_state = "clusterbang"
+	rounds = 3
+	round_term = "cluster"
+	direct_load = TRUE
+	ammo_type = "clusterbang"
@@ -211,7 +211,11 @@
 	name = "general ballistic weapon"
 	fire_sound = 'sound/weapons/gunshot.ogg'
 	var/projectiles
+	var/projectiles_cache //ammo to be loaded in, if possible.
+	var/projectiles_cache_max
 	var/projectile_energy_cost
+	var/disabledreload //For weapons with no cache (like the rockets) which are reloaded by hand
+	var/ammo_type

 /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/get_shot_amount()
 	return min(projectiles, projectiles_per_shot)
@@ -224,19 +228,32 @@
 	return 1

 /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/get_equip_info()
-	return "[..()] \[[src.projectiles]\][(src.projectiles < initial(src.projectiles))?" - <a href='?src=[REF(src)];rearm=1'>Rearm</a>":null]"
+	return "[..()] \[[src.projectiles][projectiles_cache_max &&!projectile_energy_cost?"/[projectiles_cache]":""]\][!disabledreload &&(src.projectiles < initial(src.projectiles))?" - <a href='?src=[REF(src)];rearm=1'>Rearm</a>":null]"


 /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/rearm()
 	if(projectiles < initial(projectiles))
 		var/projectiles_to_add = initial(projectiles) - projectiles
-		while(chassis.get_charge() >= projectile_energy_cost && projectiles_to_add)
-			projectiles++
-			projectiles_to_add--
-			chassis.use_power(projectile_energy_cost)
-	send_byjax(chassis.occupant,"exosuit.browser","[REF(src)]",src.get_equip_info())
-	log_message("Rearmed [src.name].", LOG_MECHA)
-	return 1
+
+		if(projectile_energy_cost)
+			while(chassis.get_charge() >= projectile_energy_cost && projectiles_to_add)
+				projectiles++
+				projectiles_to_add--
+				chassis.use_power(projectile_energy_cost)
+
+		else
+			if(!projectiles_cache)
+				return FALSE
+			if(projectiles_to_add <= projectiles_cache)
+				projectiles = projectiles + projectiles_to_add
+				projectiles_cache = projectiles_cache - projectiles_to_add
+			else
+				projectiles = projectiles + projectiles_cache
+				projectiles_cache = 0
+
+		send_byjax(chassis.occupant,"exosuit.browser","[REF(src)]",src.get_equip_info())
+		log_message("Rearmed [src.name].", LOG_MECHA)
+		return TRUE


 /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/needs_rearm()
@@ -264,8 +281,10 @@
 	equip_cooldown = 10
 	projectile = /obj/item/projectile/bullet/incendiary/fnx99
 	projectiles = 24
-	projectile_energy_cost = 15
+	projectiles_cache = 24
+	projectiles_cache_max = 96
 	harmful = TRUE
+	ammo_type = "incendiary"

 /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/silenced
 	name = "\improper S.H.H. \"Quietus\" Carbine"
@@ -285,10 +304,12 @@
 	equip_cooldown = 20
 	projectile = /obj/item/projectile/bullet/scattershot
 	projectiles = 40
-	projectile_energy_cost = 25
+	projectiles_cache = 40
+	projectiles_cache_max = 160
 	projectiles_per_shot = 4
 	variance = 25
 	harmful = TRUE
+	ammo_type = "scattershot"

 /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/lmg
 	name = "\improper Ultra AC 2"
@@ -297,23 +318,42 @@
 	equip_cooldown = 10
 	projectile = /obj/item/projectile/bullet/lmg
 	projectiles = 300
-	projectile_energy_cost = 20
+	projectiles_cache = 300
+	projectiles_cache_max = 1200
 	projectiles_per_shot = 3
 	variance = 6
 	randomspread = 1
 	projectile_delay = 2
 	harmful = TRUE
+	ammo_type = "lmg"

 /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/missile_rack
 	name = "\improper SRM-8 missile rack"
-	desc = "A weapon for combat exosuits. Shoots light explosive missiles."
+	desc = "A weapon for combat exosuits. Launches light explosive missiles."
 	icon_state = "mecha_missilerack"
 	projectile = /obj/item/projectile/bullet/a84mm_he
 	fire_sound = 'sound/weapons/grenadelaunch.ogg'
 	projectiles = 8
-	projectile_energy_cost = 1000
+	projectiles_cache = 0
+	projectiles_cache_max = 0
+	disabledreload = TRUE
 	equip_cooldown = 60
 	harmful = TRUE
+	ammo_type = "missiles_he"
+
+/obj/item/mecha_parts/mecha_equipment/weapon/ballistic/missile_rack/breaching
+	name = "\improper BRM-6 missile rack"
+	desc = "A weapon for combat exosuits. Launches low-explosive breaching missiles designed to explode only when striking a sturdy target."
+	icon_state = "mecha_missilerack_six"
+	projectile = /obj/item/projectile/bullet/a84mm_br
+	fire_sound = 'sound/weapons/grenadelaunch.ogg'
+	projectiles = 6
+	projectiles_cache = 0
+	projectiles_cache_max = 0
+	disabledreload = TRUE
+	equip_cooldown = 60
+	harmful = TRUE
+	ammo_type = "missiles_br"


 /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/launcher
@@ -344,10 +384,12 @@
 	projectile = /obj/item/grenade/flashbang
 	fire_sound = 'sound/weapons/grenadelaunch.ogg'
 	projectiles = 6
+	projectiles_cache = 6
+	projectiles_cache_max = 24
 	missile_speed = 1.5
-	projectile_energy_cost = 800
 	equip_cooldown = 60
 	var/det_time = 20
+	ammo_type = "flashbang"

 /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/launcher/flashbang/proj_init(var/obj/item/grenade/flashbang/F)
 	var/turf/T = get_turf(src)
@@ -359,9 +401,12 @@
 	name = "\improper SOB-3 grenade launcher"
 	desc = "A weapon for combat exosuits. Launches primed clusterbangs. You monster."
 	projectiles = 3
+	projectiles_cache = 0
+	projectiles_cache_max = 0
+	disabledreload = TRUE
 	projectile = /obj/item/grenade/clusterbuster
-	projectile_energy_cost = 1600 //getting off cheap seeing as this is 3 times the flashbangs held in the grenade launcher.
 	equip_cooldown = 90
+	ammo_type = "clusterbang"

 /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/launcher/banana_mortar
 	name = "banana mortar"
@@ -29,6 +29,7 @@
 								"H.O.N.K",
 								"Phazon",
 								"Exosuit Equipment",
+								"Exosuit Ammunition",
 								"Cyborg Upgrade Modules",
 								"Misc"
 								)
@@ -1115,3 +1115,53 @@ GLOBAL_VAR_INIT(year_integer, text2num(year)) // = 2013???
 	if(occupant_sight_flags)
 		if(user == occupant)
 			user.sight |= occupant_sight_flags
+
+///////////////////////
+////// Ammo stuff /////
+///////////////////////
+
+/obj/mecha/proc/ammo_resupply(var/obj/item/mecha_ammo/A, mob/user,var/fail_chat_override = FALSE)
+	if(!A.rounds)
+		if(!fail_chat_override)
+			to_chat(user, "<span class='warning'>This box of ammo is empty!</span>")
+		return FALSE
+	var/ammo_needed
+	var/found_gun
+	for(var/obj/item/mecha_parts/mecha_equipment/weapon/ballistic/gun in equipment)
+		ammo_needed = 0
+
+		if(istype(gun, /obj/item/mecha_parts/mecha_equipment/weapon/ballistic) && gun.ammo_type == A.ammo_type)
+			found_gun = TRUE
+			if(A.direct_load)
+				ammo_needed = initial(gun.projectiles) - gun.projectiles
+			else
+				ammo_needed = gun.projectiles_cache_max - gun.projectiles_cache
+
+			if(ammo_needed)
+				if(ammo_needed < A.rounds)
+					if(A.direct_load)
+						gun.projectiles = gun.projectiles + ammo_needed
+					else
+						gun.projectiles_cache = gun.projectiles_cache + ammo_needed
+					playsound(get_turf(user),A.load_audio,50,1)
+					to_chat(user, "<span class='notice'>You add [ammo_needed] [A.round_term][ammo_needed > 1?"s":""] to the [gun.name]</span>")
+					A.rounds = A.rounds - ammo_needed
+					A.update_name()
+					return TRUE
+
+				else
+					if(A.direct_load)
+						gun.projectiles = gun.projectiles + A.rounds
+					else
+						gun.projectiles_cache = gun.projectiles_cache + A.rounds
+					playsound(get_turf(user),A.load_audio,50,1)
+					to_chat(user, "<span class='notice'>You add [A.rounds] [A.round_term][A.rounds > 1?"s":""] to the [gun.name]</span>")
+					A.rounds = 0
+					A.update_name()
+					return TRUE
+	if(!fail_chat_override)
+		if(found_gun)
+			to_chat(user, "<span class='notice'>You can't fit any more ammo of this type!</span>")
+		else
+			to_chat(user, "<span class='notice'>None of the equipment on this exosuit can use this ammo!</span>")
+	return FALSE
@@ -174,6 +174,10 @@
 			to_chat(user, "[src]-[W] interface initialization failed.")
 		return

+	if(istype(W, /obj/item/mecha_ammo))
+		ammo_resupply(W, user)
+		return
+
 	if(W.GetID())
 		if(add_req_access || maint_access)
 			if(internals_access_allowed(user))
@@ -497,6 +497,31 @@
 	for(var/i in 1 to 9)
 		new /obj/item/ammo_box/magazine/smgm45(src)

+/obj/item/storage/backpack/duffelbag/syndie/ammo/dark_gygax
+	desc = "A large duffel bag, packed to the brim with various exosuit ammo."
+
+/obj/item/storage/backpack/duffelbag/syndie/ammo/dark_gygax/PopulateContents()
+	new /obj/item/mecha_ammo/incendiary(src)
+	new /obj/item/mecha_ammo/incendiary(src)
+	new /obj/item/mecha_ammo/incendiary(src)
+	new /obj/item/mecha_ammo/flashbang(src)
+	new /obj/item/mecha_ammo/flashbang(src)
+	new /obj/item/mecha_ammo/flashbang(src)
+
+/obj/item/storage/backpack/duffelbag/syndie/ammo/mauler
+	desc = "A large duffel bag, packed to the brim with various exosuit ammo."
+
+/obj/item/storage/backpack/duffelbag/syndie/ammo/mauler/PopulateContents()
+	new /obj/item/mecha_ammo/lmg(src)
+	new /obj/item/mecha_ammo/lmg(src)
+	new /obj/item/mecha_ammo/lmg(src)
+	new /obj/item/mecha_ammo/scattershot(src)
+	new /obj/item/mecha_ammo/scattershot(src)
+	new /obj/item/mecha_ammo/scattershot(src)
+	new /obj/item/mecha_ammo/missiles_he(src)
+	new /obj/item/mecha_ammo/missiles_he(src)
+	new /obj/item/mecha_ammo/missiles_he(src)
+
 /obj/item/storage/backpack/duffelbag/syndie/c20rbundle
 	desc = "A large duffel bag containing a C-20r, some magazines, and a cheap looking suppressor."

@@ -30,7 +30,7 @@
 	return BULLET_ACT_HIT

 /obj/item/projectile/bullet/a84mm_he
-	name ="\improper HE rocket"
+	name ="\improper HE missile"
 	desc = "Boom."
 	icon_state = "missile"
 	damage = 30
@@ -43,3 +43,33 @@
 	else
 		explosion(target, 0, 0, 2, 4)
 	return BULLET_ACT_HIT
+
+/obj/item/projectile/bullet/a84mm_br
+	name ="\improper HE missile"
+	desc = "Boom."
+	icon_state = "missile"
+	damage = 30
+	ricochets_max = 0 //it's a MISSILE
+	var/sturdy = list(
+	/turf/closed,
+	/obj/mecha,
+	/obj/machinery/door/,
+	/obj/machinery/door/poddoor/shutters
+	)
+
+/obj/item/broken_missile
+	name = "\improper broken missile"
+	desc = "A missile that did not detonate. The tail has snapped and it is in no way fit to be used again."
+	icon = 'icons/obj/projectiles.dmi'
+	icon_state = "missile_broken"
+	w_class = WEIGHT_CLASS_TINY
+
+
+/obj/item/projectile/bullet/a84mm_br/on_hit(atom/target, blocked=0)
+	..()
+	for(var/i in sturdy)
+		if(istype(target, i))
+			explosion(target, 0, 1, 1, 2)
+			return BULLET_ACT_HIT
+	//if(istype(target, /turf/closed) || ismecha(target))
+	new /obj/item/broken_missile(get_turf(src), 1)
@@ -147,6 +147,17 @@
 	construction_time = 100
 	category = list("Exosuit Equipment")

+/datum/design/mech_scattershot_ammo
+	name = "LBX AC 10 Scattershot Ammunition"
+	desc = "Ammunition for the LBX AC 10 exosuit weapon."
+	id = "mech_scattershot_ammo"
+	build_type = PROTOLATHE | MECHFAB
+	build_path = /obj/item/mecha_ammo/scattershot
+	materials = list(MAT_METAL=6000)
+	construction_time = 20
+	category = list("Exosuit Ammunition", "Ammo")
+	departmental_flags = DEPARTMENTAL_FLAG_SECURITY
+
 /datum/design/mech_carbine
 	name = "Exosuit Weapon (FNX-99 \"Hades\" Carbine)"
 	desc = "Allows for the construction of FNX-99 \"Hades\" Carbine."
@@ -157,6 +168,17 @@
 	construction_time = 100
 	category = list("Exosuit Equipment")

+/datum/design/mech_carbine_ammo
+	name = "FNX-99 Carbine Ammunition"
+	desc = "Ammunition for the FNX-99 \"Hades\" Carbine."
+	id = "mech_carbine_ammo"
+	build_type = PROTOLATHE | MECHFAB
+	build_path = /obj/item/mecha_ammo/incendiary
+	materials = list(MAT_METAL=6000)
+	construction_time = 20
+	category = list("Exosuit Ammunition", "Ammo")
+	departmental_flags = DEPARTMENTAL_FLAG_SECURITY
+
 /datum/design/mech_ion
 	name = "Exosuit Weapon (MKIV Ion Heavy Cannon)"
 	desc = "Allows for the construction of MKIV Ion Heavy Cannon."
@@ -217,16 +239,38 @@
 	construction_time = 100
 	category = list("Exosuit Equipment")

+/datum/design/mech_grenade_launcher_ammo
+	name = "SGL-6 Grenade Launcher Ammunition"
+	desc = "Ammunition for the SGL-6 Grenade Launcher."
+	id = "mech_grenade_launcher_ammo"
+	build_type = PROTOLATHE | MECHFAB
+	build_path = /obj/item/mecha_ammo/flashbang
+	materials = list(MAT_METAL=4000,MAT_GOLD=500,MAT_SILVER=500)
+	construction_time = 20
+	category = list("Exosuit Ammunition", "Ammo")
+	departmental_flags = DEPARTMENTAL_FLAG_SECURITY
+
 /datum/design/mech_missile_rack
-	name = "Exosuit Weapon (SRM-8 Missile Rack)"
-	desc = "Allows for the construction of an SRM-8 Missile Rack."
+	name = "Exosuit Weapon (BRM-6 Missile Rack)"
+	desc = "Allows for the construction of an BRM-6 Breaching Missile Rack."
 	id = "mech_missile_rack"
 	build_type = MECHFAB
-	build_path = /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/missile_rack
+	build_path = /obj/item/mecha_parts/mecha_equipment/weapon/ballistic/missile_rack/breaching
 	materials = list(MAT_METAL=22000,MAT_GOLD=6000,MAT_SILVER=8000)
 	construction_time = 100
 	category = list("Exosuit Equipment")

+/datum/design/mech_missile_rack_ammo
+	name = "SRM-8 Missile Rack Ammunition"
+	desc = "Ammunition for the SRM-8 Missile Rack."
+	id = "mech_missile_rack_ammo"
+	build_type = PROTOLATHE | MECHFAB
+	build_path = /obj/item/mecha_ammo/missiles_br
+	materials = list(MAT_METAL=8000,MAT_GOLD=500,MAT_SILVER=500)
+	construction_time = 20
+	category = list("Exosuit Ammunition", "Ammo")
+	departmental_flags = DEPARTMENTAL_FLAG_SECURITY
+
 /datum/design/clusterbang_launcher
 	name = "Exosuit Module (SOB-3 Clusterbang Launcher)"
 	desc = "A weapon that violates the Geneva Convention at 3 rounds per minute"
@@ -237,6 +281,17 @@
 	construction_time = 100
 	category = list("Exosuit Equipment")

+/datum/design/clusterbang_launcher_ammo
+	name = "SOB-3 Clusterbang Launcher Ammunition"
+	desc = "Ammunition for the SOB-3 Clusterbang Launcher"
+	id = "clusterbang_launcher_ammo"
+	build_type = PROTOLATHE | MECHFAB
+	build_path = /obj/item/mecha_ammo/clusterbang
+	materials = list(MAT_METAL=6000,MAT_GOLD=1500,MAT_URANIUM=1500)
+	construction_time = 20
+	category = list("Exosuit Ammunition", "Ammo")
+	departmental_flags = DEPARTMENTAL_FLAG_SECURITY
+
 /datum/design/mech_wormhole_gen
 	name = "Exosuit Module (Localized Wormhole Generator)"
 	desc = "An exosuit module that allows generating of small quasi-stable wormholes."
@@ -357,6 +412,17 @@
 	construction_time = 100
 	category = list("Exosuit Equipment")

+/datum/design/mech_lmg_ammo
+	name = "Ultra AC 2 Ammunition"
+	desc = "Ammunition for the Ultra AC 2 LMG"
+	id = "mech_lmg_ammo"
+	build_type = PROTOLATHE | MECHFAB
+	build_path = /obj/item/mecha_ammo/lmg
+	materials = list(MAT_METAL=4000)
+	construction_time = 20
+	category = list("Exosuit Ammunition", "Ammo")
+	departmental_flags = DEPARTMENTAL_FLAG_SECURITY
+
 /datum/design/mech_sleeper
 	name = "Exosuit Medical Equipment (Mounted Sleeper)"
 	desc = "Equipment for medical exosuits. A mounted sleeper that stabilizes patients and can inject reagents in the exosuit's reserves."
@@ -759,7 +759,7 @@
 	display_name = "Exosuit Weapon (LBX AC 10 \"Scattershot\")"
 	description = "An advanced piece of mech weaponry"
 	prereq_ids = list("ballistic_weapons")
-	design_ids = list("mech_scattershot")
+	design_ids = list("mech_scattershot", "mech_scattershot_ammo")
 	research_costs = list(TECHWEB_POINT_TYPE_GENERIC = 2500)
 	export_price = 5000

@@ -768,7 +768,7 @@
 	display_name = "Exosuit Weapon (FNX-99 \"Hades\" Carbine)"
 	description = "An advanced piece of mech weaponry"
 	prereq_ids = list("ballistic_weapons")
-	design_ids = list("mech_carbine")
+	design_ids = list("mech_carbine", "mech_carbine_ammo")
 	research_costs = list(TECHWEB_POINT_TYPE_GENERIC = 2500)
 	export_price = 5000

@@ -822,16 +822,16 @@
 	display_name = "Exosuit Weapon (SGL-6 Grenade Launcher)"
 	description = "An advanced piece of mech weaponry"
 	prereq_ids = list("explosive_weapons")
-	design_ids = list("mech_grenade_launcher")
+	design_ids = list("mech_grenade_launcher", "mech_grenade_launcher_ammo")
 	research_costs = list(TECHWEB_POINT_TYPE_GENERIC = 2500)
 	export_price = 5000

 /datum/techweb_node/mech_missile_rack
 	id = "mech_missile_rack"
-	display_name = "Exosuit Weapon (SRM-8 Missile Rack)"
+	display_name = "Exosuit Weapon (BRM-6 Missile Rack)"
 	description = "An advanced piece of mech weaponry"
 	prereq_ids = list("explosive_weapons")
-	design_ids = list("mech_missile_rack")
+	design_ids = list("mech_missile_rack", "mech_missile_rack_ammo")
 	research_costs = list(TECHWEB_POINT_TYPE_GENERIC = 2500)
 	export_price = 5000

@@ -840,7 +840,7 @@
 	display_name = "Exosuit Module (SOB-3 Clusterbang Launcher)"
 	description = "An advanced piece of mech weaponry"
 	prereq_ids = list("explosive_weapons")
-	design_ids = list("clusterbang_launcher")
+	design_ids = list("clusterbang_launcher", "clusterbang_launcher_ammo")
 	research_costs = list(TECHWEB_POINT_TYPE_GENERIC = 2500)
 	export_price = 5000

@@ -867,7 +867,7 @@
 	display_name = "Exosuit Weapon (\"Ultra AC 2\" LMG)"
 	description = "An advanced piece of mech weaponry"
 	prereq_ids = list("ballistic_weapons")
-	design_ids = list("mech_lmg")
+	design_ids = list("mech_lmg", "mech_lmg_ammo")
 	research_costs = list(TECHWEB_POINT_TYPE_GENERIC = 2500)
 	export_price = 5000

@@ -839,6 +839,20 @@ GLOBAL_LIST_INIT(uplink_items, subtypesof(/datum/uplink_item))
 	cost = 1
 	include_modes = list(/datum/game_mode/nuclear)

+/datum/uplink_item/ammo/dark_gygax/bag
+	name = "Dark Gygax Ammo Bag"
+	desc = "A duffel bag containing ammo for three full reloads of the incendiary carbine and flash bang launcher that are equipped on a standard Dark Gygax exosuit."
+	item = /obj/item/storage/backpack/duffelbag/syndie/ammo/dark_gygax
+	cost = 4
+	include_modes = list(/datum/game_mode/nuclear)
+
+/datum/uplink_item/ammo/mauler/bag
+	name = "Mauler Ammo Bag"
+	desc = "A duffel bag containing ammo for three full reloads of the LMG, scattershot carbine, and SRM-8 missile laucher that are equipped on a standard Mauler exosuit."
+	item = /obj/item/storage/backpack/duffelbag/syndie/ammo/mauler
+	cost = 6
+	include_modes = list(/datum/game_mode/nuclear)
+
 //Grenades and Explosives
 /datum/uplink_item/explosives
 	category = "Grenades and Explosives"
@@ -735,6 +735,7 @@
 #include "code\game\mecha\equipment\tools\other_tools.dm"
 #include "code\game\mecha\equipment\tools\weapon_bay.dm"
 #include "code\game\mecha\equipment\tools\work_tools.dm"
+#include "code\game\mecha\equipment\weapons\mecha_ammo.dm"
 #include "code\game\mecha\equipment\weapons\weapons.dm"
 #include "code\game\mecha\medical\medical.dm"
 #include "code\game\mecha\medical\odysseus.dm"