mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-10 07:41:16 +01:00
John Willard
751bfc08bb
## About The Pull Request Removes the IC tab in its entirety - Some mobs (Blob Minion & Lightgeist) had manually removed the "pull" verb, this replaces it with taking away their pull force. - Lightgeist had their "Me" verb manually removed, this is replaced by giving them Emotemute trait (the same that mime's bane gives) - Floor Changer: You can now RMB the arrow buttons to look in a direction w/o moving. Added a tip to help with this. - Exit Hivemind: Already an action button and was removed without further edits ### Removed entirely Rest Resist Look Up/Down Move Upwards/Down Activate Held Object Open Language Menu Memories View Skills ### Moved to command bar (secret verb ooh) because I am biased Sleep Navigate ### Martial Arts Martial Arts had a button to see your current skills & the ability to cycle between artstyles. This was replaced with 1 action button that does both of these. <img width="317" height="148" alt="image" src="https://github.com/user-attachments/assets/afed910f-b6b6-441d-86cb-dade0e253044" /> Name auto-updates as you swap artstyle to whatever help verb the current style uses. Mention of RMB in the name is only there if you have more than 1 martial art, but the desc will remain just so players can see it even if they only have one, for future reference. ## Why It's Good For The Game Brings greater visibility to Martial Art stuff, and especially since the stat panel is being made optional we should not be hiding ANYTHING in there. This also helps me with my project listed in https://hackmd.io/443_dE5lRWeEAp9bjGcKYw?view And also fixes some sorta-removed features due to removing verbs not matching people's actual powers due to new features like "Custom Me" and "Ctrl Clicking". ## Changelog 🆑 SirNightKnight (sprites), JohnFulpWillard del: Deleted the "IC" tab of the stat panel. fix: Lightgeists can't emote or pull as intended. fix: Blob minions can't pull again. qol: Martial Art users now have an action button for their artstyle-related businesses, rather than it being in the stat panel. qol: You can now right-click the move up/down UI buttons to look in the direction without moving. /🆑
109 lines
3.0 KiB
Plaintext
109 lines
3.0 KiB
Plaintext
/**
|
|
* Ctrl click
|
|
*/
|
|
/mob/proc/CtrlClickOn(atom/A)
|
|
base_click_ctrl(A)
|
|
|
|
/**
|
|
* ### Base proc for ctrl click interaction left click.
|
|
*
|
|
* If you wish to add custom `click_ctrl` behavior for a single type, use that proc.
|
|
*/
|
|
/mob/proc/base_click_ctrl(atom/target)
|
|
SHOULD_NOT_OVERRIDE(TRUE)
|
|
|
|
// Check if they've hooked in to prevent src from ctrl clicking anything
|
|
if(SEND_SIGNAL(src, COMSIG_MOB_CTRL_CLICKED, target) & COMSIG_MOB_CANCEL_CLICKON)
|
|
return TRUE
|
|
|
|
// If it has a signal handler that returns a click action, done.
|
|
if(SEND_SIGNAL(target, COMSIG_CLICK_CTRL, src) & CLICK_ACTION_ANY)
|
|
return TRUE
|
|
|
|
// If it has a custom click_alt that returns success/block, done.
|
|
if(can_perform_action(target, target.interaction_flags_click | SILENT_ADJACENCY))
|
|
return target.click_ctrl(src) & CLICK_ACTION_ANY
|
|
|
|
return FALSE
|
|
|
|
/**
|
|
* Ctrl click
|
|
* For most objects, pull
|
|
*/
|
|
/mob/living/base_click_ctrl(atom/target)
|
|
SHOULD_NOT_OVERRIDE(TRUE)
|
|
|
|
. = ..()
|
|
if(. || world.time < next_move || !can_perform_action(target, NOT_INSIDE_TARGET | SILENT_ADJACENCY | ALLOW_RESTING | FORBID_TELEKINESIS_REACH))
|
|
return
|
|
|
|
. = TRUE
|
|
if(grab(target) != GRAB_SKIP)
|
|
changeNext_move(CLICK_CD_MELEE)
|
|
return
|
|
start_pulling(target)
|
|
|
|
/**
|
|
* Ctrl mouse wheel click
|
|
* Except for tagging datumns same as control click
|
|
*/
|
|
/mob/proc/CtrlMiddleClickOn(atom/A)
|
|
if(check_rights_for(client, R_ADMIN))
|
|
client.toggle_tag_datum(A)
|
|
return
|
|
CtrlClickOn(A)
|
|
|
|
/**
|
|
* ## Custom ctrl click interaction
|
|
* Override this to change default ctrl click behavior. Return `CLICK_ACTION_SUCCESS`, `CLICK_ACTION_BLOCKING` or `NONE`.
|
|
*
|
|
* ### Guard clauses
|
|
* Consider adding `interaction_flags_click` before adding unique guard clauses.
|
|
*
|
|
* ### Return flags
|
|
* Forgetting your return will cause the default ctrl click behavior to occur thereafter.
|
|
*
|
|
* Returning any value besides NONE will stop the attack chain and thus stop the object from getting pulled/grabbed
|
|
**/
|
|
/atom/proc/click_ctrl(mob/user)
|
|
SHOULD_CALL_PARENT(FALSE)
|
|
return NONE
|
|
|
|
|
|
/**
|
|
* Control+Shift click
|
|
* Unused except for AI
|
|
*/
|
|
/mob/proc/CtrlShiftClickOn(atom/A)
|
|
base_click_ctrl_shift(A)
|
|
|
|
/**
|
|
* ### Base proc for ctrl shift click interaction left click.
|
|
*
|
|
* If you wish to add custom `click_ctrl_shift` behavior for a single type, use that proc.
|
|
*/
|
|
/mob/proc/base_click_ctrl_shift(atom/target)
|
|
SHOULD_NOT_OVERRIDE(TRUE)
|
|
|
|
// Check if they've hooked in to prevent src from ctrl clicking anything
|
|
if(SEND_SIGNAL(src, COMSIG_MOB_CTRL_SHIFT_CLICKED, target) & COMSIG_MOB_CANCEL_CLICKON)
|
|
return
|
|
|
|
// If it has a signal handler that returns a click action, done.
|
|
if(SEND_SIGNAL(target, COMSIG_CLICK_CTRL_SHIFT, src) & CLICK_ACTION_ANY)
|
|
return
|
|
|
|
// Proceed with ctrl shift click
|
|
if(can_perform_action(target, target.interaction_flags_click | SILENT_ADJACENCY))
|
|
target.click_ctrl_shift(src)
|
|
|
|
/**
|
|
* ## Custom ctrl shift click interaction
|
|
*
|
|
* ### Guard clauses
|
|
* Consider adding `interaction_flags_click` before adding unique guard clauses.
|
|
**/
|
|
/atom/proc/click_ctrl_shift(mob/user)
|
|
SHOULD_CALL_PARENT(FALSE)
|
|
return NONE
|