mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-11 16:14:08 +01:00
Lucy
9b6e752f3e
## About The Pull Request Continuation of https://github.com/tgstation/tgstation/pull/78857 FOR TOOO LONG WE HAVE SUFF- Ok yeah so like, we made them overlays to save on maptick, but with threaded maptick that is potentially not an issue anymore. I'm opening this pr so I can tm it and see. If it works, it'll save about 50% of lighting object update costs, which is pretty damn good. I'm also removing the fullbright light icon state, since it is barely ever used (it was added as a clientside op, but we don't hit fullbright very much at all so it does nothing but eat my cpu time) Also also changing how SSlighting does its resolution. Rather then waiting for all sources to process, then working on corners and objects, instead we will do all the sources we had at the start, then all the sources after, and so on. The goal is to avoid churn causing the system to constantly choke. it is better to potentially double operate then it is for things to feel horrifically slow. ## Why It's Good For The Game Faster. Also you won't be able to see lights through walls anymore, so mesons will be less dumb. Can maybe bump their nightvision a bit idk we'll see. ## Current Issues to be found ## Changelog 🆑 Absolucy, LemonInTheDark fix: You can no longer see lights through walls when using mesons or when ventcrawling. /🆑 --------- Co-authored-by: LemonInTheDark <58055496+LemonInTheDark@users.noreply.github.com>
122 lines
4.2 KiB
Plaintext
122 lines
4.2 KiB
Plaintext
// Causes any affecting light sources to be queued for a visibility update, for example a door got opened.
|
|
/turf/proc/reconsider_lights()
|
|
lighting_corner_NE?.vis_update()
|
|
lighting_corner_SE?.vis_update()
|
|
lighting_corner_SW?.vis_update()
|
|
lighting_corner_NW?.vis_update()
|
|
|
|
/turf/proc/lighting_clear_overlay()
|
|
if (lighting_object)
|
|
qdel(lighting_object, force=TRUE)
|
|
|
|
// Builds a lighting object for us, but only if our area is dynamic.
|
|
/turf/proc/lighting_build_overlay()
|
|
if (lighting_object)
|
|
qdel(lighting_object, force=TRUE) //Shitty fix for lighting objects persisting after death
|
|
|
|
new /atom/movable/lighting_object(null, src)
|
|
|
|
// Used to get a scaled lumcount.
|
|
/turf/proc/get_lumcount(minlum = 0, maxlum = 1)
|
|
if (!lighting_object)
|
|
return 1
|
|
|
|
var/totallums = 0
|
|
var/datum/lighting_corner/L
|
|
L = lighting_corner_NE
|
|
if (L)
|
|
totallums += L.lum_r + L.lum_b + L.lum_g
|
|
L = lighting_corner_SE
|
|
if (L)
|
|
totallums += L.lum_r + L.lum_b + L.lum_g
|
|
L = lighting_corner_SW
|
|
if (L)
|
|
totallums += L.lum_r + L.lum_b + L.lum_g
|
|
L = lighting_corner_NW
|
|
if (L)
|
|
totallums += L.lum_r + L.lum_b + L.lum_g
|
|
|
|
|
|
totallums /= 12 // 4 corners, each with 3 channels, get the average.
|
|
|
|
totallums = (totallums - minlum) / (maxlum - minlum)
|
|
|
|
totallums += dynamic_lumcount
|
|
|
|
return CLAMP01(totallums)
|
|
|
|
// Returns a boolean whether the turf is on soft lighting.
|
|
// Soft lighting being the threshold at which point the overlay considers
|
|
// itself as too dark to allow sight and see_in_dark becomes useful.
|
|
// So basically if this returns true the tile is unlit black.
|
|
/turf/proc/is_softly_lit()
|
|
if (!lighting_object)
|
|
return FALSE
|
|
|
|
return !(luminosity || dynamic_lumcount)
|
|
|
|
|
|
///Proc to add movable sources of opacity on the turf and let it handle lighting code.
|
|
/turf/proc/add_opacity_source(atom/movable/new_source)
|
|
LAZYADD(opacity_sources, new_source)
|
|
if(opacity)
|
|
return
|
|
recalculate_directional_opacity()
|
|
|
|
|
|
///Proc to remove movable sources of opacity on the turf and let it handle lighting code.
|
|
/turf/proc/remove_opacity_source(atom/movable/old_source)
|
|
LAZYREMOVE(opacity_sources, old_source)
|
|
if(opacity) //Still opaque, no need to worry on updating.
|
|
return
|
|
recalculate_directional_opacity()
|
|
|
|
|
|
///Calculate on which directions this turfs block view.
|
|
/turf/proc/recalculate_directional_opacity()
|
|
. = directional_opacity
|
|
if(opacity)
|
|
directional_opacity = ALL_CARDINALS
|
|
if(. != directional_opacity)
|
|
reconsider_lights()
|
|
return
|
|
directional_opacity = NONE
|
|
if(opacity_sources)
|
|
for(var/atom/movable/opacity_source as anything in opacity_sources)
|
|
if(opacity_source.flags_1 & ON_BORDER_1)
|
|
directional_opacity |= opacity_source.dir
|
|
else //If fulltile and opaque, then the whole tile blocks view, no need to continue checking.
|
|
directional_opacity = ALL_CARDINALS
|
|
break
|
|
else
|
|
for(var/atom/movable/content as anything in contents)
|
|
SEND_SIGNAL(content, COMSIG_TURF_NO_LONGER_BLOCK_LIGHT)
|
|
if(. != directional_opacity && (. == ALL_CARDINALS || directional_opacity == ALL_CARDINALS))
|
|
reconsider_lights() //The lighting system only cares whether the tile is fully concealed from all directions or not.
|
|
|
|
///Transfer the lighting of one area to another
|
|
/turf/proc/transfer_area_lighting(area/old_area, area/new_area)
|
|
if(SSlighting.initialized && !space_lit)
|
|
if (new_area.static_lighting != old_area.static_lighting)
|
|
if (new_area.static_lighting)
|
|
lighting_build_overlay()
|
|
else
|
|
lighting_clear_overlay()
|
|
|
|
// We will only run this logic on turfs off the prime z layer
|
|
// Since on the prime z layer, we use an overlay on the area instead, to save time
|
|
if(SSmapping.z_level_to_plane_offset[z])
|
|
var/index = SSmapping.z_level_to_plane_offset[z] + 1
|
|
//Inherit overlay of new area
|
|
if(old_area.lighting_effects)
|
|
cut_overlay(old_area.lighting_effects[index])
|
|
if(new_area.lighting_effects)
|
|
add_overlay(new_area.lighting_effects[index])
|
|
|
|
// Manage removing/adding starlight overlays, we'll inherit from the area so we can drop it if the area has it already
|
|
if(space_lit)
|
|
if(!new_area.lighting_effects && old_area.lighting_effects)
|
|
overlays += GLOB.starlight_overlays[GET_TURF_PLANE_OFFSET(src) + 1]
|
|
else if (new_area.lighting_effects && !old_area.lighting_effects)
|
|
overlays -= GLOB.starlight_overlays[GET_TURF_PLANE_OFFSET(src) + 1]
|