mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-20 03:30:01 +01:00
GhomandGitHub
adf838c32a
## About The Pull Request This PR adds a simple holiday spawner type that can be used for objects that are only spawned if the holiday they're associated with is being celebrated. Right now it has three subtypes, all related to the kitchen (liquid ingredient, powdered ingredient, meat ingredient). The involved holidays are the fictional tiziran and mothic festivities Atrakor's Might and Fleet Day. Extra stuff is also spawned on Bee Day and Beer Day. On Vegan Day, the monkey meat slabs in the meat fridges are replaced with plant-based meat slabs (killer tomato slices and pod people meat, plus veggies) and the fridge is renamed from "meat fridge" to "vegan fridge". This PR also adds a few more holiday-specific mail objects such as Speak-Like-a-Pirate Day, Fleet Day, Atrakor's Might, Chernobyl's Disaster Anniversary (it's just a geiger counter), Monkey Day and Draconic Language Day. EDIT: I've decided to make the bar backroom beer keg into a spawner that will spawn special kegs on specific days (otherwise it's a 1 in 25 chance). These kegs can contain drinks a little more refined than the average beer keg. Also it comes with a resprite of kegs because the old one was starting to look a little ass compared to other reagent dispensers. ## Why It's Good For The Game For being fictional festivities revolving around food and culture, and despite the lot of recipes for moths and lizard people, we aren't offering anything to chef players to let them cook said recipes beside what's given on any bog-generic round. This is a step toward a slightly less lackluster implementation of those festivities and recipes into the game. Also chance for cooler kegs for the bartender. ## Changelog 🆑 add: The kitchen fridges may have additional ingredients on certain holidays, in particular Atrakor's Might (lizardpeople) and Fleet Day (mothpeople), and Vegan Day. add: Added a few more holyday-specific mail items. add: Replaces the beer keg in the bar backroom with special kegs on St. Patrick's Day, Beer Day and Speak-Like-a-Pirate day. On any other day, there's a chance that the beer keg will be replaced with one containing whiskey or rum, or in rare cases, one of those special kegs. imageadd: resprited the keg as well. /🆑
103 lines
3.6 KiB
Plaintext
103 lines
3.6 KiB
Plaintext
///A spawner that only spawns specific stuff on holidays
|
|
/obj/effect/spawner/holiday
|
|
icon = 'icons/effects/random_spawners.dmi' //reusing icons for efficiency
|
|
name = "holiday spawner"
|
|
desc = "a spawner effect that only spawns stuff if a holiday is being celebrated."
|
|
///It contains holiday names (use macros please) as key, and the list of things to spawn on said holiday as value.
|
|
var/list/holidays_to_spawn
|
|
///If set and no holiday object is spawned, spawn this instead.
|
|
var/non_holiday_spawn
|
|
|
|
/obj/effect/spawner/holiday/Initialize(mapload)
|
|
. = ..()
|
|
var/found_holiday = FALSE
|
|
for(var/holiday in holidays_to_spawn)
|
|
if(check_holidays(holiday))
|
|
found_holiday = TRUE
|
|
var/list/spawn_list = holidays_to_spawn[holiday]
|
|
for(var/path in spawn_list)
|
|
new path(loc)
|
|
if(!found_holiday && non_holiday_spawn)
|
|
new non_holiday_spawn(loc)
|
|
|
|
/obj/effect/spawner/holiday/powdered_ingredient
|
|
name = "holiday powdered ingredient"
|
|
desc = "A little extra for the kitchen during specific holidays like moth and tiziran festivities."
|
|
icon_state = "chips"
|
|
holidays_to_spawn = list(
|
|
LIZARD_ATRAKOR_DAY = list( //korta flour is made of this
|
|
/obj/item/reagent_containers/condiment/korta_flour,
|
|
/obj/item/reagent_containers/condiment/korta_flour,
|
|
),
|
|
MOTH_FLEET_DAY = list( //mothic dough is made of this, and a lot other things.
|
|
/obj/item/reagent_containers/condiment/cornmeal,
|
|
/obj/item/reagent_containers/condiment/cornmeal,
|
|
),
|
|
)
|
|
|
|
/obj/effect/spawner/holiday/liquid_ingredient
|
|
name = "holiday liquid ingredient"
|
|
desc = /obj/effect/spawner/holiday/powdered_ingredient::desc
|
|
icon_state = "condiment"
|
|
holidays_to_spawn = list(
|
|
LIZARD_ATRAKOR_DAY = list( //a few lizard recipes use this (there are more that use olive oil but this is more iconic of the culture)
|
|
/obj/item/reagent_containers/cup/bottle/syrup_bottle/korta_nectar,
|
|
),
|
|
MOTH_FLEET_DAY = list( //needed for mothic dough and other mothic recipes
|
|
/obj/item/reagent_containers/condiment/olive_oil,
|
|
/obj/item/reagent_containers/condiment/yoghurt,
|
|
),
|
|
BEE_DAY = list(
|
|
/obj/item/reagent_containers/condiment/honey,
|
|
/obj/item/reagent_containers/condiment/honey,
|
|
),
|
|
BEER_DAY = list(
|
|
/obj/effect/spawner/random/food_or_drink/booze,
|
|
),
|
|
)
|
|
|
|
/obj/effect/spawner/holiday/meat_ingredient
|
|
name = "holiday meat ingredient"
|
|
desc = /obj/effect/spawner/holiday/powdered_ingredient::desc
|
|
icon_state = "condiment"
|
|
holidays_to_spawn = list(
|
|
LIZARD_ATRAKOR_DAY = list(
|
|
/obj/item/food/raw_tiziran_sausage,
|
|
/obj/item/organ/liver,
|
|
/obj/item/food/canned/larvae,
|
|
),
|
|
MOTH_FLEET_DAY = list(
|
|
/obj/item/grown/cotton,
|
|
/obj/item/grown/cotton,
|
|
/obj/item/grown/cotton,
|
|
),
|
|
VEGAN_DAY = list( ///plant-based "meat" slabs to allow chefs to cook meat recipes anyway. Plus some veggies.
|
|
/obj/item/food/meat/slab/killertomato,
|
|
/obj/item/food/meat/slab/killertomato,
|
|
/obj/item/food/meat/slab/human/mutant/plant,
|
|
/obj/item/food/meat/slab/human/mutant/plant,
|
|
/obj/item/food/grown/tomato,
|
|
/obj/item/food/grown/cabbage,
|
|
/obj/item/food/grown/onion/red,
|
|
/obj/item/food/grown/herbs,
|
|
),
|
|
)
|
|
|
|
/obj/effect/spawner/holiday/bar_keg
|
|
name = "bar keg spawner"
|
|
desc = "The spawner of the keg on the station. Special stuff on Beer Day and St. Patrick's Day."
|
|
icon_state = "keg"
|
|
holidays_to_spawn = list(
|
|
ST_PATRICK_DAY = list(
|
|
/obj/structure/reagent_dispensers/keg/gold/irish,
|
|
),
|
|
TALK_LIKE_A_PIRATE_DAY = list(
|
|
/obj/structure/reagent_dispensers/keg/gold/rum,
|
|
),
|
|
BEER_DAY = list(
|
|
/obj/structure/reagent_dispensers/keg/gold/trappist,
|
|
),
|
|
)
|
|
|
|
non_holiday_spawn = /obj/effect/spawner/random/food_or_drink/keg
|