mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-22 12:41:09 +01:00
0bd4b0820f
<!-- Write **BELOW** The Headers and **ABOVE** The comments else it may not be viewable. --> <!-- You can view Contributing.MD for a detailed description of the pull request process. --> ## About The Pull Request Brought to you by Team Powercrèpe.(same group of people that delivered the Heretic Overhaul) This PR ports the TGMC Tacmaps and grants em to our NukeOps. Code by Me, @Xander3359, @Arturlang, @Absolucy. Mapping by @RipGrayson Sprites by @KillerOrcaCora Writing bits by @necromanceranne Tacmaps are essentially dynamically generated minimaps, <img width="1711" height="1335" alt="Tac map examples" src="https://github.com/user-attachments/assets/f936fac0-fb7c-4b84-970d-7195b4995ca7" /> <img width="1274" height="714" alt="Tac-Maps Icons" src="https://github.com/user-attachments/assets/0f04e388-af4b-4955-be7a-04650cfd746b" /> As you can see from the screenshots above, departments are classified by color, hovering your cursor over an area or a team mate, will display their name, the system does allow the user to switch between Multi-Z, and lastly you can draw and add labels to the map, although the last option is only available to the NukeOps Leader and OW agents. The functionality is tied to the Syndicate implants nukies start with, Cayenne, Syndie borgs and Mechs also have the ability to toggle the map. Likewise, the tacmaps will display the positioning of the following in real time! - Nuke ops agents - Syndie borgs and Mechs - Cayenne - Location of the nuclear fission device (and beer nuke) - Location of the Nuclear Authentication Disk. <img width="1274" height="714" alt="SkyBridge OFF" src="https://github.com/user-attachments/assets/3915e7d7-644a-4e9a-b213-997834dde2ea" /> <img width="1274" height="714" alt="SkyBridge ON" src="https://github.com/user-attachments/assets/13748290-fd16-42ba-a9c4-a6b4f7e69c79" /> <img width="566" height="459" alt="Holo table done" src="https://github.com/user-attachments/assets/1a43c5b7-ee51-4794-9c09-16b4fb50e2ad" /> https://github.com/user-attachments/assets/caf38538-ef04-4330-992c-3137a67ea0d0 Lastly The tactiical map implant cannot be be used on the nuke ops base,If the team wishes to interact with the map they'll have to Interact with the "Reconnaisance Platform" (Sprite by Orcacora) in the briefing room, which has seen some mapping changes (Brought to you by TheLastGrayson). <!-- Describe The Pull Request. Please be sure every change is documented or this can delay review and even discourage maintainers from merging your PR! --> ## Why It's Good For The Game Originally this feature was planned for the Upcoming Contractor Rework our team is currently working on, but given the massive size of it all, we decided to atomize it. But without that consideration in mind, I think it makes sense for Nuclear operatives of all antagonists to have the means to Recon and plot an assault plan onto the station and actually be able to know the whereabouts of their teammates. Obviously this feature has a lot of other potential applications, we have wanted to have functional Maps for a very long time, if someone wants to give it a go once the feature is merged, by all means. <!-- Argue for the merits of your changes and how they benefit the game, especially if they are controversial and/or far reaching. If you can't actually explain WHY what you are doing will improve the game, then it probably isn't good for the game in the first place. --> ## Changelog <!-- If your PR modifies aspects of the game that can be concretely observed by players or admins you should add a changelog. If your change does NOT meet this description, remove this section. Be sure to properly mark your PRs to prevent unnecessary GBP loss. You can read up on GBP and its effects on PRs in the tgstation guides for contributors. Please note that maintainers freely reserve the right to remove and add tags should they deem it appropriate. You can attempt to finagle the system all you want, but it's best to shoot for clear communication right off the bat. --> 🆑 add: Tactical Maps have been added to the game! add: Nuclear Operatives implants now grant the ability to open a Minimap, this map will display and show the names of various areas of the station, and the positioning of the Nukeops team,borgs,mechs,Cayenne and the nuke disk in real time! add: Nukie leaders and OW agents can also draw and apply labels to the map. add: the "Recoinassance Platform" has been added to the Nukie Base, it allows displaying of the Tactical maps while on the Syndicate Base Z level. map: The briefing room in the NukeOps base has been remapped to better accomodate the new Holographic table. map: Changed the front shutters on the Syndicate Infiltrator to the more fitting Syndicate Shutters. /🆑 <!-- Both 🆑's are required for the changelog to work! You can put your name to the right of the first 🆑 if you want to overwrite your GitHub username as author ingame. --> <!-- You can use multiple of the same prefix (they're only used for the icon ingame) and delete the unneeded ones. Despite some of the tags, changelogs should generally represent how a player might be affected by the changes rather than a summary of the PR's contents. --> --------- Co-authored-by: Xander3359 <66163761+Xander3359@users.noreply.github.com> Co-authored-by: Artur Lang <24881678+Arturlang@users.noreply.github.com> Co-authored-by: Lucy <lucy@absolucy.moe> Co-authored-by: Copilot <copilot@github.com> Co-authored-by: RipGrayson <49290523+RipGrayson@users.noreply.github.com> Co-authored-by: necromanceranne <40847847+necromanceranne@users.noreply.github.com>
121 lines
4.4 KiB
Plaintext
121 lines
4.4 KiB
Plaintext
/obj/item/implant/tacmap
|
|
name = "tactical map implant"
|
|
desc = "provides you with a map"
|
|
actions_types = list(/datum/action/minimap)
|
|
var/wearer_icon_state = null
|
|
/// Optional z-trait that resolves to the first z-level and locks the minimap there.
|
|
var/minimap_fixed_z_trait
|
|
/// Whether this implant allows drawing/labeling on the personal minimap HUD.
|
|
var/can_draw_on_personal_minimap = FALSE
|
|
var/static/list/minimap_refresh_signals = list(
|
|
COMSIG_MOB_STATCHANGE,
|
|
COMSIG_LIVING_REVIVE,
|
|
COMSIG_MOB_GHOSTIZED,
|
|
)
|
|
|
|
/obj/item/implant/tacmap/implant(mob/living/target, mob/user, silent, force)
|
|
. = ..()
|
|
if(.)
|
|
configure_minimap_action()
|
|
RegisterSignals(target, minimap_refresh_signals, PROC_REF(refresh_minimap_icon))
|
|
addtimer(CALLBACK(src, PROC_REF(update_minimap_icon), target), 0.1 SECONDS) // Mobs are spawned inside nullspace sometimes so this avoids that hijinks.
|
|
|
|
/obj/item/implant/tacmap/removed(mob/living/source, silent, special)
|
|
UnregisterSignal(source, minimap_refresh_signals)
|
|
remove_minimap(source)
|
|
return ..()
|
|
|
|
///Remove all action of type minimap from the wearer, and make him disappear from the minimap
|
|
/obj/item/implant/tacmap/proc/remove_minimap(mob/user)
|
|
remove_minimap_blip(MINIMAP_NUKEOP_BLIP, user)
|
|
|
|
/obj/item/implant/tacmap/proc/refresh_minimap_icon()
|
|
SIGNAL_HANDLER
|
|
if(imp_in)
|
|
update_minimap_icon(imp_in)
|
|
|
|
/obj/item/implant/tacmap/proc/resolve_fixed_minimap_z_level()
|
|
if(!isnull(minimap_fixed_z_trait))
|
|
var/list/trait_levels = SSmapping.levels_by_trait(minimap_fixed_z_trait)
|
|
if(length(trait_levels))
|
|
return trait_levels[1]
|
|
return null
|
|
|
|
/obj/item/implant/tacmap/proc/configure_minimap_action()
|
|
var/datum/action/minimap/minimap_action = locate(/datum/action/minimap) in actions
|
|
if(isnull(minimap_action))
|
|
return
|
|
minimap_action.fixed_z_level = resolve_fixed_minimap_z_level()
|
|
minimap_action.can_draw = can_draw_on_personal_minimap
|
|
|
|
/obj/item/implant/tacmap/proc/get_minimap_icon_state(mob/living/wearer)
|
|
return wearer_icon_state
|
|
|
|
///Updates the wearer's minimap icon
|
|
/obj/item/implant/tacmap/proc/update_minimap_icon(mob/wearer)
|
|
SIGNAL_HANDLER
|
|
remove_minimap_blip(MINIMAP_NUKEOP_BLIP, wearer)
|
|
add_minimap_blip(wearer, MINIMAP_NUKEOP_BLIP, get_minimap_icon_state(wearer))
|
|
|
|
/obj/item/implant/tacmap/nuclear // Nukie subtype, map shows you nuke disk, operatives, cayenne and the nuke
|
|
actions_types = list(/datum/action/minimap/nuclear)
|
|
wearer_icon_state = "syndicate"
|
|
|
|
/obj/item/implant/tacmap/nuclear/implant(mob/living/target, mob/user, silent, force)
|
|
. = ..()
|
|
if(.)
|
|
RegisterSignal(target, COMSIG_MINIMAP_ACTION_TRIGGER, PROC_REF(deny_nukie_base_open))
|
|
|
|
/obj/item/implant/tacmap/nuclear/get_minimap_icon_state(mob/living/wearer)
|
|
if(wearer.stat != DEAD && istype(wearer, /mob/living/basic/carp/pet/cayenne))
|
|
return "cayenne"
|
|
. = ..()
|
|
|
|
/obj/item/implant/tacmap/nuclear/removed(mob/living/source, silent, special)
|
|
UnregisterSignal(source, COMSIG_MINIMAP_ACTION_TRIGGER)
|
|
return ..()
|
|
|
|
/obj/item/implant/tacmap/nuclear/proc/deny_nukie_base_open(mob/living/user)
|
|
var/turf/user_turf = get_turf(user)
|
|
if(user_turf.onSyndieBase())
|
|
user.balloon_alert(user, "can't use implant in the base, go to the holotable!")
|
|
return COMSIG_MINIMAP_ACTION_TRIGGER_CANCEL
|
|
|
|
/obj/item/implant/tacmap/nuclear/cayenne // subtype used for cayenne and syndie sentience potions in general
|
|
wearer_icon_state = "cayenne"
|
|
|
|
/obj/item/implant/tacmap/nuclear/leader // Leader subtype lets him draw on the map
|
|
actions_types = list(/datum/action/minimap/nuclear)
|
|
can_draw_on_personal_minimap = TRUE
|
|
wearer_icon_state = "syndicate_leader"
|
|
|
|
/obj/item/implant/tacmap/nuclear/leader/implant(mob/living/target, mob/user, silent, force)
|
|
. = ..()
|
|
if(.)
|
|
ADD_TRAIT(target, TRAIT_MINIMAP_TABLE_DRAW, REF(src))
|
|
|
|
/obj/item/implant/tacmap/nuclear/leader/removed(mob/living/source, silent, special)
|
|
REMOVE_TRAIT(source, TRAIT_MINIMAP_TABLE_DRAW, REF(src))
|
|
return ..()
|
|
|
|
// Subtype that just lets them open it off-base.
|
|
/obj/item/implant/tacmap/nuclear/offbase
|
|
minimap_fixed_z_trait = ZTRAIT_STATION
|
|
can_draw_on_personal_minimap = TRUE
|
|
|
|
/obj/item/implant/tacmap/nuclear/offbase/deny_nukie_base_open(mob/living/user)
|
|
return
|
|
|
|
/obj/item/implanter/tacmap
|
|
name = "implanter (minimap)"
|
|
imp_type = /obj/item/implant/tacmap
|
|
|
|
/obj/item/implanter/tacmap/nuclear
|
|
name = "implanter (operative minimap)"
|
|
imp_type = /obj/item/implant/tacmap/nuclear
|
|
|
|
/obj/item/implantcase/tacmap
|
|
name = "implant case - 'Tactical Map'"
|
|
desc = "A glass case containing an implant with a virtual map."
|
|
imp_type = /obj/item/implant/tacmap
|