mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-06-22 06:35:12 +01:00
John Willard
475fe94750
## About The Pull Request Removes Say/Me/OOC/Pray/Whisper as stat panel verbs 1. Adds a hotkey for Pray, P by default, and also adds it to the list of say modes (so tabbing on tgui-say will show it) 2. Makes Whisper a button on the commandbar, which is literally just ``say "#``, letting players know it exists in a more direct manner. 3. You now need 2 characters to be considered "typing", so `#` for whisper won't cause you to start to think anymore. Also messes around with the skin a bit, moving the commandbar to be separate from the chat window, therefore not resizing if the chat window/stat panel splitter changes, since I was already messing with the command bar entirely I might as well look into getting this fixed. This will go even better with https://github.com/tgstation/tgstation/pull/95383 as it wont stretch the command bar when the stat panel is closed. https://github.com/user-attachments/assets/26cd9df0-7582-445e-9f67-c03d2c9cf46d Also adds a new Adminhelp submenu for the Pray button for additional visibility https://github.com/user-attachments/assets/64f31f86-92a2-4f04-b248-6bbe301919fe My current goal is the deletion of the IC tab so I've been trying to inch towards that. ## Why It's Good For The Game Moves Praying & Whispering into something that's more easily seen by newer players, and helps cut some of the more useless verbs out of the stat panel. This is also part of my project you can see more of here - https://hackmd.io/443_dE5lRWeEAp9bjGcKYw?view ## Changelog 🆑 qol: Pray verb is now a hotkey, Whisper is now a command bar button, and all say verbs have been removed from the stat panel. qol: Admin button on the escape menu is now its own section for praying, as well as seeing your latest ticket & admin notes. fix: Resizing the stat panel will no longer change the size of the command bar. /🆑
108 lines
3.2 KiB
Plaintext
108 lines
3.2 KiB
Plaintext
///Text that gets highlighted when you have an admin ticket notification.
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_ticket_notification
|
|
VAR_PRIVATE
|
|
current_blink = FALSE
|
|
is_blinking = FALSE
|
|
last_blink_time = 0
|
|
blink_interval = 0.4 SECONDS
|
|
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_ticket_notification/Initialize(
|
|
mapload,
|
|
datum/hud/hud_owner,
|
|
datum/escape_menu/escape_menu,
|
|
button_text,
|
|
list/offset,
|
|
font_size = 24,
|
|
on_click_callback,
|
|
)
|
|
. = ..()
|
|
|
|
RegisterSignal(escape_menu.client, COMSIG_ADMIN_HELP_RECEIVED, PROC_REF(on_admin_help_received))
|
|
|
|
var/datum/admin_help/current_ticket = escape_menu.client?.current_ticket
|
|
if (!isnull(current_ticket))
|
|
connect_ticket(current_ticket)
|
|
if (!current_ticket?.player_replied)
|
|
begin_processing()
|
|
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_ticket_notification/proc/on_admin_help_received()
|
|
SIGNAL_HANDLER
|
|
|
|
begin_processing()
|
|
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_ticket_notification/proc/begin_processing()
|
|
if (is_blinking)
|
|
return
|
|
|
|
is_blinking = TRUE
|
|
current_blink = TRUE
|
|
START_PROCESSING(SSescape_menu, src)
|
|
update_text()
|
|
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_ticket_notification/proc/end_processing()
|
|
if (!is_blinking)
|
|
return
|
|
|
|
is_blinking = FALSE
|
|
current_blink = FALSE
|
|
STOP_PROCESSING(SSescape_menu, src)
|
|
update_text()
|
|
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_ticket_notification/proc/connect_ticket(datum/admin_help/admin_help)
|
|
ASSERT(istype(admin_help))
|
|
|
|
RegisterSignal(admin_help, COMSIG_ADMIN_HELP_REPLIED, PROC_REF(on_admin_help_replied))
|
|
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_ticket_notification/proc/on_admin_help_replied()
|
|
SIGNAL_HANDLER
|
|
|
|
end_processing()
|
|
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_ticket_notification/process(seconds_per_tick)
|
|
if (world.time - last_blink_time < blink_interval)
|
|
return
|
|
|
|
current_blink = !current_blink
|
|
last_blink_time = world.time
|
|
update_text()
|
|
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_ticket_notification/text_color()
|
|
if (!enabled())
|
|
return ..()
|
|
|
|
return current_blink ? "red" : ..()
|
|
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_ticket_notification/MouseEntered(location, control, params)
|
|
. = ..()
|
|
|
|
if (is_blinking)
|
|
openToolTip(usr, src, params, content = "An admin is trying to talk to you!")
|
|
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_ticket_notification/MouseExited(location, control, params)
|
|
. = ..()
|
|
|
|
closeToolTip(usr)
|
|
|
|
///The button used for adminhelping, this is used to grey it out when you're on cooldown.
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_help/Initialize(
|
|
mapload,
|
|
datum/hud/hud_owner,
|
|
datum/escape_menu/escape_menu,
|
|
button_text,
|
|
list/offset,
|
|
font_size = 24,
|
|
on_click_callback,
|
|
)
|
|
. = ..()
|
|
|
|
RegisterSignals(escape_menu.client, list(COMSIG_CLIENT_VERB_ADDED, COMSIG_CLIENT_VERB_REMOVED), PROC_REF(on_client_verb_changed))
|
|
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_help/proc/on_client_verb_changed(client/source, list/verbs_changed)
|
|
SIGNAL_HANDLER
|
|
|
|
if (/client/verb/adminhelp in verbs_changed)
|
|
update_text()
|
|
|
|
/atom/movable/screen/escape_menu/text/clickable/admin_help/enabled()
|
|
return (/client/verb/adminhelp in escape_menu.client?.verbs)
|