mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-13 00:55:20 +01:00
Alexis
21b4095dfd
Upstream 04/17/2026 fixes https://github.com/Bubberstation/Bubberstation/issues/5549 --------- Signed-off-by: dependabot[bot] <support@github.com> Co-authored-by: tgstation-ci[bot] <179393467+tgstation-ci[bot]@users.noreply.github.com> Co-authored-by: ArcaneMusic <41715314+ArcaneMusic@users.noreply.github.com> Co-authored-by: MrMelbert <51863163+MrMelbert@users.noreply.github.com> Co-authored-by: Rhials <28870487+Rhials@users.noreply.github.com> Co-authored-by: rageguy505 <54517726+rageguy505@users.noreply.github.com> Co-authored-by: LemonInTheDark <58055496+LemonInTheDark@users.noreply.github.com> Co-authored-by: John Willard <53777086+JohnFulpWillard@users.noreply.github.com> Co-authored-by: Aliceee2ch <160794176+Aliceee2ch@users.noreply.github.com> Co-authored-by: Time-Green <7501474+Time-Green@users.noreply.github.com> Co-authored-by: Tsar-Salat <62388554+Tsar-Salat@users.noreply.github.com> Co-authored-by: SmArtKar <44720187+SmArtKar@users.noreply.github.com> Co-authored-by: Maxipat <108554989+Maxipat112@users.noreply.github.com> Co-authored-by: SyncIt21 <110812394+SyncIt21@users.noreply.github.com> Co-authored-by: deltanedas <39013340+deltanedas@users.noreply.github.com> Co-authored-by: SimplyLogan <47579821+loganuk@users.noreply.github.com> Co-authored-by: loganuk <fakeemail123@aol.com> Co-authored-by: Leland Kemble <70413276+lelandkemble@users.noreply.github.com> Co-authored-by: FalloutFalcon <86381784+FalloutFalcon@users.noreply.github.com> Co-authored-by: Roxy <75404941+TealSeer@users.noreply.github.com> Co-authored-by: Lucy <lucy@absolucy.moe> Co-authored-by: siliconOpossum <138069572+siliconOpossum@users.noreply.github.com> Co-authored-by: Isratosh <Isratosh@hotmail.com> Co-authored-by: TheRyeGuyWhoWillNowDie <70169560+TheRyeGuyWhoWillNowDie@users.noreply.github.com> Co-authored-by: Neocloudy <88008002+Neocloudy@users.noreply.github.com> Co-authored-by: Alexander V. <volas@ya.ru> Co-authored-by: ElGitificador <168473461+ElGitificador@users.noreply.github.com> Co-authored-by: Twaticus <46540570+Twaticus@users.noreply.github.com> Co-authored-by: dependabot[bot] <49699333+dependabot[bot]@users.noreply.github.com> Co-authored-by: Bloop <13398309+vinylspiders@users.noreply.github.com> Co-authored-by: Cameron Lennox <killer65311@gmail.com> Co-authored-by: Tim <timothymtorres@gmail.com> Co-authored-by: Iamgoofball <iamgoofball@gmail.com> Co-authored-by: Layzu666 <121319428+Layzu666@users.noreply.github.com> Co-authored-by: Arturlang <24881678+Arturlang@users.noreply.github.com> Co-authored-by: _0Steven <42909981+00-Steven@users.noreply.github.com> Co-authored-by: mrmanlikesbt <99309552+mrmanlikesbt@users.noreply.github.com> Co-authored-by: Ben10Omintrix <138636438+Ben10Omintrix@users.noreply.github.com> Co-authored-by: John F. Kennedy <54908920+MacaroniCritter@users.noreply.github.com> Co-authored-by: Cursor <102828457+theselfish@users.noreply.github.com> Co-authored-by: Josh <josh.adam.powell@gmail.com> Co-authored-by: Josh Powell <josh.powell@softwire.com> Co-authored-by: Yobrocharlie <Charliemiller5617@gmail.com> Co-authored-by: Hardly3D <66234359+Hardly3D@users.noreply.github.com> Co-authored-by: shayoki <96078776+shayoki@users.noreply.github.com> Co-authored-by: LT3 <83487515+lessthnthree@users.noreply.github.com>
89 lines
3.0 KiB
Plaintext
89 lines
3.0 KiB
Plaintext
/mob/living/basic/mining/wolf
|
|
name = "white wolf"
|
|
desc = "Pack hunters of the Icemoon wastes. While a mere nuisance individually, they become fearsome foes in larger groups."
|
|
icon = 'icons/mob/simple/icemoon/icemoon_monsters.dmi'
|
|
icon_state = "whitewolf"
|
|
icon_living = "whitewolf"
|
|
icon_dead = "whitewolf_dead"
|
|
mouse_opacity = MOUSE_OPACITY_ICON
|
|
speak_emote = list("howls")
|
|
friendly_verb_continuous = "howls at"
|
|
friendly_verb_simple = "howl at"
|
|
|
|
butcher_results = list(
|
|
/obj/item/food/meat/slab = 2,
|
|
/obj/item/stack/sheet/sinew/wolf = 2,
|
|
/obj/item/stack/sheet/bone = 2
|
|
)
|
|
crusher_loot = /obj/item/crusher_trophy/wolf_ear
|
|
|
|
maxHealth = 130
|
|
health = 130
|
|
obj_damage = 15
|
|
melee_damage_lower = 7.5
|
|
melee_damage_upper = 7.5
|
|
attack_vis_effect = ATTACK_EFFECT_BITE
|
|
melee_attack_cooldown = 1.2 SECONDS
|
|
|
|
attack_verb_continuous = "bites"
|
|
attack_verb_simple = "bite"
|
|
death_message = "snarls its last and perishes."
|
|
|
|
attack_sound = 'sound/items/weapons/bite.ogg'
|
|
move_force = MOVE_FORCE_WEAK
|
|
move_resist = MOVE_FORCE_WEAK
|
|
pull_force = MOVE_FORCE_WEAK
|
|
|
|
ai_controller = /datum/ai_controller/basic_controller/wolf
|
|
|
|
//can we tame this wolf?
|
|
var/can_tame = TRUE
|
|
|
|
//commands to give when tamed
|
|
var/static/list/pet_commands = list(
|
|
/datum/pet_command/idle,
|
|
/datum/pet_command/move,
|
|
/datum/pet_command/free,
|
|
/datum/pet_command/good_boy/wolf,
|
|
/datum/pet_command/follow/wolf,
|
|
/datum/pet_command/attack,
|
|
/datum/pet_command/fetch,
|
|
/datum/pet_command/play_dead,
|
|
/datum/pet_command/protect_owner,
|
|
)
|
|
|
|
/mob/living/basic/mining/wolf/Initialize(mapload)
|
|
. = ..()
|
|
|
|
ADD_TRAIT(src, TRAIT_WOUND_LICKER, INNATE_TRAIT)
|
|
AddElement(/datum/element/footstep, FOOTSTEP_MOB_CLAW)
|
|
AddElement(/datum/element/ai_flee_while_injured)
|
|
AddElement(/datum/element/ai_retaliate)
|
|
|
|
if(can_tame)
|
|
make_tameable()
|
|
|
|
/mob/living/basic/mining/wolf/proc/make_tameable()
|
|
var/static/list/food_types = list(/obj/item/food/meat/slab)
|
|
AddComponent(/datum/component/tameable, food_types = food_types, tame_chance = 15, bonus_tame_chance = 5)
|
|
|
|
/mob/living/basic/mining/wolf/tamed(mob/living/tamer, atom/food)
|
|
. = ..()
|
|
new /obj/effect/temp_visual/heart(src.loc)
|
|
// ride wolf, life good
|
|
AddElement(/datum/element/ridable, /datum/component/riding/creature/wolf)
|
|
AddComponent(/datum/component/obeys_commands, pet_commands)
|
|
// this is purely a convenience thing once tamed so you can drag them away from shit
|
|
ai_controller.ai_traits |= STOP_MOVING_WHEN_PULLED
|
|
// makes tamed wolves run away far less
|
|
ai_controller.set_blackboard_key(BB_BASIC_MOB_FLEE_DISTANCE, 7)
|
|
|
|
//port the faction fix from goliath basicmob to make the wildlife hostile when tamed (and also help defuckulate reinforcements ai)
|
|
//this should also produce interesting behavior where tamed wolves defend other tamed wolves.
|
|
/mob/living/basic/mining/wolf/befriend(mob/living/new_friend)
|
|
. = ..()
|
|
if(isnull(.))
|
|
return
|
|
SET_FACTION_AND_ALLIES_FROM(src, new_friend)
|
|
visible_message(span_notice("[src] lowers [src.p_their()] snout at [new_friend]'s offering and begins to wag [src.p_their()] tail."))
|