mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-30 03:22:41 +00:00
8805502dc4
* Fixes the metallic hydrogen axe being silent when being used as a crowbar and crowbars can now hit windows. (#73974) ## About The Pull Request The metallic hydrogen axe had no usesound var set despite having a tool_behavior applied to it, this meant that when using it as a crowbar, for example to remove floor tiles no sound was played. I've given it the default crowbar sound for this. Bonus fix: Crowbars were incapable of hitting fully constructed default windows, this included the H2 axe, They are now able to be used on standard windows (they already worked on reinforced windows) ## Why It's Good For The Game Missing sound bad. Pretty sure the crowbar thing is a bug too. ## Changelog 🆑 fix: The metallic hydrogen axe is no longer silent when using it as a crowbar. fix: You are now capable of hitting standard windows with a crowbar when they're fully constructed. /🆑 * Fixes the metallic hydrogen axe being silent when being used as a crowbar and crowbars can now hit windows. --------- Co-authored-by: NamelessFairy <40036527+NamelessFairy@users.noreply.github.com>
89 lines
2.9 KiB
Plaintext
89 lines
2.9 KiB
Plaintext
/*
|
|
* Fireaxe
|
|
*/
|
|
/obj/item/fireaxe // DEM AXES MAN, marker -Agouri
|
|
icon = 'icons/obj/weapons/fireaxe.dmi'
|
|
icon_state = "fireaxe0"
|
|
base_icon_state = "fireaxe"
|
|
lefthand_file = 'icons/mob/inhands/weapons/axes_lefthand.dmi'
|
|
righthand_file = 'icons/mob/inhands/weapons/axes_righthand.dmi'
|
|
name = "fire axe"
|
|
desc = "Truly, the weapon of a madman. Who would think to fight fire with an axe?"
|
|
force = 5
|
|
throwforce = 15
|
|
demolition_mod = 1.25
|
|
w_class = WEIGHT_CLASS_BULKY
|
|
flags_1 = CONDUCT_1
|
|
slot_flags = ITEM_SLOT_BACK
|
|
attack_verb_continuous = list("attacks", "chops", "cleaves", "tears", "lacerates", "cuts")
|
|
attack_verb_simple = list("attack", "chop", "cleave", "tear", "lacerate", "cut")
|
|
hitsound = 'sound/weapons/bladeslice.ogg'
|
|
sharpness = SHARP_EDGED
|
|
armor_type = /datum/armor/item_fireaxe
|
|
resistance_flags = FIRE_PROOF
|
|
wound_bonus = -15
|
|
bare_wound_bonus = 20
|
|
/// How much damage to do unwielded
|
|
var/force_unwielded = 5
|
|
/// How much damage to do wielded
|
|
var/force_wielded = 24
|
|
|
|
/datum/armor/item_fireaxe
|
|
fire = 100
|
|
acid = 30
|
|
|
|
/obj/item/fireaxe/Initialize(mapload)
|
|
. = ..()
|
|
AddComponent(/datum/component/butchering, \
|
|
speed = 10 SECONDS, \
|
|
effectiveness = 80, \
|
|
bonus_modifier = 0 , \
|
|
butcher_sound = hitsound, \
|
|
)
|
|
//axes are not known for being precision butchering tools
|
|
AddComponent(/datum/component/two_handed, force_unwielded=force_unwielded, force_wielded=force_wielded, icon_wielded="[base_icon_state]1")
|
|
|
|
/obj/item/fireaxe/update_icon_state()
|
|
icon_state = "[base_icon_state]0"
|
|
return ..()
|
|
|
|
/obj/item/fireaxe/suicide_act(mob/living/user)
|
|
user.visible_message(span_suicide("[user] axes [user.p_them()]self from head to toe! It looks like [user.p_theyre()] trying to commit suicide!"))
|
|
return BRUTELOSS
|
|
|
|
/obj/item/fireaxe/afterattack(atom/A, mob/user, proximity)
|
|
. = ..()
|
|
if(!proximity)
|
|
return
|
|
if(HAS_TRAIT(src, TRAIT_WIELDED)) //destroys windows and grilles in one hit
|
|
if(istype(A, /obj/structure/window) || istype(A, /obj/structure/grille))
|
|
if(!(A.resistance_flags & INDESTRUCTIBLE))
|
|
var/obj/structure/W = A
|
|
W.atom_destruction("fireaxe")
|
|
|
|
/*
|
|
* Bone Axe
|
|
*/
|
|
/obj/item/fireaxe/boneaxe // Blatant imitation of the fireaxe, but made out of bone.
|
|
icon_state = "bone_axe0"
|
|
base_icon_state = "bone_axe"
|
|
name = "bone axe"
|
|
desc = "A large, vicious axe crafted out of several sharpened bone plates and crudely tied together. Made of monsters, by killing monsters, for killing monsters."
|
|
force_unwielded = 5
|
|
force_wielded = 23
|
|
|
|
/*
|
|
* Metal Hydrogen Axe
|
|
*/
|
|
/obj/item/fireaxe/metal_h2_axe
|
|
icon_state = "metalh2_axe0"
|
|
base_icon_state = "metalh2_axe"
|
|
name = "metallic hydrogen axe"
|
|
desc = "A lightweight crowbar with an extreme sharp fire axe head attached. It trades it's hefty as a weapon by making it easier to carry around when holstered to suits without having to sacrifice your backpack."
|
|
force_unwielded = 5
|
|
force_wielded = 15
|
|
demolition_mod = 2
|
|
tool_behaviour = TOOL_CROWBAR
|
|
toolspeed = 1
|
|
usesound = 'sound/items/crowbar.ogg'
|