mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-28 10:01:58 +00:00
58501dce77
## About The Pull Request <details> - renamed ai folder to announcer -- announcer -- - moved vox_fem to announcer - moved approachingTG to announcer - separated the ambience folder into ambience and instrumental -- ambience -- - created holy folder moved all related sounds there - created engineering folder and moved all related sounds there - created security folder and moved ambidet there - created general folder and moved ambigen there - created icemoon folder and moved all icebox-related ambience there - created medical folder and moved all medbay-related ambi there - created ruin folder and moves all ruins ambi there - created beach folder and moved seag and shore there - created lavaland folder and moved related ambi there - created aurora_caelus folder and placed its ambi there - created misc folder and moved the rest of the files that don't have a specific category into it -- instrumental -- - moved traitor folder here - created lobby_music folder and placed our songs there (title0 not used anywhere? - server-side modification?) -- items -- - moved secdeath to hailer - moved surgery to handling -- effects -- - moved chemistry into effects - moved hallucinations into effects - moved health into effects - moved magic into effects -- vehicles -- - moved mecha into vehicles created mobs folder -- mobs -- - moved creatures folder into mobs - moved voice into mobs renamed creatures to non-humanoids renamed voice to humanoids -- non-humanoids-- created cyborg folder created hiss folder moved harmalarm.ogg to cyborg -- humanoids -- -- misc -- moved ghostwhisper to misc moved insane_low_laugh to misc I give up trying to document this. </details> - [X] ambience - [x] announcer - [x] effects - [X] instrumental - [x] items - [x] machines - [x] misc - [X] mobs - [X] runtime - [X] vehicles - [ ] attributions ## Why It's Good For The Game This folder is so disorganized that it's vomit inducing, will make it easier to find and add new sounds, providng a minor structure to the sound folder. ## Changelog 🆑 grungussuss refactor: the sound folder in the source code has been reorganized, please report any oddities with sounds playing or not playing server: lobby music has been repathed to sound/music/lobby_music /🆑
117 lines
4.3 KiB
Plaintext
117 lines
4.3 KiB
Plaintext
///A pinata that has a chance to drop candy items when struck with a melee weapon that deals at least 10 damage
|
|
/obj/structure/pinata
|
|
name = "corgi pinata"
|
|
desc = "A papier-mâché representation of a corgi that contains all sorts of sugary treats."
|
|
icon = 'icons/obj/toys/toy.dmi'
|
|
icon_state = "pinata_placed"
|
|
base_icon_state = "pinata_placed"
|
|
max_integrity = 300 //20 hits from a baseball bat
|
|
anchored = TRUE
|
|
///What sort of candy the pinata will contain
|
|
var/candy_options = list(
|
|
/obj/item/food/bubblegum,
|
|
/obj/item/food/candy,
|
|
/obj/item/food/chocolatebar,
|
|
/obj/item/food/gumball,
|
|
/obj/item/food/lollipop/cyborg,
|
|
)
|
|
///How much candy is dropped when the pinata is destroyed
|
|
var/destruction_loot = 5
|
|
///Debris dropped when the pinata is destroyed
|
|
var/debris = /obj/effect/decal/cleanable/wrapping/pinata
|
|
|
|
/obj/structure/pinata/Initialize(mapload)
|
|
. = ..()
|
|
AddComponent(/datum/component/pinata, candy = candy_options, death_drop = destruction_loot)
|
|
|
|
/obj/structure/pinata/take_damage(damage_amount, damage_type, damage_flag, sound_effect, attack_dir, armour_penetration)
|
|
. = ..()
|
|
if(get_integrity() < (max_integrity/2))
|
|
icon_state = "[base_icon_state]_damaged"
|
|
if(damage_amount >= 10) // Swing means minimum damage threshold for dropping candy is met.
|
|
flick("[icon_state]_swing", src)
|
|
|
|
/obj/structure/pinata/play_attack_sound(damage_amount, damage_type, damage_flag)
|
|
switch(damage_type)
|
|
if(BRUTE)
|
|
if(damage_amount)
|
|
playsound(src, 'sound/items/weapons/slash.ogg', 50, TRUE)
|
|
else
|
|
playsound(src, 'sound/items/weapons/tap.ogg', 50, TRUE)
|
|
if(BURN)
|
|
playsound(src, 'sound/items/tools/welder.ogg', 100, TRUE)
|
|
|
|
/obj/structure/pinata/atom_deconstruct(disassembled)
|
|
new debris(get_turf(src))
|
|
|
|
///An item that when used inhand spawns an immovable pinata
|
|
/obj/item/pinata
|
|
name = "pinata assembly kit"
|
|
desc = "A papier-mâché corgi that contains various candy, must be set up before you can smash it."
|
|
icon = 'icons/obj/toys/toy.dmi'
|
|
icon_state = "pinata"
|
|
///The pinata that is created when this is placed.
|
|
var/pinata_type = /obj/structure/pinata
|
|
|
|
/obj/item/pinata/attack_self(mob/user)
|
|
var/turf/player_turf = get_turf(user)
|
|
if(player_turf?.is_blocked_turf(TRUE))
|
|
return FALSE
|
|
balloon_alert_to_viewers("setting up pinata...")
|
|
if(!do_after(user, 4 SECONDS, target = get_turf(user), progress = TRUE))
|
|
balloon_alert(user, "cancelled!")
|
|
new pinata_type(get_turf(user))
|
|
balloon_alert(user, "pinata setup")
|
|
qdel(src)
|
|
|
|
/obj/structure/pinata/syndie
|
|
name = "syndicate corgi pinata"
|
|
desc = "A papier-mâché representation of a corgi that contains all sorts of bombastic treats."
|
|
icon_state = "pinata_syndie_placed"
|
|
base_icon_state = "pinata_syndie_placed"
|
|
destruction_loot = 2
|
|
debris = /obj/effect/decal/cleanable/wrapping/pinata/syndie
|
|
candy_options = list(
|
|
/obj/item/food/bubblegum,
|
|
/obj/item/food/candy,
|
|
/obj/item/food/chocolatebar,
|
|
/obj/item/food/gumball,
|
|
/obj/item/food/lollipop,
|
|
/obj/item/grenade/c4,
|
|
/obj/item/grenade/clusterbuster/soap,
|
|
/obj/item/grenade/empgrenade,
|
|
/obj/item/grenade/frag,
|
|
/obj/item/grenade/syndieminibomb,
|
|
) //Candy items at the top, explosives at the bottom to be easier to read instead of fully alphabetized.
|
|
|
|
/obj/item/pinata/syndie
|
|
name = "weapons grade pinata assembly kit"
|
|
desc = "A papier-mâché corgi that contains various candy and explosives, must be set up before you can smash it."
|
|
icon_state = "pinata_syndie"
|
|
pinata_type = /obj/structure/pinata/syndie
|
|
|
|
/obj/structure/pinata/donk
|
|
name = "donk corgi pinata"
|
|
desc = "A papier-mâché representation of a corgi that contains all sorts of savory treats."
|
|
icon_state = "pinata_donk_placed"
|
|
base_icon_state = "pinata_donk_placed"
|
|
debris = /obj/effect/decal/cleanable/wrapping/pinata/donk
|
|
candy_options = list(
|
|
/obj/item/food/donkpocket/warm,
|
|
/obj/item/food/donkpocket/warm/pizza,
|
|
/obj/item/food/donkpocket/warm/honk,
|
|
/obj/item/food/donkpocket/warm/berry,
|
|
/obj/item/food/donkpocket/warm,
|
|
/obj/item/food/tatortot,
|
|
/obj/item/gun/ballistic/automatic/pistol/toy,
|
|
/obj/item/hot_potato/harmless/toy,
|
|
/obj/item/storage/box/donkpockets,
|
|
/obj/item/toy/plush/donkpocket,
|
|
)
|
|
|
|
/obj/item/pinata/donk
|
|
name = "\improper Donk Co. pinata assembly kit"
|
|
desc = "A papier-mâché corgi that contains various foodstuff and toys, must be set up before you can smash it."
|
|
icon_state = "pinata_donk"
|
|
pinata_type = /obj/structure/pinata/donk
|