mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-03 13:32:17 +00:00
864d6ca09b
Adds a new GUI that can be opened from the chem dispenser that will let you look up all reactions and reagents presently in the game (except secret recipes). For the colours: purple - clicking this will give you a recipe blue - clicking this will give you a reagent green - clicking this will turn it off (or it's also green if the reagent is present in the associated beaker the UI is linked to) red - clicking this will turn it on Co-authored-by: Rohesie <rohesie@gmail.com> Co-authored-by: Mothblocks <35135081+Jared-Fogle@users.noreply.github.com> Co-authored-by: Aleksej Komarov <stylemistake@gmail.com>
43 lines
1.5 KiB
Plaintext
43 lines
1.5 KiB
Plaintext
//Used for active reactions in reagents/equilibrium datums
|
|
|
|
PROCESSING_SUBSYSTEM_DEF(reagents)
|
|
name = "Reagents"
|
|
init_order = INIT_ORDER_REAGENTS
|
|
priority = FIRE_PRIORITY_REAGENTS
|
|
wait = 0.25 SECONDS //You might think that rate_up_lim has to be set to half, but since everything is normalised around delta_time, it automatically adjusts it to be per second. Magic!
|
|
flags = SS_KEEP_TIMING
|
|
runlevels = RUNLEVEL_GAME | RUNLEVEL_POSTGAME
|
|
///What time was it when we last ticked
|
|
var/previous_world_time = 0
|
|
|
|
/datum/controller/subsystem/processing/reagents/Initialize()
|
|
. = ..()
|
|
//So our first step isn't insane
|
|
previous_world_time = world.time
|
|
//Build GLOB lists - see holder.dm
|
|
build_chemical_reagent_list()
|
|
build_chemical_reactions_lists()
|
|
return
|
|
|
|
/datum/controller/subsystem/processing/reagents/fire(resumed = FALSE)
|
|
if (!resumed)
|
|
currentrun = processing.Copy()
|
|
//cache for sanic speed (lists are references anyways)
|
|
var/list/current_run = currentrun
|
|
|
|
//Attempt to realtime reactions in a way that doesn't make them overtly dangerous
|
|
var/delta_realtime = (world.time - previous_world_time)/10 //normalise to s from ds
|
|
previous_world_time = world.time
|
|
|
|
while(current_run.len)
|
|
var/datum/thing = current_run[current_run.len]
|
|
current_run.len--
|
|
if(QDELETED(thing))
|
|
stack_trace("Found qdeleted thing in [type], in the current_run list.")
|
|
processing -= thing
|
|
else if(thing.process(delta_realtime) == PROCESS_KILL) //we are realtime
|
|
// fully stop so that a future START_PROCESSING will work
|
|
STOP_PROCESSING(src, thing)
|
|
if (MC_TICK_CHECK)
|
|
return
|