mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-15 04:01:41 +00:00
169c42a262
* Refactors connect_loc_behalf into a component (#60678) See title. Also refactors caltrops into a component because they use connect_loc_behalf which requires them to hold the state. This also fixes COMPONENT_DUPE_SELECTIVE from just outright not working. connect_loc_behalf doesn't make sense as an element because it tries to hold states. There is also no way to maintain current behaviour and not have the states that it needs. Due to the fact that it tries to hold states, it means the code itself is a lot more buggy because it's a lot harder to successfully manage these states without runtimes or bugs. On metastation, there is only 2519 connect_loc_behalf components at roundstart. MrStonedOne has told me that datums take up this much space: image If we do the (oversimplified) math, there are only ever 5 variables that'll likely be changed on most connect_loc_behalf components at runtime: connections, tracked, signal_atom, parent, signal_procs This means that on metastation at roundstart, we take up this amount: (24 + 16 * 5) * 2519 = 261.97600 kilobytes This is not really significant and the benefits of moving this to a component greatly outweighs the memory cost. (Basically the memory cost is outweighed by the maint cost of tracking down issues with the thing. It's too buggy to be viable longterm basically) * Update glass.dm Co-authored-by: Watermelon914 <37270891+Watermelon914@users.noreply.github.com> Co-authored-by: Gandalf <jzo123@hotmail.com>
82 lines
2.8 KiB
Plaintext
82 lines
2.8 KiB
Plaintext
/// This component behaves similar to connect_loc, hooking into a signal on a tracked object's turf
|
|
/// It has the ability to react to that signal on behalf of a seperate listener however
|
|
/// This has great use, primarially for components, but it carries with it some overhead
|
|
/// So we do it seperately as it needs to hold state which is very likely to lead to bugs if it remains as an element.
|
|
/datum/component/connect_loc_behalf
|
|
dupe_mode = COMPONENT_DUPE_UNIQUE
|
|
|
|
/// An assoc list of signal -> procpath to register to the loc this object is on.
|
|
var/list/connections
|
|
|
|
var/atom/movable/tracked
|
|
|
|
var/atom/tracked_loc
|
|
|
|
/datum/component/connect_loc_behalf/Initialize(atom/movable/tracked, list/connections)
|
|
. = ..()
|
|
if (!istype(tracked))
|
|
return COMPONENT_INCOMPATIBLE
|
|
src.connections = connections
|
|
src.tracked = tracked
|
|
|
|
/datum/component/connect_loc_behalf/CheckDupeComponent(datum/component/component, atom/movable/tracked, list/connections)
|
|
if(src.tracked != tracked)
|
|
return FALSE
|
|
|
|
// Not equivalent. Checks if they are not the same list via shallow comparison.
|
|
if(!compare_list(src.connections, connections))
|
|
return FALSE
|
|
|
|
return TRUE
|
|
|
|
|
|
/datum/component/connect_loc_behalf/RegisterWithParent()
|
|
RegisterSignal(tracked, COMSIG_MOVABLE_MOVED, .proc/on_moved)
|
|
RegisterSignal(tracked, COMSIG_PARENT_QDELETING, .proc/handle_tracked_qdel)
|
|
update_signals()
|
|
|
|
/datum/component/connect_loc_behalf/UnregisterFromParent()
|
|
unregister_signals()
|
|
UnregisterSignal(tracked, list(
|
|
COMSIG_MOVABLE_MOVED,
|
|
COMSIG_PARENT_QDELETING,
|
|
))
|
|
|
|
tracked = null
|
|
|
|
/datum/component/connect_loc_behalf/proc/handle_tracked_qdel()
|
|
SIGNAL_HANDLER
|
|
qdel(src)
|
|
|
|
/datum/component/connect_loc_behalf/proc/update_signals()
|
|
unregister_signals()
|
|
//You may ask yourself, isn't this just silencing an error?
|
|
//The answer is yes, but there's no good cheap way to fix it
|
|
//What happens is the tracked object or hell the listener gets say, deleted, which makes targets[old_loc] return a null
|
|
//The null results in a bad index, because of course it does
|
|
//It's not a solvable problem though, since both actions, the destroy and the move, are sourced from the same signal send
|
|
//And sending a signal should be agnostic of the order of listeners
|
|
//So we need to either pick the order agnositic, or destroy safe
|
|
//And I picked destroy safe. Let's hope this is the right path!
|
|
if(isnull(tracked.loc))
|
|
return
|
|
|
|
tracked_loc = tracked.loc
|
|
|
|
for (var/signal in connections)
|
|
parent.RegisterSignal(tracked_loc, signal, connections[signal])
|
|
|
|
/datum/component/connect_loc_behalf/proc/unregister_signals()
|
|
if(isnull(tracked_loc))
|
|
return
|
|
|
|
for (var/signal in connections)
|
|
parent.UnregisterSignal(tracked_loc, signal)
|
|
|
|
tracked_loc = null
|
|
|
|
/datum/component/connect_loc_behalf/proc/on_moved(sigtype, atom/movable/tracked, atom/old_loc)
|
|
SIGNAL_HANDLER
|
|
update_signals()
|
|
|