mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-13 11:12:14 +00:00
eaf6c62f02
* Build Mode Preview + better help text (#76095) ## About The Pull Request Gives `Adv Build Mode` and `Fill` an item preview, and puts the help text for build mode modes into an examine block. https://github.com/tgstation/tgstation/assets/66640614/6751c721-6ddd-4761-8311-fb002ea905ac   ## Why It's Good For The Game It's good to see what you're doing. ## Changelog 🆑 Tattle admin: build mode help text is in an examine block admin: adv build mode and fill now have item previews /🆑 --------- Co-authored-by: tattle <article.disaster@ gmail.com> Co-authored-by: san7890 <the@ san7890.com> * Build Mode Preview + better help text --------- Co-authored-by: tattle <66640614+dragomagol@users.noreply.github.com> Co-authored-by: tattle <article.disaster@ gmail.com> Co-authored-by: san7890 <the@ san7890.com>
61 lines
2.0 KiB
Plaintext
61 lines
2.0 KiB
Plaintext
/datum/buildmode_mode/varedit
|
|
key = "edit"
|
|
// Varedit mode
|
|
var/varholder = null
|
|
var/valueholder = null
|
|
|
|
/datum/buildmode_mode/varedit/Destroy()
|
|
varholder = null
|
|
valueholder = null
|
|
return ..()
|
|
|
|
/datum/buildmode_mode/varedit/show_help(client/builder)
|
|
to_chat(builder, span_purple(examine_block(
|
|
"[span_bold("Select var(type) & value")] -> Right Mouse Button on buildmode button\n\
|
|
[span_bold("Set var(type) & value")] -> Left Mouse Button on turf/obj/mob\n\
|
|
[span_bold("Reset var's value")] -> Right Mouse Button on turf/obj/mob"))
|
|
)
|
|
|
|
/datum/buildmode_mode/varedit/Reset()
|
|
. = ..()
|
|
varholder = null
|
|
valueholder = null
|
|
|
|
/datum/buildmode_mode/varedit/change_settings(client/c)
|
|
varholder = input(c, "Enter variable name:" ,"Name", "name")
|
|
|
|
if(!vv_varname_lockcheck(varholder))
|
|
return
|
|
|
|
var/temp_value = c.vv_get_value()
|
|
if(isnull(temp_value["class"]))
|
|
Reset()
|
|
to_chat(c, span_notice("Variable unset."))
|
|
return
|
|
valueholder = temp_value["value"]
|
|
|
|
/datum/buildmode_mode/varedit/handle_click(client/c, params, obj/object)
|
|
var/list/modifiers = params2list(params)
|
|
|
|
if(isnull(varholder))
|
|
to_chat(c, span_warning("Choose a variable to modify first."))
|
|
return
|
|
if(LAZYACCESS(modifiers, LEFT_CLICK))
|
|
if(object.vars.Find(varholder))
|
|
if(object.vv_edit_var(varholder, valueholder) == FALSE)
|
|
to_chat(c, span_warning("Your edit was rejected by the object."))
|
|
return
|
|
log_admin("Build Mode: [key_name(c)] modified [object.name]'s [varholder] to [valueholder]")
|
|
else
|
|
to_chat(c, span_warning("[initial(object.name)] does not have a var called '[varholder]'"))
|
|
if(LAZYACCESS(modifiers, RIGHT_CLICK))
|
|
if(object.vars.Find(varholder))
|
|
var/reset_value = initial(object.vars[varholder])
|
|
if(object.vv_edit_var(varholder, reset_value) == FALSE)
|
|
to_chat(c, span_warning("Your edit was rejected by the object."))
|
|
return
|
|
log_admin("Build Mode: [key_name(c)] modified [object.name]'s [varholder] to [reset_value]")
|
|
else
|
|
to_chat(c, span_warning("[initial(object.name)] does not have a var called '[varholder]'"))
|
|
|