mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-10 09:42:29 +00:00
eaf6c62f02
* Build Mode Preview + better help text (#76095) ## About The Pull Request Gives `Adv Build Mode` and `Fill` an item preview, and puts the help text for build mode modes into an examine block. https://github.com/tgstation/tgstation/assets/66640614/6751c721-6ddd-4761-8311-fb002ea905ac   ## Why It's Good For The Game It's good to see what you're doing. ## Changelog 🆑 Tattle admin: build mode help text is in an examine block admin: adv build mode and fill now have item previews /🆑 --------- Co-authored-by: tattle <article.disaster@ gmail.com> Co-authored-by: san7890 <the@ san7890.com> * Build Mode Preview + better help text --------- Co-authored-by: tattle <66640614+dragomagol@users.noreply.github.com> Co-authored-by: tattle <article.disaster@ gmail.com> Co-authored-by: san7890 <the@ san7890.com>
61 lines
2.5 KiB
Plaintext
61 lines
2.5 KiB
Plaintext
/datum/buildmode_mode/basic
|
|
key = "basic"
|
|
|
|
/datum/buildmode_mode/basic/show_help(client/builder)
|
|
to_chat(builder, span_purple(examine_block(
|
|
"[span_bold("Construct / Upgrade")] -> Left Mouse Button\n\
|
|
[span_bold("Deconstruct / Delete / Downgrade")] -> Right Mouse Button\n\
|
|
[span_bold("R-Window")] -> Left Mouse Button + Ctrl\n\
|
|
[span_bold("Airlock")] -> Left Mouse Button + Alt \n\
|
|
\n\
|
|
Use the button in the upper left corner to change the direction of built objects."))
|
|
)
|
|
|
|
/datum/buildmode_mode/basic/handle_click(client/c, params, obj/object)
|
|
var/list/modifiers = params2list(params)
|
|
|
|
var/left_click = LAZYACCESS(modifiers, LEFT_CLICK)
|
|
var/right_click = LAZYACCESS(modifiers, RIGHT_CLICK)
|
|
var/alt_click = LAZYACCESS(modifiers, ALT_CLICK)
|
|
var/ctrl_click = LAZYACCESS(modifiers, CTRL_CLICK)
|
|
|
|
if(istype(object,/turf) && left_click && !alt_click && !ctrl_click)
|
|
var/turf/clicked_turf = object
|
|
if(isplatingturf(object))
|
|
clicked_turf.PlaceOnTop(/turf/open/floor/iron, flags = CHANGETURF_INHERIT_AIR)
|
|
else if(isfloorturf(object))
|
|
clicked_turf.PlaceOnTop(/turf/closed/wall)
|
|
else if(iswallturf(object))
|
|
clicked_turf.PlaceOnTop(/turf/closed/wall/r_wall)
|
|
else
|
|
clicked_turf.PlaceOnTop(/turf/open/floor/plating, flags = CHANGETURF_INHERIT_AIR) // Gotta do something
|
|
log_admin("Build Mode: [key_name(c)] built [clicked_turf] at [AREACOORD(clicked_turf)]")
|
|
return
|
|
else if(right_click)
|
|
log_admin("Build Mode: [key_name(c)] deleted [object] at [AREACOORD(object)]")
|
|
if(isturf(object))
|
|
var/turf/T = object
|
|
T.ScrapeAway(flags = CHANGETURF_INHERIT_AIR)
|
|
else if(isobj(object))
|
|
// SKYRAT EDIT -- BS delete sparks. Original was just qdel(object)
|
|
var/turf/T = get_turf(object)
|
|
qdel(object)
|
|
if(T && c.prefs.read_preference(/datum/preference/toggle/admin/delete_sparks))
|
|
playsound(T, 'sound/magic/Repulse.ogg', 100, 1)
|
|
var/datum/effect_system/spark_spread/quantum/sparks = new
|
|
sparks.set_up(10, 1, T)
|
|
sparks.attach(T)
|
|
sparks.start()
|
|
return
|
|
else if(istype(object,/turf) && alt_click && left_click)
|
|
log_admin("Build Mode: [key_name(c)] built an airlock at [AREACOORD(object)]")
|
|
new/obj/machinery/door/airlock(get_turf(object))
|
|
else if(istype(object,/turf) && ctrl_click && left_click)
|
|
var/obj/structure/window/reinforced/window
|
|
if(BM.build_dir in GLOB.diagonals)
|
|
window = new /obj/structure/window/reinforced/fulltile(get_turf(object))
|
|
else
|
|
window = new /obj/structure/window/reinforced(get_turf(object))
|
|
window.setDir(BM.build_dir)
|
|
log_admin("Build Mode: [key_name(c)] built a window at [AREACOORD(object)]")
|