mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-18 04:55:27 +00:00
f03084c1ca
## About The Pull Request FOV as it is currently implemented is incompatible* with wallening. I'm doin wallening, so we gotta redo things here. The issue is the masking of mobs. Wallening relies on sidemap (layering based off physical position), which only works on things on the same plane (because planes are basically sheets we render down onto) So rather then masking mobs, let's reuse the masking idea from old fov, and use it to cut out a bit of the game render plane, and blur/over-saturate the bit that's masked out. My hope is this makes things visible in light, but not as much in darkness, alongside making more vivid shit more easily seen (just like real life) Here's some videos, what follows after is the commits I care about (since I had to rip a bunch of planes to nothing, so the files changed tab might be a bit of a mess) Oh also I had to remove the darkness pref since the darkness is doing a lot of the heavy lifting now. I'm sorry. Edit: NEW FOV SPRITES! Thanks dongle your aviator glasses will guide us to a better future. https://github.com/tgstation/tgstation/assets/58055496/afa9eeb8-8b7b-4364-b0c0-7ac8070b5609 https://github.com/tgstation/tgstation/assets/58055496/0eff040c-8bf1-47e4-a4f3-dac56fb2ccc8 ## Commits I Care About [Implements something like fov, but without the planes as layers hell](a604c7b1c8) Rather then masking out mobs standing behind us, we use a combo color matrix and blur filter to make the stuff covered by fov harder to see. We achive this by splitting the game plane into two, masking both by fov (one normally and one inversely), and then applying effects to one of the two. I want to make the fov fullscreens more gradient, but as an effect this is a good start [Removes WALL_PLANE_UPPER by adding a WALL_PLANE overlay to material walls (init cost comes here)](2548933739) @Mothblocks see this. comment in commit explains further but uh, we need to draw material walls to the light mask plane so things actually can be seen on them, but we can't do that and also have them be big, so they get an overlay. Sorry, slight init time bump, about 0.5 seconds. I can kill it with wallening. [Moves SEETHROUGH_PLANE above ABOVE_GAME_PLANE](beec4c00e0) I don't think it actually wants to draw here @Time-Green I think this was you so pinging for opinion [Resprites FOV masks to be clean (and more consistent)](f02ad13696) [f02ad13](f02ad13696) This is 100% donglesplonge's work, he's spent a week or so going back and forth with me sharpening these to a mirror shine, real chill ## Why It's Good For The Game Walls are closing in ## Changelog 🆑 LemonInTheDark, Donglesplonge image: Redoes fov "mask" sprites. They're clean, have a very pleasant dithering effect, and look real fuckin good! del: Changed FOV, it no longer hides mobs, instead it blurs the hidden area, and makes it a bit darker/oversaturated /🆑 ###### * It's technically possible if we start using render targets to create 2 sets of sources but that's insane and we aren't doing it
175 lines
5.6 KiB
Plaintext
175 lines
5.6 KiB
Plaintext
/obj/structure/light_construct
|
|
name = "light fixture frame"
|
|
desc = "A light fixture under construction."
|
|
icon = 'icons/obj/lighting.dmi'
|
|
icon_state = "tube-construct-stage1"
|
|
anchored = TRUE
|
|
layer = WALL_OBJ_LAYER
|
|
max_integrity = 200
|
|
armor_type = /datum/armor/structure_light_construct
|
|
|
|
///Light construction stage (LIGHT_CONSTRUCT_EMPTY, LIGHT_CONSTRUCT_WIRED, LIGHT_CONSTRUCT_CLOSED)
|
|
var/stage = LIGHT_CONSTRUCT_EMPTY
|
|
///Type of fixture for icon state
|
|
var/fixture_type = "tube"
|
|
///Amount of sheets gained on deconstruction
|
|
var/sheets_refunded = 2
|
|
///Reference for light object
|
|
var/obj/machinery/light/new_light = null
|
|
///Reference for the internal cell
|
|
var/obj/item/stock_parts/cell/cell
|
|
///Can we support a cell?
|
|
var/cell_connectors = TRUE
|
|
|
|
/datum/armor/structure_light_construct
|
|
melee = 50
|
|
bullet = 10
|
|
laser = 10
|
|
fire = 80
|
|
acid = 50
|
|
|
|
/obj/structure/light_construct/Initialize(mapload, ndir, building)
|
|
. = ..()
|
|
if(building)
|
|
setDir(ndir)
|
|
find_and_hang_on_wall()
|
|
|
|
/obj/structure/light_construct/Destroy()
|
|
QDEL_NULL(cell)
|
|
return ..()
|
|
|
|
/obj/structure/light_construct/get_cell()
|
|
return cell
|
|
|
|
/obj/structure/light_construct/examine(mob/user)
|
|
. = ..()
|
|
switch(stage)
|
|
if(LIGHT_CONSTRUCT_EMPTY)
|
|
. += "It's an empty frame."
|
|
if(LIGHT_CONSTRUCT_WIRED)
|
|
. += "It's wired."
|
|
if(LIGHT_CONSTRUCT_CLOSED)
|
|
. += "The casing is closed."
|
|
if(cell_connectors)
|
|
if(cell)
|
|
. += "You see [cell] inside the casing."
|
|
else
|
|
. += "The casing has no power cell for backup power."
|
|
else
|
|
. += span_danger("This casing doesn't support power cells for backup power.")
|
|
|
|
/obj/structure/light_construct/attack_hand(mob/user, list/modifiers)
|
|
if(!cell)
|
|
return
|
|
user.visible_message(span_notice("[user] removes [cell] from [src]!"), span_notice("You remove [cell]."))
|
|
user.put_in_hands(cell)
|
|
cell.update_appearance()
|
|
cell = null
|
|
add_fingerprint(user)
|
|
|
|
/obj/structure/light_construct/attack_tk(mob/user)
|
|
if(!cell)
|
|
return
|
|
to_chat(user, span_notice("You telekinetically remove [cell]."))
|
|
var/obj/item/stock_parts/cell/cell_reference = cell
|
|
cell = null
|
|
cell_reference.forceMove(drop_location())
|
|
return cell_reference.attack_tk(user)
|
|
|
|
/obj/structure/light_construct/attackby(obj/item/tool, mob/user, params)
|
|
add_fingerprint(user)
|
|
if(istype(tool, /obj/item/stock_parts/cell))
|
|
if(!cell_connectors)
|
|
to_chat(user, span_warning("This [name] can't support a power cell!"))
|
|
return
|
|
if(HAS_TRAIT(tool, TRAIT_NODROP))
|
|
to_chat(user, span_warning("[tool] is stuck to your hand!"))
|
|
return
|
|
if(cell)
|
|
to_chat(user, span_warning("There is a power cell already installed!"))
|
|
return
|
|
if(user.temporarilyRemoveItemFromInventory(tool))
|
|
user.visible_message(span_notice("[user] hooks up [tool] to [src]."), \
|
|
span_notice("You add [tool] to [src]."))
|
|
playsound(src, 'sound/machines/click.ogg', 50, TRUE)
|
|
tool.forceMove(src)
|
|
cell = tool
|
|
add_fingerprint(user)
|
|
return
|
|
if(istype(tool, /obj/item/light))
|
|
to_chat(user, span_warning("This [name] isn't finished being setup!"))
|
|
return
|
|
|
|
switch(stage)
|
|
if(LIGHT_CONSTRUCT_EMPTY)
|
|
if(tool.tool_behaviour == TOOL_WRENCH)
|
|
if(cell)
|
|
to_chat(user, span_warning("You have to remove the cell first!"))
|
|
return
|
|
to_chat(user, span_notice("You begin deconstructing [src]..."))
|
|
if (tool.use_tool(src, user, 30, volume=50))
|
|
new /obj/item/stack/sheet/iron(drop_location(), sheets_refunded)
|
|
user.visible_message(span_notice("[user.name] deconstructs [src]."), \
|
|
span_notice("You deconstruct [src]."), span_hear("You hear a ratchet."))
|
|
playsound(src, 'sound/items/deconstruct.ogg', 75, TRUE)
|
|
qdel(src)
|
|
return
|
|
|
|
if(istype(tool, /obj/item/stack/cable_coil))
|
|
var/obj/item/stack/cable_coil/coil = tool
|
|
if(coil.use(1))
|
|
icon_state = "[fixture_type]-construct-stage2"
|
|
stage = LIGHT_CONSTRUCT_WIRED
|
|
user.visible_message(span_notice("[user.name] adds wires to [src]."), \
|
|
span_notice("You add wires to [src]."))
|
|
else
|
|
to_chat(user, span_warning("You need one length of cable to wire [src]!"))
|
|
return
|
|
if(LIGHT_CONSTRUCT_WIRED)
|
|
if(tool.tool_behaviour == TOOL_WRENCH)
|
|
to_chat(usr, span_warning("You have to remove the wires first!"))
|
|
return
|
|
|
|
if(tool.tool_behaviour == TOOL_WIRECUTTER)
|
|
stage = LIGHT_CONSTRUCT_EMPTY
|
|
icon_state = "[fixture_type]-construct-stage1"
|
|
new /obj/item/stack/cable_coil(drop_location(), 1, "red")
|
|
user.visible_message(span_notice("[user.name] removes the wiring from [src]."), \
|
|
span_notice("You remove the wiring from [src]."), span_hear("You hear clicking."))
|
|
tool.play_tool_sound(src, 100)
|
|
return
|
|
|
|
if(tool.tool_behaviour == TOOL_SCREWDRIVER)
|
|
user.visible_message(span_notice("[user.name] closes [src]'s casing."), \
|
|
span_notice("You close [src]'s casing."), span_hear("You hear screwing."))
|
|
tool.play_tool_sound(src, 75)
|
|
switch(fixture_type)
|
|
if("tube")
|
|
new_light = new /obj/machinery/light/built(loc)
|
|
if("bulb")
|
|
new_light = new /obj/machinery/light/small/built(loc)
|
|
new_light.setDir(dir)
|
|
transfer_fingerprints_to(new_light)
|
|
if(!QDELETED(cell))
|
|
new_light.cell = cell
|
|
cell.forceMove(new_light)
|
|
cell = null
|
|
qdel(src)
|
|
return
|
|
return ..()
|
|
|
|
/obj/structure/light_construct/blob_act(obj/structure/blob/attacking_blob)
|
|
if(attacking_blob && attacking_blob.loc == loc)
|
|
qdel(src)
|
|
|
|
/obj/structure/light_construct/deconstruct(disassembled = TRUE)
|
|
if(!(obj_flags & NO_DECONSTRUCTION))
|
|
new /obj/item/stack/sheet/iron(loc, sheets_refunded)
|
|
qdel(src)
|
|
|
|
/obj/structure/light_construct/small
|
|
name = "small light fixture frame"
|
|
icon_state = "bulb-construct-stage1"
|
|
fixture_type = "bulb"
|
|
sheets_refunded = 1
|