cyberpresidentvanellope/Bubberstation
1
0
Fork 0
mirror of https://github.com/Bubberstation/Bubberstation.git synced 2026-01-16 03:56:20 +00:00
Code Issues Packages Projects Releases Wiki Activity
Files
d3c19afd9e2ac4e0c2555daaf660250e20f3dfa3
Bubberstation/code/modules/research/rdconsole.dm
John Willard 9ac81e1a64 New station trait job: Human AI (#81681) 
## About The Pull Request

This PR does many things, I'll try to explain the basic/background stuff
to the main thing first:

1. Adds a new remote that allows a human to function like an AI. It
controls a fly that will fly around the station slowly, and when it
reaches a machine then the person can interact with it as if they were
an AI. This required changing a lot of silicon/AI checks with one that
also checks for this remote, and some messing with shared ui state.
2. Moves req_access from the obj and bot to ``/atom/movable`` which lets
it be shared between the two, no more copy-paste and one side lacking
features/checks/signals the other has.
3. Adds a check for AI config for AI-related station traits, which was
lacking prior

Now for the good part...
Adds a new station trait that replaces the AI with a Human.
This person is equipped with an AI headset (including Binary), an
advanced camera console, an omni door wand, the machine controller, and
their laws.
They are immune to the SAT's turrets (even if set to target borgs) and
are slow outside of the SAT, mimicing the actions of the AI.

They interact with the world through their advanced camera console,
which allows them to do most AI stuff needed, and the holopad they can
connect to without having to ring first (like Command can).

They are given a paper with the laws they must follow, but since they
are human they are able to bend it. Cyborgs that run the default lawset
are "slaved" to them via an unremovable law 0, so the Human AI can bend
the laws if they really need to (for their own survival n such), and
make the cyborgs obey their commands above laws, but in general this
shouldn't be a frequent occurrence. This does take into account the
unique AI trait, so it's not guaranteed Asimov.

When this station trait rolls, all Intellicards, AI uploads, and AI core
boards are destroyed and are unresearchable. They can be spawned by
admins in-game if necessary. Maybe in the future we can also exclude
Oldstation from this but I haven't really decided.

Extra perks:

Human AI spawns with a Robotic voicebox (unless they are a body purist)
and teleport blocking implant, so they can't use teleporters to bypass
their on-station slowdown.
They also have an infinite laser pointer that can be used to blind
through their camera console. This is unfortunately nerfed from the
recent borg balance PR that removed its stun. This was meant to be the
alternative to no longer being able to permanently lock borgs down like
AIs can (or more than one, for that matter).
They aren't affected by Roburgers, Acid, and Fuel's toxicity.
Bots salute them like they do Beepsky (which is now a trait)
They spawn with SyndEye to replace the AI's tracking ability
They do not have a bank account

### The machine remote

The machine remote has a little fly in it that flies to the machines it
is pointed to, working as the arms and legs of the Human AI. It scans
the machine and punches in the action the AI does, and is how the AI
accesses basically anything. This fly slowly moves from one machine to
the next, and can be recalled with Alt Click.
It works on machines and bots.

### Video (Low quality to fit Github)


https://github.com/tgstation/tgstation/assets/53777086/e16509f8-8bed-42b5-9fbf-7e37165a11e8

## Why It's Good For The Game

I've seen a funny screenshot one day of a person replacing the AI by
using a bunch of door remotes, camera console, crew monitoring console,
and a few other things. I've been thinking about that for a few years
and really wanted to make it official if not easier to make possible,
because it is an incredibly funny interaction.
This makes it a reality, and while they aren't as powerful as regular
AIs, I think it makes for better and funnier in-game moments. With the
same weight as Cargorilla (1), I hope this wouldn't be rolling too often
and ruin rounds, but instead show off the different capabilities that
Humans and AIs can do, to do the job of an AI. You win some you lose
some.

## Changelog

🆑 JohnFulpWillard, Tattax
add: Adds a new station trait job: The Human AI.
/🆑

---------

Co-authored-by: MrMelbert <51863163+MrMelbert@users.noreply.github.com>
2024-03-09 23:48:39 +01:00

365 lines
12 KiB
Plaintext
Raw Blame History

#define RND_TECH_DISK "tech"
#define RND_DESIGN_DISK "design"
/*
Research and Development (R&D) Console
This is the main work horse of the R&D system. It contains the menus/controls for the Destructive Analyzer, Protolathe, and Circuit
imprinter.
Basic use: When it first is created, it will attempt to link up to related devices within 3 squares. It'll only link up if they
aren't already linked to another console. Any consoles it cannot link up with (either because all of a certain type are already
linked or there aren't any in range), you'll just not have access to that menu. In the settings menu, there are menu options that
allow a player to attempt to re-sync with nearby consoles. You can also force it to disconnect from a specific console.
The only thing that requires ordnance access is locking and unlocking the console on the settings menu.
Nothing else in the console has ID requirements.
*/
/obj/machinery/computer/rdconsole
name = "R&D Console"
desc = "A console used to interface with R&D tools."
icon_screen = "rdcomp"
icon_keyboard = "rd_key"
circuit = /obj/item/circuitboard/computer/rdconsole
req_access = list(ACCESS_RESEARCH) // Locking and unlocking the console requires research access
/// Reference to global science techweb
var/datum/techweb/stored_research
/// The stored technology disk, if present
var/obj/item/disk/tech_disk/t_disk
/// The stored design disk, if present
var/obj/item/disk/design_disk/d_disk
/// Determines if the console is locked, and consequently if actions can be performed with it
var/locked = FALSE
/// Used for compressing data sent to the UI via static_data as payload size is of concern
var/id_cache = list()
/// Sequence var for the id cache
var/id_cache_seq = 1
/proc/CallMaterialName(ID)
if (istype(ID, /datum/material))
var/datum/material/material = ID
return material.name
else if(GLOB.chemical_reagents_list[ID])
var/datum/reagent/reagent = GLOB.chemical_reagents_list[ID]
return reagent.name
return ID
/obj/machinery/computer/rdconsole/LateInitialize()
. = ..()
if(!CONFIG_GET(flag/no_default_techweb_link) && !stored_research)
CONNECT_TO_RND_SERVER_ROUNDSTART(stored_research, src)
if(stored_research)
stored_research.consoles_accessing += src
/obj/machinery/computer/rdconsole/Destroy()
if(stored_research)
stored_research.consoles_accessing -= src
stored_research = null
if(t_disk)
t_disk.forceMove(get_turf(src))
t_disk = null
if(d_disk)
d_disk.forceMove(get_turf(src))
d_disk = null
return ..()
/obj/machinery/computer/rdconsole/attackby(obj/item/D, mob/user, params)
//Loading a disk into it.
if(istype(D, /obj/item/disk))
if(istype(D, /obj/item/disk/tech_disk))
if(t_disk)
to_chat(user, span_warning("A technology disk is already loaded!"))
return
if(!user.transferItemToLoc(D, src))
to_chat(user, span_warning("[D] is stuck to your hand!"))
return
t_disk = D
else if (istype(D, /obj/item/disk/design_disk))
if(d_disk)
to_chat(user, span_warning("A design disk is already loaded!"))
return
if(!user.transferItemToLoc(D, src))
to_chat(user, span_warning("[D] is stuck to your hand!"))
return
d_disk = D
else
to_chat(user, span_warning("Machine cannot accept disks in that format."))
return
to_chat(user, span_notice("You insert [D] into \the [src]!"))
return
return ..()
/obj/machinery/computer/rdconsole/multitool_act(mob/living/user, obj/item/multitool/tool)
. = ..()
if(!QDELETED(tool.buffer) && istype(tool.buffer, /datum/techweb))
stored_research = tool.buffer
return TRUE
/obj/machinery/computer/rdconsole/proc/research_node(id, mob/user)
if(!stored_research || !stored_research.available_nodes[id] || stored_research.researched_nodes[id])
say("Node unlock failed: Either no techweb is found, node is already researched or is not available!")
return FALSE
var/datum/techweb_node/TN = SSresearch.techweb_node_by_id(id)
if(!istype(TN))
say("Node unlock failed: Unknown error.")
return FALSE
var/list/price = TN.get_price(stored_research)
if(stored_research.can_afford(price))
user.investigate_log("researched [id]([json_encode(price)]) on techweb id [stored_research.id].", INVESTIGATE_RESEARCH)
if(istype(stored_research, /datum/techweb/science))
SSblackbox.record_feedback("associative", "science_techweb_unlock", 1, list("id" = "[id]", "name" = TN.display_name, "price" = "[json_encode(price)]", "time" = SQLtime()))
if(stored_research.research_node_id(id))
say("Successfully researched [TN.display_name].")
var/logname = "Unknown"
if(HAS_AI_ACCESS(user))
logname = "AI [user.name]"
if(iscyborg(user))
logname = "CYBORG [user.name]"
if(iscarbon(user))
var/obj/item/card/id/idcard = user.get_active_held_item()
if(istype(idcard))
logname = "[idcard.registered_name]"
if(ishuman(user))
var/mob/living/carbon/human/H = user
var/obj/item/I = H.wear_id
if(istype(I))
var/obj/item/card/id/ID = I.GetID()
if(istype(ID))
logname = "[ID.registered_name]"
stored_research.research_logs += list(list(
"node_name" = TN.display_name,
"node_cost" = price["General Research"],
"node_researcher" = logname,
"node_research_location" = "[get_area(src)] ([src.x],[src.y],[src.z])",
))
return TRUE
else
say("Failed to research node: Internal database error!")
return FALSE
say("Not enough research points...")
return FALSE
/obj/machinery/computer/rdconsole/emag_act(mob/user, obj/item/card/emag/emag_card)
. = ..()
if (obj_flags & EMAGGED)
return
balloon_alert(user, "security protocols disabled")
playsound(src, SFX_SPARKS, 75, TRUE, SHORT_RANGE_SOUND_EXTRARANGE)
obj_flags |= EMAGGED
locked = FALSE
return TRUE
/obj/machinery/computer/rdconsole/ui_interact(mob/user, datum/tgui/ui = null)
. = ..()
ui = SStgui.try_update_ui(user, src, ui)
if (!ui)
ui = new(user, src, "Techweb", name)
ui.open()
/obj/machinery/computer/rdconsole/ui_assets(mob/user)
return list(
get_asset_datum(/datum/asset/spritesheet/research_designs),
)
// heavy data from this proc should be moved to static data when possible
/obj/machinery/computer/rdconsole/ui_data(mob/user)
var/list/data = list()
data["stored_research"] = !!stored_research
data["locked"] = locked
if(!stored_research) //lack of a research node is all we care about.
return data
data += list(
"nodes" = list(),
"experiments" = list(),
"researched_designs" = stored_research.researched_designs,
"points" = stored_research.research_points,
"points_last_tick" = stored_research.last_bitcoins,
"web_org" = stored_research.organization,
"sec_protocols" = !(obj_flags & EMAGGED),
"t_disk" = null,
"d_disk" = null,
)
if (t_disk)
data["t_disk"] = list (
"stored_research" = t_disk.stored_research.researched_nodes,
)
if (d_disk)
data["d_disk"] = list("blueprints" = list())
for (var/datum/design/D in d_disk.blueprints)
data["d_disk"]["blueprints"] += D.id
// Serialize all nodes to display
for(var/v in stored_research.tiers)
var/datum/techweb_node/n = SSresearch.techweb_node_by_id(v)
// Ensure node is supposed to be visible
if (stored_research.hidden_nodes[v])
continue
data["nodes"] += list(list(
"id" = n.id,
"can_unlock" = stored_research.can_unlock_node(n),
"tier" = stored_research.tiers[n.id],
))
// Get experiments and serialize them
var/list/exp_to_process = stored_research.available_experiments.Copy()
for (var/e in stored_research.completed_experiments)
exp_to_process += stored_research.completed_experiments[e]
for (var/e in exp_to_process)
var/datum/experiment/ex = e
data["experiments"][ex.type] = list(
"name" = ex.name,
"description" = ex.description,
"tag" = ex.exp_tag,
"progress" = ex.check_progress(),
"completed" = ex.completed,
"performance_hint" = ex.performance_hint,
)
return data
/**
* Compresses an ID to an integer representation using the id_cache, used for deduplication
* in sent JSON payloads
*
* Arguments:
* * id - the ID to compress
*/
/obj/machinery/computer/rdconsole/proc/compress_id(id)
if (!id_cache[id])
id_cache[id] = id_cache_seq
id_cache_seq += 1
return id_cache[id]
/obj/machinery/computer/rdconsole/ui_static_data(mob/user)
. = list(
"static_data" = list(),
"point_types_abbreviations" = SSresearch.point_types,
)
// Build node cache...
// Note this looks a bit ugly but its to reduce the size of the JSON payload
// by the greatest amount that we can, as larger JSON payloads result in
// hanging when the user opens the UI
var/node_cache = list()
for (var/node_id in SSresearch.techweb_nodes)
var/datum/techweb_node/node = SSresearch.techweb_nodes[node_id] || SSresearch.error_node
var/compressed_id = "[compress_id(node.id)]"
node_cache[compressed_id] = list(
"name" = node.display_name,
"description" = node.description
)
if (LAZYLEN(node.research_costs))
node_cache[compressed_id]["costs"] = list()
for (var/node_cost in node.research_costs)
node_cache[compressed_id]["costs"]["[compress_id(node_cost)]"] = node.research_costs[node_cost]
if (LAZYLEN(node.prereq_ids))
node_cache[compressed_id]["prereq_ids"] = list()
for (var/prerequisite_node in node.prereq_ids)
node_cache[compressed_id]["prereq_ids"] += compress_id(prerequisite_node)
if (LAZYLEN(node.design_ids))
node_cache[compressed_id]["design_ids"] = list()
for (var/unlocked_design in node.design_ids)
node_cache[compressed_id]["design_ids"] += compress_id(unlocked_design)
if (LAZYLEN(node.unlock_ids))
node_cache[compressed_id]["unlock_ids"] = list()
for (var/unlocked_node in node.unlock_ids)
node_cache[compressed_id]["unlock_ids"] += compress_id(unlocked_node)
if (LAZYLEN(node.required_experiments))
node_cache[compressed_id]["required_experiments"] = node.required_experiments
if (LAZYLEN(node.discount_experiments))
node_cache[compressed_id]["discount_experiments"] = node.discount_experiments
// Build design cache
var/design_cache = list()
var/datum/asset/spritesheet/research_designs/spritesheet = get_asset_datum(/datum/asset/spritesheet/research_designs)
var/size32x32 = "[spritesheet.name]32x32"
for (var/design_id in SSresearch.techweb_designs)
var/datum/design/design = SSresearch.techweb_designs[design_id] || SSresearch.error_design
var/compressed_id = "[compress_id(design.id)]"
var/size = spritesheet.icon_size_id(design.id)
design_cache[compressed_id] = list(
design.name,
"[size == size32x32 ? "" : "[size] "][design.id]"
)
// Ensure id cache is included for decompression
var/flat_id_cache = list()
for (var/id in id_cache)
flat_id_cache += id
.["static_data"] = list(
"node_cache" = node_cache,
"design_cache" = design_cache,
"id_cache" = flat_id_cache,
)
/obj/machinery/computer/rdconsole/ui_act(action, list/params)
. = ..()
if (.)
return
add_fingerprint(usr)
// Check if the console is locked to block any actions occuring
if (locked && action != "toggleLock")
say("Console is locked, cannot perform further actions.")
return TRUE
switch (action)
if ("toggleLock")
if(obj_flags & EMAGGED)
to_chat(usr, span_boldwarning("Security protocol error: Unable to access locking protocols."))
return TRUE
if(allowed(usr))
locked = !locked
else
to_chat(usr, span_boldwarning("Unauthorized Access."))
return TRUE
if ("researchNode")
research_node(params["node_id"], usr)
return TRUE
if ("ejectDisk")
eject_disk(params["type"])
return TRUE
if ("uploadDisk")
if (params["type"] == RND_DESIGN_DISK)
if(QDELETED(d_disk))
say("No design disk inserted!")
return TRUE
for(var/D in d_disk.blueprints)
if(D)
stored_research.add_design(D, TRUE)
say("Uploading blueprints from disk.")
d_disk.on_upload(stored_research)
return TRUE
if (params["type"] == RND_TECH_DISK)
if (QDELETED(t_disk))
say("No tech disk inserted!")
return TRUE
say("Uploading technology disk.")
t_disk.stored_research.copy_research_to(stored_research)
return TRUE
//Tech disk-only action.
if ("loadTech")
if(QDELETED(t_disk))
say("No tech disk inserted!")
return
stored_research.copy_research_to(t_disk.stored_research)
say("Downloading to technology disk.")
return TRUE
/obj/machinery/computer/rdconsole/proc/eject_disk(type)
if(type == RND_DESIGN_DISK && d_disk)
d_disk.forceMove(get_turf(src))
d_disk = null
if(type == RND_TECH_DISK && t_disk)
t_disk.forceMove(get_turf(src))
t_disk = null
#undef RND_TECH_DISK
#undef RND_DESIGN_DISK
Reference in New Issue View Git Blame Copy Permalink