Adds laundry basket

Conflicts:
	icons/mob/items/lefthand.dmi
	icons/mob/items/righthand.dmi

code/game/objects/items/weapons/storage/laundry_basket.dm

@@ -0,0 +1,87 @@
+// -----------------------------
+//        Laundry Basket
+// -----------------------------
+// An item designed for hauling the belongings of a character.
+// So this cannot be abused for other uses, we make it two-handed and inable to have its storage looked into.
+/obj/item/weapon/storage/laundry_basket
+	name = "laundry basket"
+	icon = 'icons/obj/janitor.dmi'
+	icon_state = "laundry-empty"
+	item_state = "laundry"
+	desc = "The peak of thousands of years of laundry evolution."
+
+	w_class = 5
+	max_w_class = 4
+	max_storage_space = 25 //20 for clothes + a bit of additional space for non-clothing items that were worn on body
+	storage_slots = 14
+	use_to_pickup = 1
+	allow_quick_empty = 1
+	allow_quick_gather = 1
+	collection_mode = 1
+	var/linked
+
+
+/obj/item/weapon/storage/laundry_basket/attack_hand(mob/user as mob)
+	if(ishuman(user))
+		var/mob/living/carbon/human/H = user
+		var/obj/item/organ/external/temp = H.get_organ("r_hand")
+		if (user.hand)
+			temp = H.get_organ("l_hand")
+		if(!temp)
+			user << "<span class='warning'>You need two hands to pick this up!</span>"
+			return
+
+	if(user.get_inactive_hand())
+		user << "<span class='warning'>You need your other hand to be empty</span>"
+		return
+	return ..()
+
+/obj/item/weapon/storage/laundry_basket/attack_self(mob/user as mob)
+	var/turf/T = get_turf(user)
+	user << "<span class='notice'>You dump the [src]'s contents onto \the [T].</span>"
+	return ..()
+
+/obj/item/weapon/storage/laundry_basket/pickup(mob/user)
+	var/obj/item/weapon/storage/laundry_basket/offhand/O = new(user)
+	O.name = "[name] - second hand"
+	O.desc = "Your second grip on the [name]."
+	O.linked = src
+	user.put_in_inactive_hand(O)
+	linked = O
+	return
+
+/obj/item/weapon/storage/laundry_basket/update_icon()
+	if(contents.len)
+		icon_state = "laundry-full"
+	else
+		icon_state = "laundry-empty"
+	return
+
+
+/obj/item/weapon/storage/laundry_basket/MouseDrop(obj/over_object as obj)
+	if(over_object == usr)
+		return
+	else
+		return ..()
+
+/obj/item/weapon/storage/laundry_basket/dropped(mob/user as mob)
+	qdel(linked)
+	return ..()
+
+/obj/item/weapon/storage/laundry_basket/show_to(mob/user as mob)
+	return
+
+/obj/item/weapon/storage/laundry_basket/open(mob/user as mob)
+
+
+//Offhand
+/obj/item/weapon/storage/laundry_basket/offhand
+	icon = 'icons/obj/weapons.dmi'
+	icon_state = "offhand"
+	name = "second hand"
+	use_to_pickup = 0
+
+/obj/item/weapon/storage/laundry_basket/offhand/dropped(mob/user as mob)
+	user.drop_from_inventory(linked)
+	return
+

code/game/objects/structures/crates_lockers/closets.dm

@@ -217,6 +217,15 @@
 				M.show_message("<span class='notice'>\The [src] has been cut apart by [user] with \the [WT].</span>", 3, "You hear welding.", 2)
 			qdel(src)
 			return
+		if(istype(W, /obj/item/weapon/storage/laundry_basket) && W.contents.len)
+			var/obj/item/weapon/storage/laundry_basket/LB = W
+			var/turf/T = get_turf(src)
+			for(var/obj/item/I in LB.contents)
+				LB.remove_from_storage(I, T)
+			user.visible_message("<span class='notice'>[user] empties \the [LB] into \the [src].</span>", \
+								 "<span class='notice'>You empty \the [LB] into \the [src].</span>", \
+								 "<span class='notice'>You hear rustling of clothes.</span>")
+			return
 		if(isrobot(user))
 			return
 		if(W.loc != user) // This should stop mounted modules ending up outside the module.

code/game/objects/structures/crates_lockers/closets/secure/secure_closets.dm

@@ -65,6 +65,8 @@
 
 /obj/structure/closet/secure_closet/attackby(obj/item/weapon/W as obj, mob/user as mob)
 	if(src.opened)
+		if(istype(W, /obj/item/weapon/storage/laundry_basket))
+			return ..(W,user)
 		if(istype(W, /obj/item/weapon/grab))
 			var/obj/item/weapon/grab/G = W
 			if(src.large)

polaris.dme

@@ -734,6 +734,7 @@
 #include "code\game\objects\items\weapons\storage\fancy.dm"
 #include "code\game\objects\items\weapons\storage\firstaid.dm"
 #include "code\game\objects\items\weapons\storage\internal.dm"
+#include "code\game\objects\items\weapons\storage\laundry_basket.dm"
 #include "code\game\objects\items\weapons\storage\lockbox.dm"
 #include "code\game\objects\items\weapons\storage\misc.dm"
 #include "code\game\objects\items\weapons\storage\secure.dm"