CHOMPstation/code/game/objects/items/weapons/flamethrower.dm

/obj/item/weapon/flamethrower
	name = "flamethrower"
	desc = "You are a firestarter!"
	icon = 'icons/obj/flamethrower.dmi'
	icon_state = "flamethrowerbase"
	item_icons = list(
			slot_l_hand_str = 'icons/mob/items/lefthand_guns.dmi',
			slot_r_hand_str = 'icons/mob/items/righthand_guns.dmi',
			)
	item_state = "flamethrower_0"
	flags = CONDUCT
	force = 3.0
	throwforce = 10.0
	throw_speed = 1
	throw_range = 5
	w_class = ITEMSIZE_NORMAL
	origin_tech = list(TECH_COMBAT = 1, TECH_PHORON = 1)
	matter = list(DEFAULT_WALL_MATERIAL = 500)
	var/status = 0
	var/throw_amount = 100
	var/lit = 0	//on or off
	var/operating = 0//cooldown
	var/turf/previousturf = null
	var/obj/item/weapon/weldingtool/weldtool = null
	var/obj/item/device/assembly/igniter/igniter = null
	//CHOMPStation Edit Start TFF 14/11/19 - Port Citadel Flamethrower fix
	var/obj/item/weapon/reagent_containers/glass/beaker/beaker = null
	var/cooldown
	//CHOMPStation Edit End

/obj/item/weapon/flamethrower/Destroy()
	qdel_null(weldtool)
	qdel_null(igniter)
	//CHOMPStation Edit Start TFF 14/11/19 - Port Citadel Flamethrower fix
	qdel_null(beaker)
	//CHOMPStation Edit End
	. = ..()

/obj/item/weapon/flamethrower/process()
	if(!lit)
		processing_objects.Remove(src)
		return null
	var/turf/location = loc
	if(istype(location, /mob/))
		var/mob/living/M = location
		if(M.item_is_in_hands(src))
			location = M.loc
	if(isturf(location)) //start a fire if possible
		location.hotspot_expose(700, 2)
	return


/obj/item/weapon/flamethrower/update_icon()
	overlays.Cut()
	if(igniter)
		overlays += "+igniter[status]"
	//CHOMPStation Edit Start TFF 14/11/19 - Port Citadel Flamethrower fix
	if(beaker)
	//CHOMPStation Edit End
		overlays += "+ptank"
	if(lit)
		overlays += "+lit"
		item_state = "flamethrower_1"
	else
		item_state = "flamethrower_0"
	return

/obj/item/weapon/flamethrower/afterattack(atom/target, mob/user, proximity)
	if(world.time < cooldown)
		return
	if(proximity) return
	// Make sure our user is still holding us
	if(user && user.get_active_hand() == src)
		var/turf/target_turf = get_turf(target)
		if(target_turf)
			var/turflist = getline(user, target_turf)
			flame_turf(turflist)
	cooldown = world.time + 1.5 SECONDS

/obj/item/weapon/flamethrower/attackby(obj/item/W as obj, mob/user as mob)
	if(user.stat || user.restrained() || user.lying)	return
	if(iswrench(W) && !status)//Taking this apart
		var/turf/T = get_turf(src)
		if(weldtool)
			weldtool.loc = T
			weldtool = null
		if(igniter)
			igniter.loc = T
			igniter = null
		//CHOMPStation Edit Start TFF 14/11/19 - Port Citadel Flamethrower fix
		if(beaker)
			beaker.loc = T
			beaker = null
		//CHOMPStation Edit End
		new /obj/item/stack/rods(T)
		qdel(src)
		return

	if(isscrewdriver(W) && igniter && !lit)
		status = !status
		user << "<span class='notice'>[igniter] is now [status ? "secured" : "unsecured"]!</span>"
		update_icon()
		return

	if(isigniter(W))
		var/obj/item/device/assembly/igniter/I = W
		if(I.secured)	return
		if(igniter)		return
		user.drop_item()
		I.loc = src
		igniter = I
		update_icon()
		return

	//CHOMPStation Edit Start TFF 14/11/19 - Port Citadel Flamethrower fix
	if(istype(W,/obj/item/weapon/reagent_containers/glass/beaker))
		if(beaker)
			user << "<span class='notice'>There is a beaker already loaded!!</span>"
			return
		user.drop_item()
		beaker = W
	//CHOMPStation Edit End
		W.loc = src
		update_icon()
		return
	//CHOMPStation Removal Start TFF 14/11/19 - Port Citadel Flamethrower fix
/*
	if(istype(W, /obj/item/device/analyzer))
		var/obj/item/device/analyzer/A = W
		A.analyze_gases(src, user)
		return
*/
	..()
	return


/obj/item/weapon/flamethrower/attack_self(mob/user as mob)
	if(user.stat || user.restrained() || user.lying)	return
	user.set_machine(src)
	//CHOMPStation Edit Start TFF 14/11/19 - Port Citadel Flamethrower fix
	if(!beaker)
		user << "<span class='notice'>Attach a beaker first!</span>"
		return
	var/dat = text("<TT><B>Flamethrower (<A HREF='?src=\ref[src];light=1'>[lit ? "<font color='red'>Lit</font>" : "Unlit"]</a>)</B>\n<A HREF='?src=\ref[src];remove=1'>Remove beaker</A> - <A HREF='?src=\ref[src];close=1'>Close</A></TT>")
	//CHOMPStation Edit End
	user << browse(dat, "window=flamethrower;size=600x300")
	onclose(user, "flamethrower")
	return


/obj/item/weapon/flamethrower/Topic(href,href_list[])
	if(href_list["close"])
		usr.unset_machine()
		usr << browse(null, "window=flamethrower")
		return
	if(usr.stat || usr.restrained() || usr.lying)	return
	usr.set_machine(src)
	if(href_list["light"])
		//CHOMPStation Edit Start TFF 14/11/19 - Port Citadel Flamethrower fix
		if(!beaker)
			return
		//CHOMPStation Edit End
		if(!status)	return
		lit = !lit
		if(lit)
			processing_objects.Add(src)
	if(href_list["remove"])
		//CHOMPStation Edit Start TFF 14/11/19 - Port Citadel Flamethrower fix
		if(!beaker)	return
		usr.put_in_hands(beaker)
		beaker = null
		//CHOMPStation Edit End
		lit = 0
		usr.unset_machine()
		usr << browse(null, "window=flamethrower")
	for(var/mob/M in viewers(1, loc))
		if((M.client && M.machine == src))
			attack_self(M)
	update_icon()
	return


//Called from turf.dm turf/dblclick
/obj/item/weapon/flamethrower/proc/flame_turf(turflist)
	if(!lit || operating)	return
	operating = 1
	for(var/turf/T in turflist)
		if(T.density || istype(T, /turf/space))
			break
		if(!previousturf && length(turflist)>1)
			previousturf = get_turf(src)
			continue	//so we don't burn the tile we be standin on
		if(previousturf && LinkBlocked(previousturf, T))
			break
		ignite_turf(T)
		sleep(1)
	previousturf = null
	operating = 0
	for(var/mob/M in viewers(1, loc))
		if((M.client && M.machine == src))
			attack_self(M)
	//remove fuel now
	return


/obj/item/weapon/flamethrower/proc/ignite_turf(turf/target)
//CHOMPStation Edit Start TFF 14/11/19 - Port Citadel Flamethrower fix
	//>flamethrowers using gas
	//Why?
	if(!beaker)
		return
	if(!beaker.reagents.has_reagent("fuel", 5))
		return
	new/obj/effect/decal/cleanable/liquid_fuel/flamethrower_fuel(target,get_dir(loc,target))
	target.hotspot_expose(500)
	for(var/mob/living/carbon/human/M in target)
		to_chat(M, "<span class='warning'>The fuel ignites you!</span>")
		M.adjust_fire_stacks(2)
		M.IgniteMob()
	for(var/mob/living/simple_animal/S in target) //also kills simple things.
		S.health -= 10
	for(var/obj/effect/plant/V in target)
		qdel(V)
	beaker.reagents.remove_reagent("fuel", 5)
//CHOMPStation Edit End
	return

/obj/item/weapon/flamethrower/full/New(var/loc)
	..()
	weldtool = new /obj/item/weapon/weldingtool(src)
	weldtool.status = 0
	igniter = new /obj/item/device/assembly/igniter(src)
	igniter.secured = 0
	status = 1
	update_icon()
	return