Merge pull request #1371 from ArchieBeepBoop/bobross

Ports: Painting - Experimental

code/__DEFINES/vv.dm

@@ -121,3 +121,6 @@
 
 // misc
 #define VV_HK_SPACEVINE_PURGE "spacevine_purge"
+
+// paintings
+#define VV_HK_REMOVE_PAINTING "remove_painting"

code/controllers/subsystem/persistence.dm

@@ -18,6 +18,8 @@ SUBSYSTEM_DEF(persistence)
 	var/list/picture_logging_information = list()
 	var/list/obj/structure/sign/picture_frame/photo_frames
 	var/list/obj/item/storage/photo_album/photo_albums
+	var/list/obj/structure/sign/painting/painting_frames = list()
+	var/list/paintings = list()
 
 /datum/controller/subsystem/persistence/Initialize()
 	LoadSatchels()
@@ -208,6 +210,7 @@ SUBSYSTEM_DEF(persistence)
 	if(CONFIG_GET(flag/use_antag_rep))
 		CollectAntagReputation()
 	SaveRandomizedRecipes()
+	SavePaintings()
 
 /datum/controller/subsystem/persistence/proc/GetPhotoAlbums()
 	var/album_path = file("data/photo_albums.json")
@@ -413,3 +416,19 @@ SUBSYSTEM_DEF(persistence)
 
 	fdel(json_file)
 	WRITE_FILE(json_file, json_encode(file_data))
+
+/datum/controller/subsystem/persistence/proc/LoadPaintings()
+	var/json_file = file("data/paintings.json")
+	if(fexists(json_file))
+		paintings = json_decode(file2text(json_file))
+
+	for(var/obj/structure/sign/painting/P in painting_frames)
+		P.load_persistent()
+
+/datum/controller/subsystem/persistence/proc/SavePaintings()
+	for(var/obj/structure/sign/painting/P in painting_frames)
+		P.save_persistent()
+
+	var/json_file = file("data/paintings.json")
+	fdel(json_file)
+	WRITE_FILE(json_file, json_encode(paintings))

code/datums/components/art.dm

@@ -0,0 +1,56 @@
+
+#define BAD_ART 12.5
+#define GOOD_ART 25
+#define GREAT_ART 50
+
+/datum/component/art
+	var/impressiveness = 0
+
+/datum/component/art/Initialize(impress)
+	impressiveness = impress
+	if(isobj(parent))
+		RegisterSignal(parent, COMSIG_PARENT_EXAMINE, .proc/on_obj_examine)
+	else
+		RegisterSignal(parent, COMSIG_PARENT_EXAMINE, .proc/on_other_examine)
+	if(isstructure(parent))
+		RegisterSignal(parent, COMSIG_ATOM_ATTACK_HAND, .proc/on_attack_hand)
+	if(isitem(parent))
+		RegisterSignal(parent, COMSIG_ITEM_ATTACK_SELF, .proc/apply_moodlet)
+
+/datum/component/art/proc/apply_moodlet(mob/M, impress)
+	M.visible_message("<span class='notice'>[M] stops and looks intently at [parent].</span>", \
+						 "<span class='notice'>You stop to take in [parent].</span>")
+	switch(impress)
+		if (0 to BAD_ART)
+			SEND_SIGNAL(M, COMSIG_ADD_MOOD_EVENT, "artbad", /datum/mood_event/artbad)
+		if (BAD_ART to GOOD_ART)
+			SEND_SIGNAL(M, COMSIG_ADD_MOOD_EVENT, "artok", /datum/mood_event/artok)
+		if (GOOD_ART to GREAT_ART)
+			SEND_SIGNAL(M, COMSIG_ADD_MOOD_EVENT, "artgood", /datum/mood_event/artgood)
+		if(GREAT_ART to INFINITY)
+			SEND_SIGNAL(M, COMSIG_ADD_MOOD_EVENT, "artgreat", /datum/mood_event/artgreat)
+
+
+/datum/component/art/proc/on_other_examine(datum/source, mob/M)
+	apply_moodlet(M, impressiveness)
+
+/datum/component/art/proc/on_obj_examine(datum/source, mob/M)
+	var/obj/O = parent
+	apply_moodlet(M, impressiveness *(O.obj_integrity/O.max_integrity))
+
+/datum/component/art/proc/on_attack_hand(datum/source, mob/M)
+	to_chat(M, "<span class='notice'>You start examining [parent]...</span>")
+	if(!do_after(M, 20, target = parent))
+		return
+	on_obj_examine(source, M)
+
+/datum/component/art/rev
+
+/datum/component/art/rev/apply_moodlet(mob/M, impress)
+	M.visible_message("<span class='notice'>[M] stops to inspect [parent].</span>", \
+						 "<span class='notice'>You take in [parent], inspecting the fine craftsmanship of the proletariat.</span>")
+
+	if(M.mind && M.mind.has_antag_datum(/datum/antagonist/rev))
+		SEND_SIGNAL(M, COMSIG_ADD_MOOD_EVENT, "artgreat", /datum/mood_event/artgreat)
+	else
+		SEND_SIGNAL(M, COMSIG_ADD_MOOD_EVENT, "artbad", /datum/mood_event/artbad)

code/datums/mood_events/generic_negative_events.dm

@@ -225,6 +225,19 @@
 	mood_change = -6
 	timeout = 15 MINUTES
 
+/datum/mood_event/bloodsucker_disgust
+	description = "<span class='boldwarning'>Something I recently ate was horrifyingly disgusting.</span>\n"
+	mood_change = -5
+	timeout = 5 MINUTES
+	
+/datum/mood_event/nanite_sadness
+	description = "<span class='warning robot'>+++++++HAPPINESS SUPPRESSION+++++++</span>\n"
+	mood_change = -7
+
 /datum/mood_event/nanite_sadness/add_effects(message)
 	description = "<span class='warning robot'>+++++++[message]+++++++</span>\n"
 
+/datum/mood_event/artbad
+	description = "<span class='warning'>I've produced better art than that from my ass.</span>\n"
+	mood_change = -2
+	timeout = 1200

code/datums/mood_events/generic_positive_events.dm

@@ -175,3 +175,18 @@
 /datum/mood_event/radiant
 	description = "<span class='nicegreen'>I have seen the light of The Phoenix; I cannot be stopped.</span>\n"
 	mood_change = 12
+
+/datum/mood_event/artok
+	description = "<span class='nicegreen'>It's nice to see people are making art around here.</span>\n"
+	mood_change = 2
+	timeout = 2 MINUTES
+
+/datum/mood_event/artgood
+	description = "<span class='nicegreen'>What a thought-provoking piece of art. I'll remember that for a while.</span>\n"
+	mood_change = 3
+	timeout = 3 MINUTES
+
+/datum/mood_event/artgreat
+	description = "<span class='nicegreen'>That work of art was so great it made me believe in the goodness of humanity. Says a lot in a place like this.</span>\n"
+	mood_change = 4
+	timeout = 4 MINUTES

code/game/objects/items/crayons.dm

@@ -89,6 +89,11 @@
 
 	refill()
 
+/obj/item/toy/crayon/examine(mob/user)
+	. = ..()
+	if(can_change_colour)
+		. += "<span class='notice'>Ctrl-click [src] while it's on your person to quickly recolour it.</span>"
+
 /obj/item/toy/crayon/proc/refill()
 	if(charges == -1)
 		charges_left = 100
@@ -158,6 +163,12 @@
 			update_icon()
 			return TRUE
 
+/obj/item/toy/crayon/CtrlClick(mob/user)
+	if(can_change_colour && !isturf(loc) && user.canUseTopic(src, BE_CLOSE, ismonkey(user)))
+		select_colour(user)
+	else
+		return ..()
+
 /obj/item/toy/crayon/proc/staticDrawables()
 
 	. = list()
@@ -235,14 +246,7 @@
 			else
 				paint_mode = PAINT_NORMAL
 		if("select_colour")
-			if(can_change_colour)
-				var/chosen_colour = input(usr,"","Choose Color",paint_color) as color|null
-
-				if (!isnull(chosen_colour))
-					paint_color = chosen_colour
-					. = TRUE
-				else
-					. = FALSE
+			. = can_change_colour && select_colour(usr)
 		if("enter_text")
 			var/txt = stripped_input(usr,"Choose what to write.",
 				"Scribbles",default = text_buffer)
@@ -252,6 +256,13 @@
 			drawtype = "a"
 	update_icon()
 
+/obj/item/toy/crayon/proc/select_colour(mob/user)
+	var/chosen_colour = input(user, "", "Choose Color", paint_color) as color|null
+	if (!isnull(chosen_colour) && user.canUseTopic(src, BE_CLOSE, ismonkey(user)))
+		paint_color = chosen_colour
+		return TRUE
+	return FALSE
+
 /obj/item/toy/crayon/proc/crayon_text_strip(text)
 	var/static/regex/crayon_r = new /regex(@"[^\w!?,.=%#&+\/\-]")
 	return replacetext(lowertext(text), crayon_r, "")

code/game/objects/items/stacks/sheets/sheet_types.dm

@@ -233,6 +233,7 @@ GLOBAL_LIST_INIT(wood_recipes, list ( \
 	new/datum/stack_recipe("apiary", /obj/structure/beebox, 40, time = 50),\
 	null, \
 	new/datum/stack_recipe("picture frame", /obj/item/wallframe/picture, 1, time = 10),\
+	new/datum/stack_recipe("painting frame", /obj/item/wallframe/painting, 1, time = 10),\
 	new/datum/stack_recipe("honey frame", /obj/item/honey_frame, 5, time = 10),\
 	new/datum/stack_recipe("cross", /obj/structure/kitchenspike/cross, 10, time = 10),\
 	))
@@ -343,6 +344,10 @@ GLOBAL_LIST_INIT(cloth_recipes, list ( \
 	null, \
 	new/datum/stack_recipe("blindfold", /obj/item/clothing/glasses/sunglasses/blindfold, 2), \
 	new/datum/stack_recipe("eyepatch", /obj/item/clothing/glasses/eyepatch, 2), \
+	null, \
+	new/datum/stack_recipe("19x19 canvas", /obj/item/canvas/nineteenXnineteen, 3), \
+	new/datum/stack_recipe("23x19 canvas", /obj/item/canvas/twentythreeXnineteen, 4), \
+	new/datum/stack_recipe("23x23 canvas", /obj/item/canvas/twentythreeXtwentythree, 5), \
 	))
 
 /obj/item/stack/sheet/cloth

code/game/objects/structures/artstuff.dm

@@ -16,12 +16,12 @@
 //Adding canvases
 /obj/structure/easel/attackby(obj/item/I, mob/user, params)
 	if(istype(I, /obj/item/canvas))
-		var/obj/item/canvas/C = I
-		user.dropItemToGround(C)
-		painting = C
-		C.forceMove(get_turf(src))
-		C.layer = layer+0.1
-		user.visible_message("<span class='notice'>[user] puts \the [C] on \the [src].</span>","<span class='notice'>You place \the [C] on \the [src].</span>")
+		var/obj/item/canvas/canvas = I
+		user.dropItemToGround(canvas)
+		painting = canvas
+		canvas.forceMove(get_turf(src))
+		canvas.layer = layer+0.1
+		user.visible_message("<span class='notice'>[user] puts \the [canvas] on \the [src].</span>","<span class='notice'>You place \the [canvas] on \the [src].</span>")
 	else
 		return ..()
 
@@ -35,101 +35,418 @@
 	else
 		painting = null
 
-
-//////////////
-// CANVASES //
-//////////////
-
-#define AMT_OF_CANVASES	4 //Keep this up to date or shit will break.
-
-//To safe memory on making /icons we cache the blanks..
-GLOBAL_LIST_INIT(globalBlankCanvases, new(AMT_OF_CANVASES))
-
 /obj/item/canvas
 	name = "canvas"
 	desc = "Draw out your soul on this canvas!"
 	icon = 'icons/obj/artstuff.dmi'
 	icon_state = "11x11"
+	// flags_1 = UNPAINTABLE_1
 	resistance_flags = FLAMMABLE
-	var/whichGlobalBackup = 1 //List index
+	var/width = 11
+	var/height = 11
+	var/list/grid
+	var/canvas_color = "#ffffff" //empty canvas color
+	var/ui_x = 400
+	var/ui_y = 400
+	var/used = FALSE
+	var/painting_name = "Untitled Artwork" //Painting name, this is set after framing.
+	var/finalized = FALSE //Blocks edits
+	var/author_ckey
+	var/icon_generated = FALSE
+	var/icon/generated_icon
 
-/obj/item/canvas/nineteenXnineteen
-	icon_state = "19x19"
-	whichGlobalBackup = 2
+	// Painting overlay offset when framed
+	var/framed_offset_x = 11
+	var/framed_offset_y = 10
 
-/obj/item/canvas/twentythreeXnineteen
-	icon_state = "23x19"
-	whichGlobalBackup = 3
+	pixel_x = 10
+	pixel_y = 9
 
-/obj/item/canvas/twentythreeXtwentythree
-	icon_state = "23x23"
-	whichGlobalBackup = 4
-
-//HEY YOU
-//ARE YOU READING THE CODE FOR CANVASES?
-//ARE YOU AWARE THEY CRASH HALF THE SERVER WHEN SOMEONE DRAWS ON THEM...
-//...AND NOBODY CAN FIGURE OUT WHY?
-//THEN GO ON BRAVE TRAVELER
-//TRY TO FIX THEM AND REMOVE THIS CODE
 /obj/item/canvas/Initialize()
-	..()
-	return INITIALIZE_HINT_QDEL //Delete on creation
+	. = ..()
+	reset_grid()
 
-//Find the right size blank canvas
-/obj/item/canvas/proc/getGlobalBackup()
-	. = null
-	if(GLOB.globalBlankCanvases[whichGlobalBackup])
-		. = GLOB.globalBlankCanvases[whichGlobalBackup]
-	else
-		var/icon/I = icon(initial(icon),initial(icon_state))
-		GLOB.globalBlankCanvases[whichGlobalBackup] = I
-		. = I
+/obj/item/canvas/proc/reset_grid()
+	grid = new/list(width,height)
+	for(var/x in 1 to width)
+		for(var/y in 1 to height)
+			grid[x][y] = canvas_color
 
+/obj/item/canvas/attack_self(mob/user)
+	. = ..()
+	ui_interact(user)
 
+/obj/item/canvas/ui_interact(mob/user, ui_key = "main", datum/tgui/ui = null, force_open = FALSE, \
+										datum/tgui/master_ui = null, datum/ui_state/state = GLOB.default_state)
 
-//One pixel increments
-/obj/item/canvas/attackby(obj/item/I, mob/user, params)
-	//Click info
-	var/list/click_params = params2list(params)
-	var/pixX = text2num(click_params["icon-x"])
-	var/pixY = text2num(click_params["icon-y"])
+	ui = SStgui.try_update_ui(user, src, ui_key, ui, force_open)
+	if(!ui)
+		ui = new(user, src, ui_key, "canvas", name, ui_x, ui_y, master_ui, state)
+		ui.set_autoupdate(FALSE)
+		ui.open()
 
-	//Should always be true, otherwise you didn't click the object, but let's check because SS13~
-	if(!click_params || !click_params["icon-x"] || !click_params["icon-y"])
-		return
-
-	//Cleaning one pixel with a soap or rag
-	if(istype(I, /obj/item/soap) || istype(I, /obj/item/reagent_containers/rag))
-		//Pixel info created only when needed
-		var/icon/masterpiece = icon(icon,icon_state)
-		var/thePix = masterpiece.GetPixel(pixX,pixY)
-		var/icon/Ico = getGlobalBackup()
-		if(!Ico)
-			qdel(masterpiece)
-			return
-
-		var/theOriginalPix = Ico.GetPixel(pixX,pixY)
-		if(thePix != theOriginalPix) //colour changed
-			DrawPixelOn(theOriginalPix,pixX,pixY)
-		qdel(masterpiece)
-
-	//Drawing one pixel with a crayon
-	else if(istype(I, /obj/item/toy/crayon))
-		var/obj/item/toy/crayon/C = I
-		DrawPixelOn(C.paint_color, pixX, pixY)
+/obj/item/canvas/attackby(obj/item/I, mob/living/user, params)
+	if(user.a_intent == INTENT_HELP)
+		ui_interact(user)
 	else
 		return ..()
 
+/obj/item/canvas/ui_data(mob/user)
+	. = ..()
+	.["grid"] = grid
+	.["name"] = painting_name
+	.["finalized"] = finalized
 
-//Clean the whole canvas
-/obj/item/canvas/attack_self(mob/user)
-	if(!user)
+/obj/item/canvas/examine(mob/user)
+	. = ..()
+	ui_interact(user)
+
+/obj/item/canvas/ui_act(action, params)
+	. = ..()
+	if(. || finalized)
 		return
-	var/icon/blank = getGlobalBackup()
-	if(blank)
-		//it's basically a giant etch-a-sketch
-		icon = blank
-		user.visible_message("<span class='notice'>[user] cleans the canvas.</span>","<span class='notice'>You clean the canvas.</span>")
+	var/mob/user = usr
+	switch(action)
+		if("paint")
+			var/obj/item/I = user.get_active_held_item()
+			var/color = get_paint_tool_color(I)
+			if(!color)
+				return FALSE
+			var/x = text2num(params["x"])
+			var/y = text2num(params["y"])
+			grid[x][y] = color
+			used = TRUE
+			update_icon()
+			. = TRUE
+		if("finalize")
+			. = TRUE
+			if(!finalized)
+				finalize(user)
 
+/obj/item/canvas/proc/finalize(mob/user)
+	finalized = TRUE
+	author_ckey = user.ckey
+	generate_proper_overlay()
+	try_rename(user)
 
-#undef AMT_OF_CANVASES
+/obj/item/canvas/update_overlays()
+	. = ..()
+	if(icon_generated)
+		var/mutable_appearance/detail = mutable_appearance(generated_icon)
+		detail.pixel_x = 1
+		detail.pixel_y = 1
+		. += detail
+		return
+	if(!used)
+		return
+
+	var/mutable_appearance/detail = mutable_appearance(icon, "[icon_state]wip")
+	detail.pixel_x = 1
+	detail.pixel_y = 1
+	. += detail
+
+/obj/item/canvas/proc/generate_proper_overlay()
+	if(icon_generated)
+		return
+	var/png_filename = "data/paintings/temp_painting.png"
+	var/result = rustg_dmi_create_png(png_filename,"[width]","[height]",get_data_string())
+	if(result)
+		CRASH("Error generating painting png : [result]")
+	generated_icon = new(png_filename)
+	icon_generated = TRUE
+	update_icon()
+
+/obj/item/canvas/proc/get_data_string()
+	var/list/data = list()
+	for(var/y in 1 to height)
+		for(var/x in 1 to width)
+			data += grid[x][y]
+	return data.Join("")
+
+//Todo make this element ?
+/obj/item/canvas/proc/get_paint_tool_color(obj/item/I)
+	if(!I)
+		return
+	if(istype(I, /obj/item/toy/crayon))
+		var/obj/item/toy/crayon/crayon = I
+		return crayon.paint_color
+	else if(istype(I, /obj/item/pen))
+		var/obj/item/pen/P = I
+		switch(P.colour)
+			if("black")
+				return "#000000"
+			if("blue")
+				return "#0000ff"
+			if("red")
+				return "#ff0000"
+		return P.colour
+	else if(istype(I, /obj/item/soap) || istype(I, /obj/item/reagent_containers/rag))
+		return canvas_color
+
+/obj/item/canvas/proc/try_rename(mob/user)
+	var/new_name = stripped_input(user,"What do you want to name the painting?")
+	if(new_name != painting_name && new_name && user.canUseTopic(src,BE_CLOSE))
+		painting_name = new_name
+		SStgui.update_uis(src)
+
+/obj/item/canvas/nineteenXnineteen
+	icon_state = "19x19"
+	width = 19
+	height = 19
+	ui_x = 600
+	ui_y = 600
+	pixel_x = 6
+	pixel_y = 9
+	framed_offset_x = 8
+	framed_offset_y = 9
+
+/obj/item/canvas/twentythreeXnineteen
+	icon_state = "23x19"
+	width = 23
+	height = 19
+	ui_x = 800
+	ui_y = 600
+	pixel_x = 4
+	pixel_y = 10
+	framed_offset_x = 6
+	framed_offset_y = 8
+
+/obj/item/canvas/twentythreeXtwentythree
+	icon_state = "23x23"
+	width = 23
+	height = 23
+	ui_x = 800
+	ui_y = 800
+	pixel_x = 5
+	pixel_y = 9
+	framed_offset_x = 5
+	framed_offset_y = 6
+
+/obj/item/canvas/twentyfour_twentyfour
+	name = "ai universal standard canvas"
+	desc = "Besides being very large, the AI can accept these as a display from their internal database after you've hung it up."
+	icon_state = "24x24"
+	width = 24
+	height = 24
+	pixel_x = 2
+	pixel_y = 1
+	framed_offset_x = 4
+	framed_offset_y = 5
+
+/obj/item/wallframe/painting
+	name = "painting frame"
+	desc = "The perfect showcase for your favorite deathtrap memories."
+	icon = 'icons/obj/decals.dmi'
+	//custom_materials = null
+	flags_1 = 0
+	icon_state = "frame-empty"
+	result_path = /obj/structure/sign/painting
+
+/obj/structure/sign/painting
+	name = "Painting"
+	desc = "Art or \"Art\"? You decide."
+	icon = 'icons/obj/decals.dmi'
+	icon_state = "frame-empty"
+	// base_icon_state = "frame"
+	//custom_materials = list(/datum/material/wood = 2000)
+	buildable_sign = FALSE
+	///Canvas we're currently displaying.
+	var/obj/item/canvas/current_canvas
+	///Description set when canvas is added.
+	var/desc_with_canvas
+	var/persistence_id
+
+/obj/structure/sign/painting/Initialize(mapload, dir, building)
+	. = ..()
+	SSpersistence.painting_frames += src
+	AddComponent(/datum/component/art, 20)
+	if(dir)
+		setDir(dir)
+	if(building)
+		pixel_x = (dir & 3)? 0 : (dir == 4 ? -30 : 30)
+		pixel_y = (dir & 3)? (dir ==1 ? -30 : 30) : 0
+	desc = current_canvas ? desc_with_canvas : initial(desc)
+
+/obj/structure/sign/painting/Destroy()
+	. = ..()
+	SSpersistence.painting_frames -= src
+
+/obj/structure/sign/painting/attackby(obj/item/I, mob/user, params)
+	if(!current_canvas && istype(I, /obj/item/canvas))
+		frame_canvas(user,I)
+	else if(current_canvas && current_canvas.painting_name == initial(current_canvas.painting_name) && istype(I,/obj/item/pen))
+		try_rename(user)
+	else
+		return ..()
+
+/obj/structure/sign/painting/examine(mob/user)
+	. = ..()
+	if(persistence_id)
+		. += "<span class='notice'>Any painting placed here will be archived at the end of the shift.</span>"
+	if(current_canvas)
+		current_canvas.ui_interact(user)
+		. += "<span class='notice'>Use wirecutters to remove the painting.</span>"
+
+/obj/structure/sign/painting/wirecutter_act(mob/living/user, obj/item/I)
+	. = ..()
+	if(current_canvas)
+		current_canvas.forceMove(drop_location())
+		current_canvas = null
+		to_chat(user, "<span class='notice'>You remove the painting from the frame.</span>")
+		update_icon()
+		return TRUE
+
+/obj/structure/sign/painting/proc/frame_canvas(mob/user,obj/item/canvas/new_canvas)
+	if(user.transferItemToLoc(new_canvas,src))
+		current_canvas = new_canvas
+		if(!current_canvas.finalized)
+			current_canvas.finalize(user)
+		to_chat(user,"<span class='notice'>You frame [current_canvas].</span>")
+	update_icon()
+
+/obj/structure/sign/painting/proc/try_rename(mob/user)
+	if(current_canvas.painting_name == initial(current_canvas.painting_name))
+		current_canvas.try_rename(user)
+
+// /obj/structure/sign/painting/update_name(updates)
+// 	name = current_canvas ? "painting - [current_canvas.painting_name]" : initial(name)
+// 	return ..()
+
+// /obj/structure/sign/painting/update_desc(updates)
+// 	desc = current_canvas ? desc_with_canvas : initial(desc)
+// 	return ..()
+
+/obj/structure/sign/painting/update_icon_state()
+	// icon_state = "[base_icon_state]-[current_canvas?.generated_icon ? "overlay" : "empty"]"
+	if(current_canvas?.generated_icon)
+		icon_state = "frame-empty"
+	//else
+	//	icon_state = null // or "frame-empty"
+	return ..()
+
+/obj/structure/sign/painting/update_overlays()
+	. = ..()
+	if(!current_canvas?.generated_icon)
+		return
+
+	var/mutable_appearance/MA = mutable_appearance(current_canvas.generated_icon)
+	MA.pixel_x = current_canvas.framed_offset_x
+	MA.pixel_y = current_canvas.framed_offset_y
+	. += MA
+	var/mutable_appearance/frame = mutable_appearance(current_canvas.icon,"[current_canvas.icon_state]frame")
+	frame.pixel_x = current_canvas.framed_offset_x - 1
+	frame.pixel_y = current_canvas.framed_offset_y - 1
+	. += frame
+
+/obj/structure/sign/painting/proc/load_persistent()
+	if(!persistence_id)
+		return
+	if(!SSpersistence.paintings || !SSpersistence.paintings[persistence_id] || !length(SSpersistence.paintings[persistence_id]))
+		return
+	var/list/chosen = pick(SSpersistence.paintings[persistence_id])
+	var/title = chosen["title"]
+	var/author = chosen["ckey"]
+	var/png = "data/paintings/[persistence_id]/[chosen["md5"]].png"
+	if(!title)
+		title = "Untitled Artwork" //Should prevent NULL named art from loading as NULL, if you're still getting the admin log chances are persistence is broken
+	if(!title)
+		message_admins("<span class='notice'>Painting with NO TITLE loaded on a [persistence_id] frame in [get_area(src)]. Please delete it, it is saved in the database with no name and will create bad assets.</span>")
+	if(!fexists(png))
+		stack_trace("Persistent painting [chosen["md5"]].png was not found in [persistence_id] directory.")
+		return
+	var/icon/I = new(png)
+	var/obj/item/canvas/new_canvas
+	var/w = I.Width()
+	var/h = I.Height()
+	for(var/T in typesof(/obj/item/canvas))
+		new_canvas = T
+		if(initial(new_canvas.width) == w && initial(new_canvas.height) == h)
+			new_canvas = new T(src)
+			break
+	new_canvas.fill_grid_from_icon(I)
+	new_canvas.generated_icon = I
+	new_canvas.icon_generated = TRUE
+	new_canvas.finalized = TRUE
+	new_canvas.painting_name = title
+	new_canvas.author_ckey = author
+	new_canvas.name = "painting - [title]"
+	current_canvas = new_canvas
+	update_icon()
+
+/obj/structure/sign/painting/proc/save_persistent()
+	if(!persistence_id || !current_canvas)
+		return
+	if(sanitize_filename(persistence_id) != persistence_id)
+		stack_trace("Invalid persistence_id - [persistence_id]")
+		return
+	if(!current_canvas.painting_name)
+		current_canvas.painting_name = "Untitled Artwork"
+	var/data = current_canvas.get_data_string()
+	var/md5 = md5(lowertext(data))
+	var/list/current = SSpersistence.paintings[persistence_id]
+	if(!current)
+		current = list()
+	for(var/list/entry in current)
+		if(entry["md5"] == md5)
+			return
+	var/png_directory = "data/paintings/[persistence_id]/"
+	var/png_path = png_directory + "[md5].png"
+	var/result = rustg_dmi_create_png(png_path,"[current_canvas.width]","[current_canvas.height]",data)
+	if(result)
+		CRASH("Error saving persistent painting: [result]")
+	current += list(list("title" = current_canvas.painting_name , "md5" = md5, "ckey" = current_canvas.author_ckey))
+	SSpersistence.paintings[persistence_id] = current
+
+/obj/item/canvas/proc/fill_grid_from_icon(icon/I)
+	var/h = I.Height() + 1
+	for(var/x in 1 to width)
+		for(var/y in 1 to height)
+			grid[x][y] = I.GetPixel(x,h-y)
+
+//Presets for art gallery mapping, for paintings to be shared across stations
+/obj/structure/sign/painting/library
+	name = "\improper Public Painting Exhibit mounting"
+	desc = "For art pieces hung by the public."
+	desc_with_canvas = "A piece of art (or \"art\"). Anyone could've hung it."
+	persistence_id = "library"
+
+/obj/structure/sign/painting/library_secure
+	name = "\improper Curated Painting Exhibit mounting"
+	desc = "For masterpieces hand-picked by the curator."
+	desc_with_canvas = "A masterpiece hand-picked by the curator, supposedly."
+	persistence_id = "library_secure"
+
+/obj/structure/sign/painting/library_private // keep your smut away from prying eyes, or non-librarians at least
+	name = "\improper Private Painting Exhibit mounting"
+	desc = "For art pieces deemed too subversive or too illegal to be shared outside of curators."
+	desc_with_canvas = "A painting hung away from lesser minds."
+	persistence_id = "library_private"
+
+/obj/structure/sign/painting/vv_get_dropdown()
+	. = ..()
+	VV_DROPDOWN_OPTION(VV_HK_REMOVE_PAINTING, "Remove Persistent Painting")
+
+/obj/structure/sign/painting/vv_do_topic(list/href_list)
+	. = ..()
+	if(href_list[VV_HK_REMOVE_PAINTING])
+		if(!check_rights(NONE))
+			return
+		var/mob/user = usr
+		if(!persistence_id || !current_canvas)
+			to_chat(user,"<span class='warning'>This is not a persistent painting.</span>")
+			return
+		var/md5 = md5(lowertext(current_canvas.get_data_string()))
+		var/author = current_canvas.author_ckey
+		var/list/current = SSpersistence.paintings[persistence_id]
+		if(current)
+			for(var/list/entry in current)
+				if(entry["md5"] == md5)
+					current -= entry
+			var/png = "data/paintings/[persistence_id]/[md5].png"
+			fdel(png)
+		for(var/obj/structure/sign/painting/P in SSpersistence.painting_frames)
+			if(P.current_canvas && md5(P.current_canvas.get_data_string()) == md5)
+				QDEL_NULL(P.current_canvas)
+				P.update_icon()
+		log_admin("[key_name(user)] has deleted a persistent painting made by [author].")
+		message_admins("<span class='notice'>[key_name_admin(user)] has deleted persistent painting made by [author].</span>")

code/game/objects/structures/statues.dm

@@ -8,12 +8,11 @@
 	max_integrity = 100
 	var/oreAmount = 5
 	var/material_drop_type = /obj/item/stack/sheet/metal
+	var/impressiveness = 15
 	CanAtmosPass = ATMOS_PASS_DENSITY
 
-
 /obj/structure/statue/attackby(obj/item/W, mob/living/user, params)
 	add_fingerprint(user)
-	user.changeNext_move(CLICK_CD_MELEE)
 	if(!(flags_1 & NODECONSTRUCT_1))
 		if(default_unfasten_wrench(user, W))
 			return
@@ -36,8 +35,22 @@
 		return
 	user.changeNext_move(CLICK_CD_MELEE)
 	add_fingerprint(user)
-	user.visible_message("[user] rubs some dust off from the [name]'s surface.", \
-						 "<span class='notice'>You rub some dust off from the [name]'s surface.</span>")
+	if(!do_after(user, 20, target = src))
+		return
+	user.visible_message("[user] rubs some dust off [src].", \
+						 "<span class='notice'>You take in [src], rubbing some dust off its surface.</span>")
+	if(!ishuman(user)) // only humans have the capacity to appreciate art
+		return
+	var/totalimpressiveness = (impressiveness *(obj_integrity/max_integrity))
+	switch(totalimpressiveness)
+		if(GREAT_ART to 100)
+			SEND_SIGNAL(user, COMSIG_ADD_MOOD_EVENT, "artgreat", /datum/mood_event/artgreat)
+		if (GOOD_ART to GREAT_ART)
+			SEND_SIGNAL(user, COMSIG_ADD_MOOD_EVENT, "artgood", /datum/mood_event/artgood)
+		if (BAD_ART to GOOD_ART)
+			SEND_SIGNAL(user, COMSIG_ADD_MOOD_EVENT, "artok", /datum/mood_event/artok)
+		if (0 to BAD_ART)
+			SEND_SIGNAL(user, COMSIG_ADD_MOOD_EVENT, "artbad", /datum/mood_event/artbad)
 
 /obj/structure/statue/deconstruct(disassembled = TRUE)
 	if(!(flags_1 & NODECONSTRUCT_1))
@@ -58,6 +71,7 @@
 	material_drop_type = /obj/item/stack/sheet/mineral/uranium
 	var/last_event = 0
 	var/active = null
+	impressiveness = 25 // radiation makes an impression
 
 /obj/structure/statue/uranium/nuke
 	name = "statue of a nuclear fission explosive"
@@ -101,6 +115,7 @@
 	max_integrity = 200
 	material_drop_type = /obj/item/stack/sheet/mineral/plasma
 	desc = "This statue is suitably made from plasma."
+	impressiveness = 20
 
 /obj/structure/statue/plasma/scientist
 	name = "statue of a scientist"
@@ -151,6 +166,7 @@
 	max_integrity = 300
 	material_drop_type = /obj/item/stack/sheet/mineral/gold
 	desc = "This is a highly valuable statue made from gold."
+	impressiveness = 30
 
 /obj/structure/statue/gold/hos
 	name = "statue of the head of security"
@@ -178,6 +194,7 @@
 	max_integrity = 300
 	material_drop_type = /obj/item/stack/sheet/mineral/silver
 	desc = "This is a valuable statue made from silver."
+	impressiveness = 25
 
 /obj/structure/statue/silver/md
 	name = "statue of a medical officer"
@@ -205,6 +222,7 @@
 	max_integrity = 1000
 	material_drop_type = /obj/item/stack/sheet/mineral/diamond
 	desc = "This is a very expensive diamond statue."
+	impressiveness = 60
 
 /obj/structure/statue/diamond/captain
 	name = "statue of THE captain."
@@ -225,6 +243,7 @@
 	material_drop_type = /obj/item/stack/sheet/mineral/bananium
 	desc = "A bananium statue with a small engraving:'HOOOOOOONK'."
 	var/spam_flag = 0
+	impressiveness = 65
 
 /obj/structure/statue/bananium/clown
 	name = "statue of a clown"

code/modules/photography/photos/frame.dm

@@ -40,6 +40,7 @@
 /obj/item/wallframe/picture/examine(mob/user)
 	if(user.is_holding(src) && displayed)
 		displayed.show(user)
+		SEND_SIGNAL(user, COMSIG_ADD_MOOD_EVENT, "artok", /datum/mood_event/artok)
 		return list()
 	return ..()
 
@@ -109,8 +110,9 @@
 /obj/structure/sign/picture_frame/examine(mob/user)
 	if(in_range(src, user) && framed)
 		framed.show(user)
-	else
-		..()
+		SEND_SIGNAL(user, COMSIG_ADD_MOOD_EVENT, "artok", /datum/mood_event/artok)
+		return list()
+	return ..()
 
 /obj/structure/sign/picture_frame/attackby(obj/item/I, mob/user, params)
 	if(can_decon && (istype(I, /obj/item/screwdriver) || istype(I, /obj/item/wrench)))

code/modules/tgui/states/physical.dm

@@ -2,7 +2,7 @@
   * tgui state: physical_state
   *
   * Short-circuits the default state to only check physical distance.
- **/
+  */
 
 GLOBAL_DATUM_INIT(physical_state, /datum/ui_state/physical, new)
 
@@ -22,3 +22,28 @@ GLOBAL_DATUM_INIT(physical_state, /datum/ui_state/physical, new)
 
 /mob/living/silicon/ai/physical_can_use_topic(src_object)
 	return UI_UPDATE // AIs are not physical.
+
+/**
+ * tgui state: physical_obscured_state
+ *
+ * Short-circuits the default state to only check physical distance, being in view doesn't matter
+ */
+
+GLOBAL_DATUM_INIT(physical_obscured_state, /datum/ui_state/physical_obscured_state, new)
+
+/datum/ui_state/physical_obscured_state/can_use_topic(src_object, mob/user)
+	. = user.shared_ui_interaction(src_object)
+	if(. > UI_CLOSE)
+		return min(., user.physical_obscured_can_use_topic(src_object))
+
+/mob/proc/physical_obscured_can_use_topic(src_object)
+	return UI_CLOSE
+
+/mob/living/physical_obscured_can_use_topic(src_object)
+	return shared_living_ui_distance(src_object)
+
+/mob/living/silicon/physical_obscured_can_use_topic(src_object)
+	return max(UI_UPDATE, shared_living_ui_distance(src_object)) // Silicons can always see.
+
+/mob/living/silicon/ai/physical_obscured_can_use_topic(src_object)
+	return UI_UPDATE // AIs are not physical.

tgstation.dme

@@ -359,6 +359,7 @@
 #include "code\datums\components\_component.dm"
 #include "code\datums\components\anti_magic.dm"
 #include "code\datums\components\armor_plate.dm"
+#include "code\datums\components\art.dm"
 #include "code\datums\components\bouncy.dm"
 #include "code\datums\components\butchering.dm"
 #include "code\datums\components\caltrop.dm"

tgui-next/packages/tgui/interfaces/Canvas.js

@@ -0,0 +1,90 @@
+import { Fragment } from 'inferno';
+import { useBackend } from '../backend';
+import { Box } from '../components';
+import { Component, createRef } from 'inferno';
+import { pureComponentHooks } from 'common/react';
+
+
+class PaintCanvas extends Component {
+  constructor(props) {
+    super(props);
+    this.canvasRef = createRef();
+    this.onCVClick = props.onCanvasClick;
+  }
+
+  componentDidMount() {
+    this.drawCanvas(this.props);
+  }
+
+  componentDidUpdate() {
+    this.drawCanvas(this.props);
+  }
+
+  drawCanvas(propSource) {
+    const ctx = this.canvasRef.current.getContext("2d");
+    const grid = propSource.value;
+    const x_size = grid.length;
+    if (!x_size) {
+      return;
+    }
+    const y_size = grid[0].length;
+    const x_scale = Math.round(this.canvasRef.current.width / x_size);
+    const y_scale = Math.round(this.canvasRef.current.height / y_size);
+    ctx.save();
+    ctx.scale(x_scale, y_scale);
+    for (let x = 0; x < grid.length; x++) {
+      const element = grid[x];
+      for (let y = 0; y < element.length; y++) {
+        const color = element[y];
+        ctx.fillStyle = color;
+        ctx.fillRect(x, y, 1, 1);
+      }
+    }
+    ctx.restore();
+  }
+
+  clickwrapper(event) {
+    const x_size = this.props.value.length;
+    if (!x_size)
+    {
+      return;
+    }
+    const y_size = this.props.value[0].length;
+    const x_scale = this.canvasRef.current.width / x_size;
+    const y_scale = this.canvasRef.current.height / y_size;
+    const x = Math.floor(event.offsetX / x_scale)+1;
+    const y = Math.floor(event.offsetY / y_scale)+1;
+    this.onCVClick(x, y);
+  }
+
+  render() {
+    const {
+      res = 1,
+      value,
+      px_per_unit = 28,
+      ...rest
+    } = this.props;
+    const x_size = value.length * px_per_unit;
+    const y_size = x_size !== 0 ? value[0].length * px_per_unit : 0;
+    return (
+      <canvas
+        ref={this.canvasRef}
+        width={x_size || 300}
+        height={y_size || 300}
+        {...rest}
+        onClick={e => this.clickwrapper(e)}>
+          Canvas failed to render.
+      </canvas>
+    );
+  }
+}
+export const Canvas = props => {
+  const { act, data } = useBackend(props);
+  return (
+    <Box textAlign="center">
+      <PaintCanvas
+        value={data.grid}
+        onCanvasClick={(x, y) => act("paint", { x, y })} />
+      <Box>{data.name}</Box>
+    </Box>);
+};

tgui-next/packages/tgui/routes.js

@@ -13,6 +13,7 @@ import { BluespaceArtillery } from './interfaces/BluespaceArtillery';
 import { Bepis } from './interfaces/Bepis';
 import { BorgPanel } from './interfaces/BorgPanel';
 import { BrigTimer } from './interfaces/BrigTimer';
+import { Canvas } from './interfaces/Canvas';
 import { Canister } from './interfaces/Canister';
 import { Cargo, CargoExpress } from './interfaces/Cargo';
 import { CellularEmporium } from './interfaces/CellularEmporium';
@@ -172,6 +173,10 @@ const ROUTES = {
     component: () => BluespaceArtillery,
     scrollable: false,
   },
+  canvas: {
+    component: () => Canvas,
+    scrollable: false,
+  },
   canister: {
     component: () => Canister,
     scrollable: false,