Add shared storage and godeye items, split Lavaland loot files

code/modules/mining/lavaland/loot/ashdragon_loot.dm

@@ -0,0 +1,215 @@
+/obj/structure/closet/crate/necropolis/dragon
+	name = "dragon chest"
+
+/obj/structure/closet/crate/necropolis/dragon/New()
+	..()
+	var/loot = rand(1,4)
+	switch(loot)
+		if(1)
+			new /obj/item/weapon/melee/ghost_sword(src)
+		if(2)
+			new /obj/item/weapon/lava_staff(src)
+		if(3)
+			new /obj/item/weapon/spellbook/oneuse/sacredflame(src)
+			new /obj/item/weapon/gun/magic/wand/fireball(src)
+		if(4)
+			new /obj/item/weapon/dragons_blood(src)
+
+// Spectral Blade			
+			
+/obj/item/weapon/melee/ghost_sword
+	name = "spectral blade"
+	desc = "A rusted and dulled blade. It doesn't look like it'd do much damage. It glows weakly."
+	icon_state = "spectral"
+	item_state = "spectral"
+	flags = CONDUCT
+	sharp = 1
+	edge = 1
+	w_class = 4
+	force = 1
+	throwforce = 1
+	hitsound = 'sound/effects/ghost2.ogg'
+	attack_verb = list("attacked", "slashed", "stabbed", "sliced", "torn", "ripped", "diced", "rended")
+	var/summon_cooldown = 0
+	var/list/mob/dead/observer/spirits
+
+/obj/item/weapon/melee/ghost_sword/New()
+	..()
+	spirits = list()
+	processing_objects.Add(src)
+	poi_list |= src
+
+/obj/item/weapon/melee/ghost_sword/Destroy()
+	for(var/mob/dead/observer/G in spirits)
+		G.invisibility = initial(G.invisibility)
+	spirits.Cut()
+	processing_objects.Remove(src)
+	poi_list -= src
+	. = ..()
+
+/obj/item/weapon/melee/ghost_sword/attack_self(mob/user)
+	if(summon_cooldown > world.time)
+		to_chat(user, "You just recently called out for aid. You don't want to annoy the spirits.")
+		return
+	to_chat(user, "You call out for aid, attempting to summon spirits to your side.")
+
+	notify_ghosts("[user] is raising their [src], calling for your help!", enter_link="<a href=?src=[UID()];follow=1>(Click to help)</a>", source = user, action = NOTIFY_FOLLOW)
+
+	summon_cooldown = world.time + 600
+
+/obj/item/weapon/melee/ghost_sword/Topic(href, href_list)
+	if(href_list["follow"])
+		var/mob/dead/observer/ghost = usr
+		if(istype(ghost))
+			ghost.ManualFollow(src)
+
+/obj/item/weapon/melee/ghost_sword/process()
+	ghost_check()
+
+/obj/item/weapon/melee/ghost_sword/proc/ghost_check()
+	var/ghost_counter = 0
+	var/turf/T = get_turf(src)
+	var/list/contents = T.GetAllContents()
+	var/mob/dead/observer/current_spirits = list()
+	
+	for(var/mob/dead/observer/O in player_list)
+		if(is_type_in_list(O.following, contents))
+			ghost_counter++
+			O.invisibility = 0
+			current_spirits |= O
+
+	for(var/mob/dead/observer/G in spirits - current_spirits)
+		G.invisibility = initial(G.invisibility)
+
+	spirits = current_spirits
+
+	return ghost_counter
+
+/obj/item/weapon/melee/ghost_sword/attack(mob/living/target, mob/living/carbon/human/user)
+	force = 0
+	var/ghost_counter = ghost_check()
+
+	force = Clamp((ghost_counter * 4), 0, 75)
+	user.visible_message("<span class='danger'>[user] strikes with the force of [ghost_counter] vengeful spirits!</span>")
+	..()
+
+/obj/item/weapon/melee/ghost_sword/hit_reaction(mob/living/carbon/human/owner, attack_text, final_block_chance, damage, attack_type)
+	var/ghost_counter = ghost_check()
+	final_block_chance += Clamp((ghost_counter * 5), 0, 75)
+	owner.visible_message("<span class='danger'>[owner] is protected by a ring of [ghost_counter] ghosts!</span>")
+	return ..()
+
+// Blood
+
+/obj/item/weapon/dragons_blood
+	name = "bottle of dragons blood"
+	desc = "You're not actually going to drink this, are you?"
+	icon = 'icons/obj/wizard.dmi'
+	icon_state = "vial"
+
+/obj/item/weapon/dragons_blood/attack_self(mob/living/carbon/human/user)
+	if(!istype(user))
+		return
+
+	var/mob/living/carbon/human/H = user
+	var/random = rand(1,3)
+
+	switch(random)
+		if(1)
+			to_chat(user, "<span class='danger'>Your flesh begins to melt! Miraculously, you seem fine otherwise.</span>")
+			H.set_species("Skeleton")
+		if(2)
+			to_chat(user, "<span class='danger'>Power courses through you! You can now shift your form at will.")
+			if(user.mind)
+				var/obj/effect/proc_holder/spell/targeted/shapeshift/dragon/D = new
+				user.mind.AddSpell(D)
+		if(3)
+			to_chat(user, "<span class='danger'>You feel like you could walk straight through lava now.</span>")
+			H.weather_immunities |= "lava"
+
+	playsound(user.loc,'sound/items/drink.ogg', rand(10,50), 1)
+	qdel(src)
+
+/datum/disease/transformation/dragon
+	name = "dragon transformation"
+	cure_text = "nothing"
+	cures = list("adminordrazine")
+	agent = "dragon's blood"
+	desc = "What do dragons have to do with Space Station 13?"
+	stage_prob = 20
+	severity = BIOHAZARD
+	visibility_flags = 0
+	stage1	= list("Your bones ache.")
+	stage2	= list("Your skin feels scaley.")
+	stage3	= list("<span class='danger'>You have an overwhelming urge to terrorize some peasants.</span>", "<span class='danger'>Your teeth feel sharper.</span>")
+	stage4	= list("<span class='danger'>Your blood burns.</span>")
+	stage5	= list("<span class='danger'>You're a fucking dragon. However, any previous allegiances you held still apply. It'd be incredibly rude to eat your still human friends for no reason.</span>")
+	new_form = /mob/living/simple_animal/hostile/megafauna/dragon/lesser
+	
+//Lava Staff
+
+/obj/item/weapon/lava_staff
+	name = "staff of lava"
+	desc = "The ability to fill the emergency shuttle with lava. What more could you want out of life?"
+	icon_state = "staffofstorms"
+	item_state = "staffofstorms"
+	icon = 'icons/obj/guns/magic.dmi'
+	slot_flags = SLOT_BACK
+	item_state = "staffofstorms"
+	w_class = 4
+	force = 25
+	damtype = BURN
+	hitsound = 'sound/weapons/sear.ogg'
+	var/turf_type = /turf/unsimulated/floor/lava // /turf/simulated/floor/plating/lava/smooth once Lavaland turfs are added
+	var/transform_string = "lava"
+	var/reset_turf_type = /turf/simulated/floor/plating/airless/asteroid // /turf/simulated/floor/plating/asteroid/basalt once Lavaland turfs are added
+	var/reset_string = "basalt"
+	var/create_cooldown = 100
+	var/create_delay = 30
+	var/reset_cooldown = 50
+	var/timer = 0
+	var/banned_turfs
+
+/obj/item/weapon/lava_staff/New()
+	. = ..()
+	banned_turfs = typecacheof(list(/turf/space/transit, /turf/unsimulated))
+
+/obj/item/weapon/lava_staff/afterattack(atom/target, mob/user, proximity_flag, click_parameters)
+	..()
+	if(timer > world.time)
+		return
+
+	if(is_type_in_typecache(target, banned_turfs))
+		return
+
+	if(target in view(user.client.view, get_turf(user)))
+
+		var/turf/simulated/T = get_turf(target)
+		if(!istype(T))
+			return
+		if(!istype(T, turf_type))
+			var/obj/effect/overlay/temp/lavastaff/L = new /obj/effect/overlay/temp/lavastaff(T)
+			L.alpha = 0
+			animate(L, alpha = 255, time = create_delay)
+			user.visible_message("<span class='danger'>[user] points [src] at [T]!</span>")
+			timer = world.time + create_delay + 1
+			if(do_after(user, create_delay, target = T))
+				user.visible_message("<span class='danger'>[user] turns \the [T] into [transform_string]!</span>")
+				message_admins("[key_name_admin(user)] fired the lava staff at [get_area(target)] (<A HREF='?_src_=holder;adminplayerobservecoodjump=1;X=[T.x];Y=[T.y];Z=[T.z]'>JMP</a>).")
+				log_game("[key_name(user)] fired the lava staff at [get_area(target)] ([T.x], [T.y], [T.z]).")
+				T.ChangeTurf(turf_type)
+				timer = world.time + create_cooldown
+				qdel(L)
+			else
+				timer = world.time
+				qdel(L)
+				return
+		else
+			user.visible_message("<span class='danger'>[user] turns \the [T] into [reset_string]!</span>")
+			T.ChangeTurf(reset_turf_type)
+			timer = world.time + reset_cooldown
+		playsound(T,'sound/magic/Fireball.ogg', 200, 1)
+
+/obj/effect/overlay/temp/lavastaff
+	icon_state = "lavastaff_warn"
+	duration = 50

code/modules/mining/lavaland/loot/bubblegum_loot.dm

@@ -0,0 +1,81 @@
+/obj/structure/closet/crate/necropolis/bubblegum
+	name = "bubblegum chest"
+
+/obj/structure/closet/crate/necropolis/bubblegum/New()
+	..()
+	var/loot = rand(1,3)
+	switch(loot)
+		if(1)
+			new /obj/item/mayhem(src)
+		if(2)
+			new /obj/item/blood_contract(src)
+		if(3)
+			new /obj/item/weapon/gun/magic/staff/spellblade(src)
+		
+// Mayhem
+		
+/obj/item/mayhem
+	name = "mayhem in a bottle"
+	desc = "A magically infused bottle of blood, the scent of which will drive anyone nearby into a murderous frenzy."
+	icon = 'icons/obj/wizard.dmi'
+	icon_state = "vial"
+
+/obj/item/mayhem/attack_self(mob/user)
+	for(var/mob/living/carbon/human/H in range(7,user))
+		spawn()
+			var/obj/effect/mine/pickup/bloodbath/B = new(H)
+			B.mineEffect(H)
+	to_chat(user, "<span class='notice'>You shatter the bottle!</span>")
+	playsound(user.loc, 'sound/effects/Glassbr1.ogg', 100, 1)
+	qdel(src)
+	
+// Blood Contract
+
+/obj/item/blood_contract
+	name = "blood contract"
+	icon = 'icons/obj/wizard.dmi'
+	icon_state = "scroll2"
+	color = "#FF0000"
+	desc = "Mark your target for death."
+	var/used = FALSE
+
+/obj/item/blood_contract/attack_self(mob/user)
+	if(used)
+		return
+		
+	used = TRUE
+	var/choice = input(user,"Who do you want dead?","Choose Your Victim") as null|anything in player_list
+
+	if(!choice)
+		used = FALSE
+		return
+	else if(!isliving(choice))
+		to_chat(user, "[choice] is already dead!")
+		used = FALSE
+		return
+	else if(choice == user)
+		user << "You feel like writing your own name into a cursed death warrant would be unwise."
+		used = FALSE
+		return
+	else
+		var/mob/living/L = choice
+
+		message_admins("[key_name_admin(L)] has been marked for death by [key_name_admin(user)].")
+		log_admin("[key_name(L)] has been marked for death by [key_name(user)].")
+
+		var/datum/objective/survive/survive = new
+		survive.owner = L.mind
+		L.mind.objectives += survive
+		to_chat(L, "<span class='userdanger'>You've been marked for death! Don't let the demons get you!</span>")
+		L.color = "#FF0000"
+		spawn()
+			var/obj/effect/mine/pickup/bloodbath/B = new(L)
+			B.mineEffect(L)
+
+		for(var/mob/living/carbon/human/H in player_list)
+			if(H == L)
+				continue
+			to_chat(H, "<span class='userdanger'>You have an overwhelming desire to kill [L]. They have been marked red! Go kill them!</span>")
+			H.put_in_hands(new /obj/item/weapon/kitchen/knife/butcher(H))
+
+	qdel(src)

code/modules/mining/lavaland/loot/colossus_loot.dm

@@ -0,0 +1,493 @@
+//Black Box
+
+/obj/machinery/smartfridge/black_box
+	name = "black box"
+	desc = "A completely indestructible chunk of crystal, rumoured to predate the start of this universe. It looks like you could store things inside it."
+	icon = 'icons/obj/lavaland/artefacts.dmi'
+	icon_state = "blackbox"
+	icon_on = "blackbox"
+	icon_off = "blackbox"
+	luminosity = 8
+	max_n_of_items = INFINITY
+	unacidable = 1
+	pixel_y = -4
+	use_power = 0
+	var/memory_saved = FALSE
+	var/list/stored_items = list()
+	var/static/list/blacklist = typecacheof(list(/obj/item/weapon/spellbook))
+
+/obj/machinery/smartfridge/black_box/update_icon()
+	return
+
+/obj/machinery/smartfridge/black_box/accept_check(obj/item/O)
+	if(!istype(O))
+		return FALSE
+	if(is_type_in_typecache(O, blacklist))
+		return FALSE
+	return TRUE
+
+/obj/machinery/smartfridge/black_box/New()
+	var/static/obj/machinery/smartfridge/black_box/current
+	if(current && current != src)
+		qdel(src, force=TRUE)
+		return
+	current = src
+	ReadMemory()
+	. = ..()
+
+/obj/machinery/smartfridge/black_box/process()
+	..()
+	if(!memory_saved && ticker.current_state == GAME_STATE_FINISHED)
+		WriteMemory()
+
+/obj/machinery/smartfridge/black_box/proc/WriteMemory()
+	var/savefile/S = new /savefile("data/npc_saves/Blackbox.sav")
+	stored_items = list()
+
+	for(var/obj/O in (contents-component_parts))
+		stored_items += O.type
+
+	S["stored_items"]				<< stored_items
+	memory_saved = TRUE
+
+/obj/machinery/smartfridge/black_box/proc/ReadMemory()
+	var/savefile/S = new /savefile("data/npc_saves/Blackbox.sav")
+	S["stored_items"] 		>> stored_items
+
+	if(isnull(stored_items))
+		stored_items = list()
+
+	for(var/item in stored_items)
+		create_item(item)
+
+//in it's own proc to avoid issues with items that nolonger exist in the code base.
+//try catch doesn't always prevent byond runtimes from halting a proc,
+/obj/machinery/smartfridge/black_box/proc/create_item(item_type)
+	new item_type(src)
+
+/obj/machinery/smartfridge/black_box/Destroy(force = FALSE)
+	if(force)
+		for(var/thing in src)
+			qdel(thing)
+		return ..()
+	else
+		return QDEL_HINT_LETMELIVE
+
+
+//No taking it apart
+
+/obj/machinery/smartfridge/black_box/default_deconstruction_screwdriver()
+	return
+
+/obj/machinery/smartfridge/black_box/exchange_parts()
+	return
+
+/obj/machinery/smartfridge/black_box/default_unfasten_wrench()
+	return
+
+/obj/machinery/smartfridge/black_box/default_deconstruction_crowbar()
+	return
+
+///Anomolous Crystal///
+
+/obj/machinery/anomalous_crystal
+	name = "anomalous crystal"
+	desc = "A strange chunk of crystal, being in the presence of it fills you with equal parts excitement and dread."
+	icon = 'icons/obj/lavaland/artefacts.dmi'
+	icon_state = "anomaly_crystal"
+	luminosity = 8
+	use_power = 0
+	density = 1
+	unacidable = 1
+	var/activation_method = "touch"
+	var/activation_damage_type = null
+	var/last_use_timer = 0
+	var/cooldown_add = 30
+	var/list/affected_targets = list()
+	var/activation_sound = 'sound/effects/break_stone.ogg'
+
+/obj/machinery/anomalous_crystal/New()
+	activation_method = pick("touch","laser","bullet","energy","bomb","mob_bump","weapon","speech") // "heat" removed due to lack of is_hot()
+	..()
+
+/obj/machinery/anomalous_crystal/hear_talk(mob/speaker, message)
+	..()
+	if(isliving(speaker) && message)
+		ActivationReaction(speaker, "speech")
+
+/obj/machinery/anomalous_crystal/attack_hand(mob/user)
+	..()
+	ActivationReaction(user,"touch")
+
+/obj/machinery/anomalous_crystal/attackby(obj/item/I, mob/user, params)
+	ActivationReaction(user,"weapon")
+	..()
+
+/obj/machinery/anomalous_crystal/bullet_act(obj/item/projectile/P, def_zone)
+	..()
+	if(istype(P, /obj/item/projectile/magic))
+		ActivationReaction(P.firer, "magic", P.damage_type)
+		return
+	ActivationReaction(P.firer, P.flag, P.damage_type)
+
+/obj/machinery/anomalous_crystal/proc/ActivationReaction(mob/user, method, damtype)
+	if(world.time < last_use_timer)
+		return 0
+	if(activation_damage_type && activation_damage_type != damtype)
+		return 0
+	if(method != activation_method)
+		return 0
+	last_use_timer = (world.time + cooldown_add)
+	playsound(user, activation_sound, 100, 1)
+	return 1
+
+/obj/machinery/anomalous_crystal/Bumped(atom/AM as mob|obj)
+	..()
+	if(ismob(AM))
+		ActivationReaction(AM,"mob_bump")
+
+/obj/machinery/anomalous_crystal/ex_act()
+	ActivationReaction(null,"bomb")
+
+/obj/machinery/anomalous_crystal/random/New()//Just a random crysal spawner for loot
+	var/random_crystal = pick(typesof(/obj/machinery/anomalous_crystal) - /obj/machinery/anomalous_crystal/random - /obj/machinery/anomalous_crystal)
+	new random_crystal(loc)
+	qdel(src)
+
+/obj/machinery/anomalous_crystal/honk //Strips and equips you as a clown. I apologize for nothing
+	activation_method = "mob_bump"
+	activation_sound = 'sound/items/bikehorn.ogg'
+
+/obj/machinery/anomalous_crystal/honk/ActivationReaction(mob/user)
+	if(..() && ishuman(user) && !(user in affected_targets))
+		var/mob/living/carbon/human/H = user
+		for(var/obj/item/W in H)
+			H.unEquip(W)
+		var/datum/job/clown/C = job_master.GetJob("Clown")
+		C.equip(H)
+		affected_targets.Add(H)
+
+/obj/machinery/anomalous_crystal/honk/New()
+	..()
+	activation_method = pick("mob_bump","speech")
+
+/obj/machinery/anomalous_crystal/theme_warp //Warps the area you're in to look like a new one
+	activation_method = "touch"
+	cooldown_add = 200
+	var/terrain_theme = "winter"
+	var/NewTerrainFloors
+	var/NewTerrainWalls
+	var/NewTerrainChairs
+	var/NewTerrainTables
+	var/list/NewFlora = list()
+	var/florachance = 8
+
+/obj/machinery/anomalous_crystal/theme_warp/New()
+	..()
+	terrain_theme = pick("lavaland","winter","jungle","alien")
+	switch(terrain_theme)
+		if("lavaland")//Depressurizes the place... and free cult metal, I guess.
+			NewTerrainFloors = /turf/simulated/floor/basalt // Needs to be updated after turf update
+			NewTerrainWalls = /turf/simulated/wall/cult
+			NewFlora = list(/mob/living/simple_animal/hostile/asteroid/goldgrub)
+			florachance = 1
+		if("winter") //Snow terrain is slow to move in and cold! Get the assistants to shovel your driveway.
+			NewTerrainFloors = /turf/simulated/floor/snow // Needs to be updated after turf update
+			NewTerrainWalls = /turf/simulated/wall/mineral/wood
+			NewTerrainChairs = /obj/structure/stool/bed/chair/wood/normal
+			NewTerrainTables = /obj/structure/table/glass
+			NewFlora = list(/obj/structure/flora/grass/green, /obj/structure/flora/grass/brown, /obj/structure/flora/grass/both)
+		if("jungle") //Beneficial due to actually having breathable air. Plus, monkeys and bows and arrows.
+			NewTerrainFloors = /turf/simulated/floor/grass
+			NewTerrainWalls = /turf/simulated/wall/mineral/sandstone
+			NewTerrainChairs = /obj/structure/stool/bed/chair/wood/normal
+			NewTerrainTables = /obj/structure/table/woodentable
+			NewFlora = list(/obj/structure/flora/ausbushes/sparsegrass, /obj/structure/flora/ausbushes/fernybush, /obj/structure/flora/ausbushes/leafybush,
+							/obj/structure/flora/ausbushes/grassybush, /obj/structure/flora/ausbushes/sunnybush, /obj/structure/flora/tree/palm, /mob/living/carbon/human/monkey,
+							/obj/item/weapon/gun/projectile/bow, /obj/item/weapon/storage/backpack/quiver/full)
+			florachance = 20
+		if("alien") //Beneficial, turns stuff into alien alloy which is useful to cargo and research. Also repairs atmos.
+			NewTerrainFloors = /turf/simulated/floor/mineral/abductor
+			NewTerrainWalls = /turf/simulated/wall/mineral/abductor
+			NewTerrainChairs = /obj/structure/stool/bed/abductor //ayys apparently don't have chairs. An entire species of people who only recline.
+			NewTerrainTables = /obj/structure/table/abductor
+
+/obj/machinery/anomalous_crystal/theme_warp/ActivationReaction(mob/user, method)
+	if(..())
+		var/area/A = get_area(src)
+		if(!A.outdoors && !(A in affected_targets))
+			for(var/atom/Stuff in A)
+				if(isturf(Stuff))
+					var/turf/T = Stuff
+					if((isspaceturf(T) || isfloorturf(T)) && NewTerrainFloors)
+						var/turf/simulated/O = T.ChangeTurf(NewTerrainFloors)
+						if(O.air)
+							var/datum/gas_mixture/G = O.air
+							G.copy_from(O.air)
+						if(prob(florachance) && NewFlora.len && !is_blocked_turf(O))
+							var/atom/Picked = pick(NewFlora)
+							new Picked(O)
+						continue
+					if(iswallturf(T) && NewTerrainWalls)
+						T.ChangeTurf(NewTerrainWalls)
+						continue
+				if(istype(Stuff, /obj/structure/stool/bed/chair) && NewTerrainChairs)
+					var/obj/structure/stool/bed/chair/Original = Stuff
+					var/obj/structure/stool/bed/chair/C = new NewTerrainChairs(Original.loc)
+					C.dir = Original.dir
+					qdel(Stuff)
+					continue
+				if(istype(Stuff, /obj/structure/table) && NewTerrainTables)
+					var/obj/structure/table/Original = Stuff
+					var/obj/structure/table/T = new NewTerrainTables(Original.loc)
+					T.dir = Original.dir
+					qdel(Stuff)
+					continue
+			affected_targets += A
+
+/obj/machinery/anomalous_crystal/emitter //Generates a projectile when interacted with
+	activation_method = "touch"
+	cooldown_add = 50
+	var/generated_projectile = /obj/item/projectile/beam/emitter
+
+/obj/machinery/anomalous_crystal/emitter/New()
+	..()
+	generated_projectile = pick(/obj/item/projectile/magic/fireball/infernal,/obj/item/projectile/magic/spellblade,
+								 /obj/item/projectile/bullet/meteorshot, /obj/item/projectile/beam/xray, /obj/item/projectile/colossus)
+
+/obj/machinery/anomalous_crystal/emitter/ActivationReaction(mob/user, method)
+	if(..())
+		var/obj/item/projectile/P = new generated_projectile(get_turf(src))
+		P.dir = dir
+		switch(dir)
+			if(NORTH)
+				P.yo = 20
+				P.xo = 0
+			if(EAST)
+				P.yo = 0
+				P.xo = 20
+			if(WEST)
+				P.yo = 0
+				P.xo = -20
+			else
+				P.yo = -20
+				P.xo = 0
+		P.fire()
+
+/obj/machinery/anomalous_crystal/dark_reprise //Revives anyone nearby, but turns them into shadowpeople and renders them uncloneable, so the crystal is your only hope of getting up again if you go down.
+	activation_method = "touch"
+	activation_sound = 'sound/hallucinations/growl1.ogg'
+
+/obj/machinery/anomalous_crystal/dark_reprise/ActivationReaction(mob/user, method)
+	if(..())
+		for(var/i in range(1, src))
+			if(isturf(i))
+				new /obj/effect/overlay/temp/cult/sparks(i)
+				continue
+			if(ishuman(i))
+				var/mob/living/carbon/human/H = i
+				if(H.stat == DEAD)
+					H.set_species("Shadow")
+					H.revive()
+					H.disabilities |= NOCLONE //Free revives, but significantly limits your options for reviving except via the crystal
+					H.grab_ghost(force = TRUE)
+
+/obj/machinery/anomalous_crystal/helpers //Lets ghost spawn as helpful creatures that can only heal people slightly. Incredibly fragile and they can't converse with humans
+	activation_method = "touch"
+	var/ready_to_deploy = 0
+
+/obj/machinery/anomalous_crystal/helpers/ActivationReaction(mob/user, method)
+	if(..() && !ready_to_deploy)
+		ready_to_deploy = 1
+		notify_ghosts("An anomalous crystal has been activated in [get_area(src)]! This crystal can always be used by ghosts hereafter.", enter_link = "<a href=?src=\ref[src];ghostjoin=1>(Click to enter)</a>", source = src, action = NOTIFY_ATTACK)
+
+/obj/machinery/anomalous_crystal/helpers/attack_ghost(mob/dead/observer/user)
+	..()
+	if(ready_to_deploy)
+		var/be_helper = alert("Become a Lightgeist? (Warning, You can no longer be cloned!)",,"Yes","No")
+		if(be_helper == "No")
+			return
+		var/mob/living/simple_animal/hostile/lightgeist/W = new /mob/living/simple_animal/hostile/lightgeist(get_turf(loc))
+		W.key = user.key
+
+/obj/machinery/anomalous_crystal/helpers/Topic(href, href_list)
+	if(href_list["ghostjoin"])
+		var/mob/dead/observer/ghost = usr
+		if(istype(ghost))
+			attack_ghost(ghost)
+
+/mob/living/simple_animal/hostile/lightgeist
+	name = "lightgeist"
+	desc = "This small floating creature is a completely unknown form of life... being near it fills you with a sense of tranquility."
+	icon_state = "lightgeist"
+	icon_living = "lightgeist"
+	icon_dead = "butterfly_dead"
+	turns_per_move = 1
+	response_help = "waves away"
+	response_disarm = "brushes aside"
+	response_harm = "disrupts"
+	speak_emote = list("oscillates")
+	maxHealth = 2
+	health = 2
+	harm_intent_damage = 1
+	friendly = "mends"
+	density = 0
+	flying = 1
+	pass_flags = PASSTABLE | PASSGRILLE | PASSMOB
+	ventcrawler = 2
+	mob_size = MOB_SIZE_TINY
+	gold_core_spawnable = 0
+	speak_emote = list("warps")
+	damage_coeff = list(BRUTE = 1, BURN = 1, TOX = 0, CLONE = 0, STAMINA = 0, OXY = 0)
+	luminosity = 4
+	faction = list("neutral")
+	universal_understand = 1
+	del_on_death = 1
+	unsuitable_atmos_damage = 0
+	flying = 1
+	minbodytemp = 0
+	maxbodytemp = 1500
+	environment_smash = 0
+	AIStatus = AI_OFF
+	stop_automated_movement = 1
+	var/heal_power = 5
+
+/mob/living/simple_animal/hostile/lightgeist/New()
+	..()
+	verbs -= /mob/living/verb/pulled
+	verbs -= /mob/verb/me_verb
+	var/datum/atom_hud/medsensor = huds[DATA_HUD_MEDICAL_ADVANCED]
+	medsensor.add_hud_to(src)
+
+/mob/living/simple_animal/hostile/lightgeist/AttackingTarget()
+	..()
+	if(isliving(target) && target != src)
+		var/mob/living/L = target
+		if(L.stat < DEAD)
+			L.heal_overall_damage(heal_power, heal_power)
+			new /obj/effect/overlay/temp/heal(get_turf(target), "#80F5FF")
+
+/mob/living/simple_animal/hostile/lightgeist/ghostize()
+	if(..())
+		death()
+
+/obj/machinery/anomalous_crystal/refresher //Deletes and recreates a copy of the item, "refreshing" it.
+	activation_method = "touch"
+	cooldown_add = 50
+	activation_sound = 'sound/magic/TIMEPARADOX2.ogg'
+	var/list/banned_items_typecache = list(/obj/item/weapon/storage, /obj/item/weapon/implant, /obj/item/weapon/implanter, /obj/item/weapon/disk/nuclear, /obj/item/projectile, /obj/item/weapon/spellbook)
+
+/obj/machinery/anomalous_crystal/refresher/New()
+	..()
+	banned_items_typecache = typecacheof(banned_items_typecache)
+
+
+/obj/machinery/anomalous_crystal/refresher/ActivationReaction(mob/user, method)
+	if(..())
+		var/list/L = list()
+		var/turf/T = get_step(src, dir)
+		new /obj/effect/overlay/temp/emp/pulse(T)
+		for(var/i in T)
+			if(istype(i, /obj/item) && !is_type_in_typecache(i, banned_items_typecache))
+				var/obj/item/W = i
+				if(!W.admin_spawned)
+					L += W
+		if(L.len)
+			var/obj/item/CHOSEN = pick(L)
+			new CHOSEN.type(T)
+			qdel(CHOSEN)
+
+/obj/machinery/anomalous_crystal/possessor //Allows you to bodyjack small animals, then exit them at your leisure, but you can only do this once per activation. Because they blow up. Also, if the bodyjacked animal dies, SO DO YOU.
+	activation_method = "touch"
+
+/obj/machinery/anomalous_crystal/possessor/ActivationReaction(mob/user, method)
+	if(..())
+		if(ishuman(user))
+			var/mobcheck = 0
+			for(var/mob/living/simple_animal/A in range(1, src))
+				if(A.melee_damage_upper > 5 || A.mob_size >= MOB_SIZE_LARGE || A.ckey || A.stat)
+					break
+				var/obj/structure/closet/stasis/S = new /obj/structure/closet/stasis(A)
+				user.forceMove(S)
+				mobcheck = 1
+				break
+			if(!mobcheck)
+				new /mob/living/simple_animal/cockroach(get_step(src,dir)) //Just in case there aren't any animals on the station, this will leave you with a terrible option to possess if you feel like it
+
+/obj/structure/closet/stasis
+	name = "quantum entanglement stasis warp field"
+	desc = "You can hardly comprehend this thing... which is why you can't see it."
+	icon_state = null //This shouldn't even be visible, so if it DOES show up, at least nobody will notice
+	density = 1
+	anchored = 1
+	var/mob/living/simple_animal/holder_animal
+
+/obj/structure/closet/stasis/process()
+	if(holder_animal)
+		if(holder_animal.stat == DEAD && !qdeleted(holder_animal))
+			dump_contents()
+			holder_animal.gib()
+			return
+
+/obj/structure/closet/stasis/New()
+	..()
+	if(isanimal(loc))
+		holder_animal = loc
+	processing_objects.Add(src)
+
+/obj/structure/closet/stasis/Entered(atom/A)
+	if(isliving(A) && holder_animal)
+		var/mob/living/L = A
+		L.notransform = 1
+		L.disabilities |= MUTE
+		L.status_flags |= GODMODE
+		L.mind.transfer_to(holder_animal)
+		var/obj/effect/proc_holder/spell/targeted/exit_possession/P = new /obj/effect/proc_holder/spell/targeted/exit_possession
+		holder_animal.mind.AddSpell(P)
+		holder_animal.verbs -= /mob/living/verb/pulled
+
+/obj/structure/closet/stasis/dump_contents(var/kill = 1)
+	processing_objects.Remove(src)
+	for(var/mob/living/L in src)
+		L.disabilities &= ~MUTE
+		L.status_flags &= ~GODMODE
+		L.notransform = 0
+		if(holder_animal && !qdeleted(holder_animal))
+			holder_animal.mind.transfer_to(L)
+			L.mind.RemoveSpell(/obj/effect/proc_holder/spell/targeted/exit_possession)
+		if(kill || !isanimal(loc))
+			L.death(0)
+	..()
+
+/obj/structure/closet/stasis/emp_act()
+	return
+
+/obj/structure/closet/stasis/ex_act()
+	return
+
+/obj/effect/proc_holder/spell/targeted/exit_possession
+	name = "Exit Possession"
+	desc = "Exits the body you are possessing"
+	charge_max = 60
+	clothes_req = 0
+	invocation_type = "none"
+	max_targets = 1
+	range = -1
+	include_user = 1
+	selection_type = "view"
+	action_icon_state = "exit_possession"
+	sound = null
+
+/obj/effect/proc_holder/spell/targeted/exit_possession/cast(list/targets, mob/user = usr)
+	if(!isfloorturf(user.loc))
+		return
+	var/datum/mind/target_mind = user.mind
+	var/mob/living/current = user // Saving the current mob here to gib as usr seems to get confused after the mind's been transferred, due to delay in transfer_to
+	for(var/i in user)
+		if(istype(i, /obj/structure/closet/stasis))
+			var/obj/structure/closet/stasis/S = i
+			S.dump_contents(0)
+			qdel(S)
+			break
+	current.gib()
+	target_mind.RemoveSpell(/obj/effect/proc_holder/spell/targeted/exit_possession)

code/modules/mining/lavaland/loot/hierophant_loot.dm

@@ -0,0 +1,188 @@
+/obj/item/weapon/hierophant_staff
+	name = "Hierophant's staff"
+	desc = "A large club with intense magic power infused into it."
+	icon_state = "hierophant_staff"
+	item_state = "hierophant_staff"
+	icon = 'icons/obj/guns/magic.dmi'
+	slot_flags = SLOT_BACK
+	w_class = 4
+	force = 20
+	hitsound = "swing_hit"
+	//hitsound = 'sound/weapons/sonic_jackhammer.ogg'
+	actions_types = list(/datum/action/item_action/vortex_recall, /datum/action/item_action/toggle_unfriendly_fire)
+	var/cooldown_time = 20 //how long the cooldown between non-melee ranged attacks is
+	var/chaser_cooldown = 101 //how long the cooldown between firing chasers at mobs is
+	var/chaser_timer = 0 //what our current chaser cooldown is
+	var/timer = 0 //what our current cooldown is
+	var/blast_range = 3 //how long the cardinal blast's walls are
+	var/obj/effect/hierophant/rune //the associated rune we teleport to
+	var/teleporting = FALSE //if we ARE teleporting
+	var/friendly_fire_check = FALSE //if the blasts we make will consider our faction against the faction of hit targets
+
+/obj/item/weapon/hierophant_staff/afterattack(atom/target, mob/user, proximity_flag, click_parameters)
+	..()
+	var/turf/T = get_turf(target)
+	if(!T || timer > world.time)
+		return
+	timer = world.time + CLICK_CD_MELEE //by default, melee attacks only cause melee blasts, and have an accordingly short cooldown
+	if(proximity_flag)
+		spawn(0)
+			aoe_burst(T, user)
+		add_logs(user, target, "fired 3x3 blast at", src)
+	else
+		if(ismineralturf(target) && get_dist(user, target) < 6) //target is minerals, we can hit it(even if we can't see it)
+			spawn(0)
+				cardinal_blasts(T, user)
+			timer = world.time + cooldown_time
+		else if(target in view(5, get_turf(user))) //if the target is in view, hit it
+			timer = world.time + cooldown_time
+			if(isliving(target) && chaser_timer <= world.time) //living and chasers off cooldown? fire one!
+				chaser_timer = world.time + chaser_cooldown
+				new /obj/effect/overlay/temp/hierophant/chaser(get_turf(user), user, target, 1.5, friendly_fire_check)
+				add_logs(user, target, "fired a chaser at", src)
+			else
+				spawn(0)
+					cardinal_blasts(T, user) //otherwise, just do cardinal blast
+				add_logs(user, target, "fired cardinal blast at", src)
+		else
+			to_chat(user, "<span class='warning'>That target is out of range!</span>") //too far away
+
+/obj/item/weapon/hierophant_staff/ui_action_click(mob/user, actiontype)
+	if(actiontype == /datum/action/item_action/toggle_unfriendly_fire) //toggle friendly fire...
+		friendly_fire_check = !friendly_fire_check
+		to_chat(user, "<span class='warning'>You toggle friendly fire [friendly_fire_check ? "off":"on"]!</span>")
+		return
+	if(user.get_active_hand() != src && user.get_inactive_hand() != src) //you need to hold the staff to teleport
+		to_chat(user, "<span class='warning'>You need to hold the staff in your hands to [rune ? "teleport with it" : "create a rune"]!</span>")
+		return
+	if(!rune)
+		if(isturf(user.loc))
+			user.visible_message("<span class='hierophant_warning'>[user] holds [src] carefully in front of them, moving it in a strange pattern...</span>", \
+			"<span class='notice'>You start creating a hierophant rune to teleport to...</span>")
+			timer = world.time + 51
+			if(do_after(user, 50, target = user))
+				var/turf/T = get_turf(user)
+				playsound(T,'sound/magic/Blind.ogg', 200, 1, -4)
+				new /obj/effect/overlay/temp/hierophant/telegraph/teleport(T, user)
+				var/obj/effect/hierophant/H = new/obj/effect/hierophant(T)
+				rune = H
+				user.update_action_buttons_icon()
+				user.visible_message("<span class='hierophant_warning'>[user] creates a strange rune beneath them!</span>", \
+				"<span class='hierophant'>You create a hierophant rune, which you can teleport yourself and any allies to at any time!</span>\n\
+				<span class='notice'>You can remove the rune to place a new one by striking it with the staff.</span>")
+			else
+				timer = world.time
+		else
+			to_chat(user, "<span class='warning'>You need to be on solid ground to produce a rune!</span>")
+		return
+	if(get_dist(user, rune) <= 2) //rune too close abort
+		to_chat(user, "<span class='warning'>You are too close to the rune to teleport to it!</span>")
+		return
+	if(is_blocked_turf(get_turf(rune)))
+		to_chat(user, "<span class='warning'>The rune is blocked by something, preventing teleportation!</span>")
+		return
+	teleporting = TRUE //start channel
+	user.update_action_buttons_icon()
+	user.visible_message("<span class='hierophant_warning'>[user] starts to glow faintly...</span>")
+	timer = world.time + 50
+	if(do_after(user, 40, target = user) && rune)
+		var/turf/T = get_turf(rune)
+		var/turf/source = get_turf(user)
+		if(is_blocked_turf(T))
+			teleporting = FALSE
+			to_chat(user, "<span class='warning'>The rune is blocked by something, preventing teleportation!</span>")
+			user.update_action_buttons_icon()
+			return
+		new /obj/effect/overlay/temp/hierophant/telegraph(T, user)
+		new /obj/effect/overlay/temp/hierophant/telegraph(source, user)
+		playsound(T,'sound/magic/blink.ogg', 200, 1)
+		//playsound(T,'sound/magic/Wand_Teleport.ogg', 200, 1)
+		playsound(source,'sound/magic/blink.ogg', 200, 1)
+		//playsound(source,'sound/machines/AirlockOpen.ogg', 200, 1)
+		if(!do_after(user, 3, target = user) || !rune) //no walking away shitlord
+			teleporting = FALSE
+			if(user)
+				user.update_action_buttons_icon()
+			return
+		if(is_blocked_turf(T))
+			teleporting = FALSE
+			to_chat(user, "<span class='warning'>The rune is blocked by something, preventing teleportation!</span>")
+			user.update_action_buttons_icon()
+			return
+		add_logs(user, rune, "teleported self from ([source.x],[source.y],[source.z]) to")
+		new /obj/effect/overlay/temp/hierophant/telegraph/teleport(T, user)
+		new /obj/effect/overlay/temp/hierophant/telegraph/teleport(source, user)
+		for(var/t in RANGE_TURFS(1, T))
+			var/obj/effect/overlay/temp/hierophant/blast/B = new /obj/effect/overlay/temp/hierophant/blast(t, user, TRUE) //blasts produced will not hurt allies
+			B.damage = 30
+		for(var/t in RANGE_TURFS(1, source))
+			var/obj/effect/overlay/temp/hierophant/blast/B = new /obj/effect/overlay/temp/hierophant/blast(t, user, TRUE) //but absolutely will hurt enemies
+			B.damage = 30
+		for(var/mob/living/L in range(1, source))
+			spawn(0)
+				teleport_mob(source, L, T, user) //regardless, take all mobs near us along
+		sleep(6) //at this point the blasts detonate
+	else
+		timer = world.time
+	teleporting = FALSE
+	if(user)
+		user.update_action_buttons_icon()
+
+/obj/item/weapon/hierophant_staff/proc/teleport_mob(turf/source, mob/M, turf/target, mob/user)
+	var/turf/turf_to_teleport_to = get_step(target, get_dir(source, M)) //get position relative to caster
+	if(!turf_to_teleport_to || is_blocked_turf(turf_to_teleport_to))
+		return
+	animate(M, alpha = 0, time = 2, easing = EASE_OUT) //fade out
+	sleep(1)
+	if(!M)
+		return
+	M.visible_message("<span class='hierophant_warning'>[M] fades out!</span>")
+	sleep(2)
+	if(!M)
+		return
+	M.forceMove(turf_to_teleport_to)
+	sleep(1)
+	if(!M)
+		return
+	animate(M, alpha = 255, time = 2, easing = EASE_IN) //fade IN
+	sleep(1)
+	if(!M)
+		return
+	M.visible_message("<span class='hierophant_warning'>[M] fades in!</span>")
+	if(user != M)
+		add_logs(user, M, "teleported", null, "from ([source.x],[source.y],[source.z])")
+
+/obj/item/weapon/hierophant_staff/proc/cardinal_blasts(turf/T, mob/living/user) //fire cardinal cross blasts with a delay
+	if(!T)
+		return
+	new /obj/effect/overlay/temp/hierophant/telegraph/cardinal(T, user)
+	playsound(T,'sound/magic/blink.ogg', 200, 1)
+	//playsound(T,'sound/effects/bin_close.ogg', 200, 1)
+	sleep(2)
+	new /obj/effect/overlay/temp/hierophant/blast(T, user, friendly_fire_check)
+	for(var/d in cardinal)
+		spawn(0)
+			blast_wall(T, d, user)
+
+/obj/item/weapon/hierophant_staff/proc/blast_wall(turf/T, dir, mob/living/user) //make a wall of blasts blast_range tiles long
+	if(!T)
+		return
+	var/range = blast_range
+	var/turf/previousturf = T
+	var/turf/J = get_step(previousturf, dir)
+	for(var/i in 1 to range)
+		if(!J)
+			return
+		new /obj/effect/overlay/temp/hierophant/blast(J, user, friendly_fire_check)
+		previousturf = J
+		J = get_step(previousturf, dir)
+
+/obj/item/weapon/hierophant_staff/proc/aoe_burst(turf/T, mob/living/user) //make a 3x3 blast around a target
+	if(!T)
+		return
+	new /obj/effect/overlay/temp/hierophant/telegraph(T, user)
+	playsound(T,'sound/magic/blink.ogg', 200, 1)
+	//playsound(T,'sound/effects/bin_close.ogg', 200, 1)
+	sleep(2)
+	for(var/t in RANGE_TURFS(1, T))
+		new /obj/effect/overlay/temp/hierophant/blast(t, user, friendly_fire_check)

code/modules/mining/lavaland/loot/legion_loot.dm

@@ -0,0 +1,52 @@
+/obj/item/weapon/staff/storm
+	name = "staff of storms"
+	desc = "An ancient staff retrieved from the remains of Legion. The wind stirs as you move it."
+	icon_state = "staffofstorms"
+	item_state = "staffofstorms"
+	icon = 'icons/obj/guns/magic.dmi'
+	slot_flags = SLOT_BACK
+	item_state = "staffofstorms"
+	w_class = 4
+	force = 25
+	damtype = BURN
+	hitsound = 'sound/weapons/sear.ogg'
+	var/storm_type = /datum/weather/ash_storm
+	var/storm_cooldown = 0
+
+/obj/item/weapon/staff/storm/attack_self(mob/user)
+	if(storm_cooldown > world.time)
+		to_chat(user, "<span class='warning'>The staff is still recharging!</span>")
+		return
+
+	var/area/user_area = get_area(user)
+	var/datum/weather/A
+	var/z_level_name = space_manager.levels_by_name[user.z]
+	for(var/V in weather_master.existing_weather)
+		var/datum/weather/W = V
+		if(W.target_z == z_level_name && W.area_type == user_area.type)
+			A = W
+			break
+	if(A)
+
+		if(A.stage != END_STAGE)
+			if(A.stage == WIND_DOWN_STAGE)
+				to_chat(user, "<span class='warning'>The storm is already ending! It would be a waste to use the staff now.</span>")
+				return
+			user.visible_message("<span class='warning'>[user] holds [src] skywards as an orange beam travels into the sky!</span>", \
+			"<span class='notice'>You hold [src] skyward, dispelling the storm!</span>")
+			playsound(user, 'sound/magic/Staff_Change.ogg', 200, 0)
+			A.wind_down()
+			return
+	else
+		A = new storm_type
+		A.name = "staff storm"
+		A.area_type = user_area.type
+		A.target_z = z_level_name
+		A.telegraph_duration = 100
+		A.end_duration = 100
+
+	user.visible_message("<span class='warning'>[user] holds [src] skywards as red lightning crackles into the sky!</span>", \
+	"<span class='notice'>You hold [src] skyward, calling down a terrible storm!</span>")
+	playsound(user, 'sound/magic/Staff_Change.ogg', 200, 0)
+	A.telegraph()
+	storm_cooldown = world.time + 200

code/modules/mining/lavaland/loot/tendril_loot.dm

@@ -0,0 +1,105 @@
+//Shared Bag
+
+//Internal
+/obj/item/weapon/storage/backpack/shared
+	name = "paradox bag"
+	desc = "Somehow, it's in two places at once."
+	max_combined_w_class = 60
+	max_w_class = 3
+
+//External
+/obj/item/device/shared_storage
+	name = "paradox bag"
+	desc = "Somehow, it's in two places at once."
+	icon = 'icons/obj/storage.dmi'
+	icon_state = "cultpack"
+	slot_flags = SLOT_BACK
+	var/obj/item/weapon/storage/backpack/shared/bag
+
+/obj/item/device/shared_storage/red
+	name = "paradox bag"
+	desc = "Somehow, it's in two places at once."
+
+/obj/item/device/shared_storage/red/New()
+	..()
+	if(!bag)
+		var/obj/item/weapon/storage/backpack/shared/S = new(src)
+		var/obj/item/device/shared_storage/blue = new(loc)
+
+		bag = S
+		blue.bag = S
+
+/obj/item/device/shared_storage/attackby(obj/item/W, mob/user, params)
+	if(bag)
+		bag.forceMove(user)
+		bag.attackby(W, user, params)
+
+/obj/item/device/shared_storage/attack_hand(mob/living/carbon/user)
+	if(!iscarbon(user))
+		return
+	if(loc == user && user.back && user.back == src)
+		if(bag)
+			bag.forceMove(user)
+			bag.attack_hand(user)
+	else
+		..()
+
+/obj/item/device/shared_storage/MouseDrop(atom/over_object)
+	if(iscarbon(usr))
+		var/mob/M = usr
+
+		if(!over_object)
+			return
+
+		if (istype(usr.loc, /obj/mecha))
+			return
+
+		if(!M.restrained() && !M.stat)
+			playsound(loc, "rustle", 50, 1, -5)
+
+			if(istype(over_object, /obj/screen/inventory/hand))
+				if(!M.unEquip(src))
+					return
+				M.put_in_active_hand(src)
+
+			add_fingerprint(usr)
+			
+
+//Potion of Flight
+
+/obj/item/weapon/reagent_containers/glass/bottle/potion
+	icon = 'icons/obj/lavaland/artefacts.dmi'
+	icon_state = "potionflask"
+
+/obj/item/weapon/reagent_containers/glass/bottle/potion/flight
+	name = "strange elixir"
+	desc = "A flask with an almost-holy aura emitting from it. The label on the bottle says: 'erqo'hyy tvi'rf lbh jv'atf'."
+	list_reagents = list("flightpotion" = 5)
+
+/obj/item/weapon/reagent_containers/glass/bottle/potion/update_icon()
+	if(reagents.total_volume)
+		icon_state = "potionflask"
+	else
+		icon_state = "potionflask_empty"
+
+/datum/reagent/flightpotion
+	name = "Flight Potion"
+	id = "flightpotion"
+	description = "Strange mutagenic compound of unknown origins."
+	reagent_state = LIQUID
+	color = "#FFEBEB"
+
+/datum/reagent/flightpotion/reaction_mob(mob/living/M, method = TOUCH, reac_volume, show_message = 1)
+	if(ishuman(M) && M.stat != DEAD)
+		var/mob/living/carbon/human/H = M
+		if(H.species.name != "Human" || reac_volume < 5) // implying xenohumans are holy
+			if(method == INGEST && show_message)
+				to_chat(H, "<span class='notice'><i>You feel nothing but a terrible aftertaste.</i></span>")
+			return ..()
+
+		to_chat(H, "<span class='userdanger'>A terrible pain travels down your back as wings burst out!</span>")
+		H.set_species("Angel")
+		playsound(H.loc, 'sound/items/poster_ripped.ogg', 50, 1, -1)
+		H.adjustBruteLoss(20)
+		H.emote("scream")
+	..()