Reworks Ash Drake, Refactors Colossus, Fixes Endless Animal Attacks

code/modules/mob/living/carbon/alien/alien_defense.dm

@@ -59,7 +59,8 @@ In all, this is a lot like the monkey code. /N
 	return 0
 
 /mob/living/carbon/alien/attack_animal(mob/living/simple_animal/M)
-	if(..())
+	. = ..()
+	if(.)
 		var/damage = rand(M.melee_damage_lower, M.melee_damage_upper)
 		switch(M.melee_damage_type)
 			if(BRUTE)

code/modules/mob/living/carbon/human/human_defense.dm

@@ -437,16 +437,17 @@ emp_act
 					visible_message("<span class='danger'>[M] has tried to disarm [src]!</span>")
 
 /mob/living/carbon/human/attack_animal(mob/living/simple_animal/M)
-	if(..())
+	. = ..()
+	if(.)
 		var/damage = rand(M.melee_damage_lower, M.melee_damage_upper)
 		if(check_shields(damage, "the [M.name]", null, MELEE_ATTACK, M.armour_penetration))
-			return 0
+			return FALSE
 		var/dam_zone = pick("head", "chest", "groin", "l_arm", "l_hand", "r_arm", "r_hand", "l_leg", "l_foot", "r_leg", "r_foot")
 		var/obj/item/organ/external/affecting = get_organ(ran_zone(dam_zone))
+		if(!affecting)
+			affecting = get_organ("chest")
+		affecting.add_autopsy_data(M.name, damage) // Add the mob's name to the autopsy data
 		var/armor = run_armor_check(affecting, "melee", armour_penetration = M.armour_penetration)
-		var/obj/item/organ/external/affected = src.get_organ(dam_zone)
-		if(affected)
-			affected.add_autopsy_data(M.name, damage) // Add the mob's name to the autopsy data
 		apply_damage(damage, M.melee_damage_type, affecting, armor)
 		updatehealth("animal attack")
 

code/modules/mob/living/carbon/slime/slime.dm

@@ -258,7 +258,8 @@
 		M.updatehealth()
 
 /mob/living/carbon/slime/attack_animal(mob/living/simple_animal/M)
-	if(..())
+	. = ..()
+	if(.)
 		var/damage = rand(M.melee_damage_lower, M.melee_damage_upper)
 		attacked += 10
 		adjustBruteLoss(damage)

code/modules/mob/living/living_defense.dm

@@ -303,17 +303,17 @@
 	return
 
 /mob/living/attack_animal(mob/living/simple_animal/M)
+	M.face_atom(src)
 	if((M.a_intent == INTENT_HELP && M.ckey) || M.melee_damage_upper == 0)
 		M.custom_emote(1, "[M.friendly] [src].")
-		return 0
-	else
-		if(M.attack_sound)
-			playsound(loc, M.attack_sound, 50, 1, 1)
-		M.do_attack_animation(src)
-		visible_message("<span class='danger'>\The [M] [M.attacktext] [src]!</span>", \
-						"<span class='userdanger'>\The [M] [M.attacktext] [src]!</span>")
-		add_attack_logs(M, src, "Animal attacked")
-		return 1
+		return FALSE
+	if(M.attack_sound)
+		playsound(loc, M.attack_sound, 50, 1, 1)
+	M.do_attack_animation(src)
+	visible_message("<span class='danger'>\The [M] [M.attacktext] [src]!</span>", \
+					"<span class='userdanger'>\The [M] [M.attacktext] [src]!</span>")
+	add_attack_logs(M, src, "Animal attacked")
+	return TRUE
 
 /mob/living/attack_larva(mob/living/carbon/alien/larva/L)
 	switch(L.a_intent)

code/modules/mob/living/silicon/pai/pai.dm

@@ -227,14 +227,8 @@
 // See software.dm for Topic()
 
 /mob/living/silicon/pai/attack_animal(mob/living/simple_animal/M)
-	if((M.a_intent == INTENT_HELP && M.ckey) || M.melee_damage_upper == 0)
-		M.custom_emote(1, "[M.friendly] [src].")
-	else
-		M.do_attack_animation(src)
-		if(M.attack_sound)
-			playsound(loc, M.attack_sound, 50, 1, 1)
-		for(var/mob/O in viewers(src, null))
-			O.show_message("<span class='danger'>[M]</span> [M.attacktext] [src]!", 1)
+	. = ..()
+	if(.)
 		var/damage = rand(M.melee_damage_lower, M.melee_damage_upper)
 		add_attack_logs(M, src, "Animal attacked for [damage] damage")
 		adjustBruteLoss(damage)

code/modules/mob/living/silicon/silicon_defense.dm

@@ -20,7 +20,8 @@
 	return
 
 /mob/living/silicon/attack_animal(mob/living/simple_animal/M)
-	if(..())
+	. = ..()
+	if(.)
 		var/damage = rand(M.melee_damage_lower, M.melee_damage_upper)
 		switch(M.melee_damage_type)
 			if(BRUTE)

code/modules/mob/living/simple_animal/animal_defense.dm

@@ -53,9 +53,10 @@
 				L.amount_grown = min(L.amount_grown + damage, L.max_grown)
 
 /mob/living/simple_animal/attack_animal(mob/living/simple_animal/M)
-	if(..())
+	. = ..()
+	if(.)
 		var/damage = rand(M.melee_damage_lower, M.melee_damage_upper)
-		attack_threshold_check(damage, M.melee_damage_type)
+		return attack_threshold_check(damage, M.melee_damage_type)
 
 /mob/living/simple_animal/attack_slime(mob/living/carbon/slime/M)
 	..()

code/modules/mob/living/simple_animal/constructs.dm

@@ -80,7 +80,7 @@
 			else
 				to_chat(M, "<span class='cult'>You cannot repair your own dents, as you have none!</span>")
 	else if(src != M)
-		..()
+		return ..()
 
 
 /mob/living/simple_animal/hostile/construct/narsie_act()

code/modules/mob/living/simple_animal/hostile/megafauna/blood_drunk_miner.dm

@@ -30,7 +30,7 @@ Difficulty: Medium
 	icon = 'icons/mob/alienqueen.dmi'
 	light_color = "#E4C7C5"
 	speak_emote = list("roars")
-	speed = 1
+	speed = 3
 	move_to_delay = 3
 	projectiletype = /obj/item/projectile/kinetic/miner
 	projectilesound = 'sound/weapons/kenetic_accel.ogg'

code/modules/mob/living/simple_animal/hostile/megafauna/colossus.dm

@@ -1,4 +1,3 @@
-
 /*
 
 COLOSSUS
@@ -31,35 +30,74 @@ Difficulty: Very Hard
 	attack_sound = 'sound/magic/ratvar_attack.ogg'
 	icon_state = "eva"
 	icon_living = "eva"
-	icon_dead = "dragon_dead"
+	icon_dead = ""
 	friendly = "stares down"
 	icon = 'icons/mob/lavaland/96x96megafauna.dmi'
 	speak_emote = list("roars")
 	armour_penetration = 40
 	melee_damage_lower = 40
 	melee_damage_upper = 40
-	speed = 1
+	speed = 10
 	move_to_delay = 10
-	ranged = 1
+	ranged = TRUE
 	pixel_x = -32
-	del_on_death = 1
+	del_on_death = TRUE
 	internal_type = /obj/item/gps/internal/colossus
 	medal_type = BOSS_MEDAL_COLOSSUS
 	score_type = COLOSSUS_SCORE
 	crusher_loot = list(/obj/structure/closet/crate/necropolis/colossus/crusher)
 	loot = list(/obj/structure/closet/crate/necropolis/colossus)
-	butcher_results = list(/obj/item/stack/ore/diamond = 5, /obj/item/stack/sheet/sinew = 5, /obj/item/stack/sheet/animalhide/ashdrake = 10, /obj/item/stack/sheet/bone = 30)
 	deathmessage = "disintegrates, leaving a glowing core in its wake."
 	death_sound = 'sound/misc/demon_dies.ogg'
+	attack_action_types = list(/datum/action/innate/megafauna_attack/spiral_attack,
+							   /datum/action/innate/megafauna_attack/aoe_attack,
+							   /datum/action/innate/megafauna_attack/shotgun,
+							   /datum/action/innate/megafauna_attack/alternating_cardinals)
 
-/mob/living/simple_animal/hostile/megafauna/colossus/devour(mob/living/L)
-	visible_message("<span class='colossus'>[src] disintegrates [L]!</span>")
-	L.dust()
+/datum/action/innate/megafauna_attack/spiral_attack
+	name = "Spiral Shots"
+	icon_icon = 'icons/mob/actions/actions.dmi'
+	button_icon_state = "sniper_zoom"
+	chosen_message = "<span class='colossus'>You are now firing in a spiral.</span>"
+	chosen_attack_num = 1
+
+/datum/action/innate/megafauna_attack/aoe_attack
+	name = "All Directions"
+	icon_icon = 'icons/effects/effects.dmi'
+	button_icon_state = "at_shield2"
+	chosen_message = "<span class='colossus'>You are now firing in all directions.</span>"
+	chosen_attack_num = 2
+
+/datum/action/innate/megafauna_attack/shotgun
+	name = "Shotgun Fire"
+	icon_icon = 'icons/obj/guns/projectile.dmi'
+	button_icon_state = "shotgun"
+	chosen_message = "<span class='colossus'>You are now firing shotgun shots where you aim.</span>"
+	chosen_attack_num = 3
+
+/datum/action/innate/megafauna_attack/alternating_cardinals
+	name = "Alternating Shots"
+	icon_icon = 'icons/obj/guns/projectile.dmi'
+	button_icon_state = "pistol"
+	chosen_message = "<span class='colossus'>You are now firing in alternating cardinal directions.</span>"
+	chosen_attack_num = 4
 
 /mob/living/simple_animal/hostile/megafauna/colossus/OpenFire()
 	anger_modifier = Clamp(((maxHealth - health)/50),0,20)
 	ranged_cooldown = world.time + 120
 
+	if(client)
+		switch(chosen_attack)
+			if(1)
+				select_spiral_attack()
+			if(2)
+				random_shots()
+			if(3)
+				blast()
+			if(4)
+				alternating_dir_shots()
+		return
+
 	if(enrage(target))
 		if(move_to_delay == initial(move_to_delay))
 			visible_message("<span class='colossus'>\"<b>You can't dodge.</b>\"</span>")
@@ -72,52 +110,14 @@ Difficulty: Very Hard
 		move_to_delay = initial(move_to_delay)
 
 	if(prob(20+anger_modifier)) //Major attack
-		telegraph()
-
-		if(health < maxHealth/3)
-			double_spiral()
-		else
-			visible_message("<span class='colossus'>\"<b>Judgement.</b>\"</span>")
-			spawn(0)
-				spiral_shoot(rand(0, 1))
-
+		select_spiral_attack()
 	else if(prob(20))
-		ranged_cooldown = world.time + 30
 		random_shots()
 	else
 		if(prob(70))
-			ranged_cooldown = world.time + 20
 			blast()
 		else
-			ranged_cooldown = world.time + 40
-			spawn(0)
-				alternating_dir_shots()
-
-/obj/effect/temp_visual/at_shield
-	name = "anti-toolbox field"
-	desc = "A shimmering forcefield protecting the colossus."
-	icon = 'icons/effects/effects.dmi'
-	icon_state = "at_shield2"
-	layer = FLY_LAYER
-	luminosity = 2
-	duration = 8
-	var/target
-
-/obj/effect/temp_visual/at_shield/New(new_loc, new_target)
-	..()
-	target = new_target
-	spawn(0)
-		orbit(target, 0, FALSE, 0, 0, FALSE, TRUE)
-
-/mob/living/simple_animal/hostile/megafauna/colossus/bullet_act(obj/item/projectile/P)
-	if(!stat)
-		var/obj/effect/temp_visual/at_shield/AT = new /obj/effect/temp_visual/at_shield(loc, src)
-		var/random_x = rand(-32, 32)
-		AT.pixel_x += random_x
-
-		var/random_y = rand(0, 72)
-		AT.pixel_y += random_y
-	..()
+			alternating_dir_shots()
 
 /mob/living/simple_animal/hostile/megafauna/colossus/proc/enrage(mob/living/L)
 	if(ishuman(L))
@@ -126,61 +126,33 @@ Difficulty: Very Hard
 			. = TRUE
 
 /mob/living/simple_animal/hostile/megafauna/colossus/proc/alternating_dir_shots()
+	ranged_cooldown = world.time + 40
 	dir_shots(diagonals)
-	sleep(10)
+	SLEEP_CHECK_DEATH(10)
 	dir_shots(cardinal)
-	sleep(10)
+	SLEEP_CHECK_DEATH(10)
 	dir_shots(diagonals)
-	sleep(10)
+	SLEEP_CHECK_DEATH(10)
 	dir_shots(cardinal)
 
+/mob/living/simple_animal/hostile/megafauna/colossus/proc/select_spiral_attack()
+	telegraph()
+	if(health < maxHealth/3)
+		return double_spiral()
+	visible_message("<span class='colossus'>\"<b>Judgement.</b>\"</span>")
+	return spiral_shoot()
+
 /mob/living/simple_animal/hostile/megafauna/colossus/proc/double_spiral()
 	visible_message("<span class='colossus'>\"<b>Die.</b>\"</span>")
 
-	sleep(10)
-	spawn(0)
-		spiral_shoot()
-	spawn(0)
-		spiral_shoot(1)
+	SLEEP_CHECK_DEATH(10)
+	INVOKE_ASYNC(src, .proc/spiral_shoot, FALSE)
+	INVOKE_ASYNC(src, .proc/spiral_shoot, TRUE)
 
-/mob/living/simple_animal/hostile/megafauna/colossus/proc/spiral_shoot(negative = 0, counter_start = 1)
+/mob/living/simple_animal/hostile/megafauna/colossus/proc/spiral_shoot(negative = pick(TRUE, FALSE), counter_start = 8)
+	var/turf/start_turf = get_step(src, pick(alldirs))
 	var/counter = counter_start
-	var/turf/marker
 	for(var/i in 1 to 80)
-		switch(counter)
-			if(1)
-				marker = locate(x, y - 2, z)
-			if(2)
-				marker = locate(x - 1, y - 2, z)
-			if(3)
-				marker = locate(x - 2, y - 2, z)
-			if(4)
-				marker = locate(x - 2, y - 1, z)
-			if(5)
-				marker = locate(x - 2, y, z)
-			if(6)
-				marker = locate(x - 2, y + 1, z)
-			if(7)
-				marker = locate(x - 2, y + 2, z)
-			if(8)
-				marker = locate(x - 1, y + 2, z)
-			if(9)
-				marker = locate(x, y + 2, z)
-			if(10)
-				marker = locate(x + 1, y + 2, z)
-			if(11)
-				marker = locate(x + 2, y + 2, z)
-			if(12)
-				marker = locate(x + 2, y + 1, z)
-			if(13)
-				marker = locate(x + 2, y, z)
-			if(14)
-				marker = locate(x + 2, y - 1, z)
-			if(15)
-				marker = locate(x + 2, y - 2, z)
-			if(16)
-				marker = locate(x + 1, y - 2, z)
-
 		if(negative)
 			counter--
 		else
@@ -189,44 +161,45 @@ Difficulty: Very Hard
 			counter = 1
 		if(counter < 1)
 			counter = 16
-		shoot_projectile(marker)
-		playsound(get_turf(src), 'sound/magic/invoke_general.ogg', 20, 1)
-		sleep(1)
+		shoot_projectile(start_turf, counter * 22.5)
+		playsound(get_turf(src), 'sound/magic/clockwork/invoke_general.ogg', 20, TRUE)
+		SLEEP_CHECK_DEATH(1)
 
-/mob/living/simple_animal/hostile/megafauna/colossus/proc/shoot_projectile(turf/marker)
-	if(!marker || marker == loc)
+/mob/living/simple_animal/hostile/megafauna/colossus/proc/shoot_projectile(turf/marker, set_angle)
+	if(!isnum(set_angle) && (!marker || marker == loc))
 		return
 	var/turf/startloc = get_turf(src)
 	var/obj/item/projectile/P = new /obj/item/projectile/colossus(startloc)
-	P.current = startloc
-	P.starting = startloc
+	P.preparePixelProjectile(marker, marker, startloc)
 	P.firer = src
-	P.yo = marker.y - startloc.y
-	P.xo = marker.x - startloc.x
 	if(target)
 		P.original = target
-	else
-		P.original = marker
-	P.fire()
+	P.fire(set_angle)
 
 /mob/living/simple_animal/hostile/megafauna/colossus/proc/random_shots()
+	ranged_cooldown = world.time + 30
 	var/turf/U = get_turf(src)
-	playsound(U, 'sound/magic/invoke_general.ogg', 300, 1, 5)
+	playsound(U, 'sound/magic/clockwork/invoke_general.ogg', 300, TRUE, 5)
 	for(var/T in RANGE_TURFS(12, U) - U)
 		if(prob(5))
 			shoot_projectile(T)
 
-/mob/living/simple_animal/hostile/megafauna/colossus/proc/blast()
-	playsound(get_turf(src), 'sound/magic/invoke_general.ogg', 200, 1, 2)
-	var/turf/T = get_turf(target)
-	newtonian_move(get_dir(T, targets_from))
-	for(var/turf/turf in range(1, T))
-		shoot_projectile(turf)
+/mob/living/simple_animal/hostile/megafauna/colossus/proc/blast(set_angle)
+	ranged_cooldown = world.time + 20
+	var/turf/target_turf = get_turf(target)
+	playsound(src, 'sound/magic/clockwork/invoke_general.ogg', 200, TRUE, 2)
+	newtonian_move(get_dir(target_turf, src))
+	var/angle_to_target = Get_Angle(src, target_turf)
+	if(isnum(set_angle))
+		angle_to_target = set_angle
+	var/static/list/colossus_shotgun_shot_angles = list(12.5, 7.5, 2.5, -2.5, -7.5, -12.5)
+	for(var/i in colossus_shotgun_shot_angles)
+		shoot_projectile(target_turf, angle_to_target + i)
 
 /mob/living/simple_animal/hostile/megafauna/colossus/proc/dir_shots(list/dirs)
 	if(!islist(dirs))
 		dirs = alldirs.Copy()
-	playsound(get_turf(src), 'sound/magic/invoke_general.ogg', 200, 1, 2)
+	playsound(src, 'sound/magic/clockwork/invoke_general.ogg', 200, TRUE, 2)
 	for(var/d in dirs)
 		var/turf/E = get_step(src, d)
 		shoot_projectile(E)
@@ -234,9 +207,29 @@ Difficulty: Very Hard
 /mob/living/simple_animal/hostile/megafauna/colossus/proc/telegraph()
 	for(var/mob/M in range(10,src))
 		if(M.client)
-			flash_color(M.client, rgb(200, 0, 0), 1)
+			flash_color(M.client, "#C80000", 1)
 			shake_camera(M, 4, 3)
-	playsound(get_turf(src),'sound/magic/narsie_attack.ogg', 200, 1)
+	playsound(src, 'sound/magic/narsie_attack.ogg', 200, TRUE)
+
+
+/mob/living/simple_animal/hostile/megafauna/colossus/devour(mob/living/L)
+	visible_message("<span class='colossus'>[src] disintegrates [L]!</span>")
+	L.dust()
+
+/obj/effect/temp_visual/at_shield
+	name = "anti-toolbox field"
+	desc = "A shimmering forcefield protecting the colossus."
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "at_shield2"
+	layer = FLY_LAYER
+	light_range = 2
+	duration = 8
+	var/target
+
+/obj/effect/temp_visual/at_shield/Initialize(mapload, new_target)
+	. = ..()
+	target = new_target
+	INVOKE_ASYNC(src, /atom/movable/proc/orbit, target, 0, FALSE, 0, 0, FALSE, TRUE)
 
 /obj/item/projectile/colossus
 	name ="death bolt"

code/modules/mob/living/simple_animal/hostile/megafauna/drake.dm

@@ -1,3 +1,9 @@
+#define DRAKE_SWOOP_HEIGHT 270 //how high up drakes go, in pixels
+#define DRAKE_SWOOP_DIRECTION_CHANGE_RANGE 5 //the range our x has to be within to not change the direction we slam from
+
+#define SWOOP_DAMAGEABLE 1
+#define SWOOP_INVULNERABLE 2
+
 /*
 
 ASH DRAKE
@@ -6,10 +12,11 @@ Ash drakes spawn randomly wherever a lavaland creature is able to spawn. They ar
 
 It acts as a melee creature, chasing down and attacking its target while also using different attacks to augment its power that increase as it takes damage.
 
-Whenever possible, the drake will breathe fire in the four cardinal directions, igniting and heavily damaging anything caught in the blast.
-It also often causes fire to rain from the sky - many nearby turfs will flash red as a fireball crashes into them, dealing damage to anything on the turfs.
-The drake also utilizes its wings to fly into the sky and crash down onto a specified point. Anything on this point takes tremendous damage.
+Whenever possible, the drake will breathe fire directly at it's target, igniting and heavily damaging anything caught in the blast.
+It also often causes lava to pool from the ground around you - many nearby turfs will temporarily turn into lava, dealing damage to anything on the turfs.
+The drake also utilizes its wings to fly into the sky, flying after its target and attempting to slam down on them. Anything near when it slams down takes huge damage.
  - Sometimes it will chain these swooping attacks over and over, making swiftness a necessity.
+ - Sometimes, it will encase its target in an arena of lava
 
 When an ash drake dies, it leaves behind a chest that can contain four things:
  1. A spectral blade that allows its wielder to call ghosts to it, enhancing its power
@@ -39,31 +46,358 @@ Difficulty: Medium
 	armour_penetration = 40
 	melee_damage_lower = 40
 	melee_damage_upper = 40
-	speed = 1
-	move_to_delay = 10
-	ranged = 1
+	speed = 5
+	move_to_delay = 5
+	ranged = TRUE
 	pixel_x = -16
 	crusher_loot = list(/obj/structure/closet/crate/necropolis/dragon/crusher)
 	loot = list(/obj/structure/closet/crate/necropolis/dragon)
 	butcher_results = list(/obj/item/stack/ore/diamond = 5, /obj/item/stack/sheet/sinew = 5, /obj/item/stack/sheet/animalhide/ashdrake = 10, /obj/item/stack/sheet/bone = 30)
-	var/swooping = 0
-	var/swoop_cooldown = 0
+	var/swooping = NONE
+	var/player_cooldown = 0
 	internal_type = /obj/item/gps/internal/dragon
 	medal_type = BOSS_MEDAL_DRAKE
 	score_type = DRAKE_SCORE
 	deathmessage = "collapses into a pile of bones, its flesh sloughing away."
 	death_sound = 'sound/misc/demon_dies.ogg'
+	attack_action_types = list(/datum/action/innate/megafauna_attack/fire_cone,
+							   /datum/action/innate/megafauna_attack/fire_cone_meteors,
+							   /datum/action/innate/megafauna_attack/mass_fire,
+							   /datum/action/innate/megafauna_attack/lava_swoop)
+
+/datum/action/innate/megafauna_attack/fire_cone
+	name = "Fire Cone"
+	icon_icon = 'icons/obj/wizard.dmi'
+	button_icon_state = "fireball"
+	chosen_message = "<span class='colossus'>You are now shooting fire at your target.</span>"
+	chosen_attack_num = 1
+
+/datum/action/innate/megafauna_attack/fire_cone_meteors
+	name = "Fire Cone With Meteors"
+	icon_icon = 'icons/mob/actions/actions.dmi'
+	button_icon_state = "sniper_zoom"
+	chosen_message = "<span class='colossus'>You are now shooting fire at your target and raining fire around you.</span>"
+	chosen_attack_num = 2
+
+/datum/action/innate/megafauna_attack/mass_fire
+	name = "Mass Fire Attack"
+	icon_icon = 'icons/effects/fire.dmi'
+	button_icon_state = "1"
+	chosen_message = "<span class='colossus'>You are now shooting mass fire at your target.</span>"
+	chosen_attack_num = 3
+
+/datum/action/innate/megafauna_attack/lava_swoop
+	name = "Lava Swoop"
+	icon_icon = 'icons/effects/effects.dmi'
+	button_icon_state = "lavastaff_warn"
+	chosen_message = "<span class='colossus'>You are now swooping and raining lava at your target.</span>"
+	chosen_attack_num = 4
+
+/obj/item/gps/internal/dragon
+	icon_state = null
+	gpstag = "Fiery Signal"
+	desc = "Here there be dragons."
+	invisibility = 100
+
+/mob/living/simple_animal/hostile/megafauna/dragon/OpenFire()
+	if(swooping)
+		return
+
+	anger_modifier = Clamp(((maxHealth - health)/50),0,20)
+	ranged_cooldown = world.time + ranged_cooldown_time
+
+	if(client)
+		switch(chosen_attack)
+			if(1)
+				fire_cone(meteors = FALSE)
+			if(2)
+				fire_cone()
+			if(3)
+				mass_fire()
+			if(4)
+				lava_swoop()
+		return
+
+	if(prob(15 + anger_modifier))
+		lava_swoop()
+
+	else if(prob(10+anger_modifier))
+		shoot_fire_attack()
+	else
+		fire_cone()
+
+/mob/living/simple_animal/hostile/megafauna/dragon/proc/shoot_fire_attack()
+	if(health < maxHealth*0.5)
+		mass_fire()
+	else
+		fire_cone()
+
+/mob/living/simple_animal/hostile/megafauna/dragon/proc/fire_rain()
+	if(!target)
+		return
+	target.visible_message("<span class='boldwarning'>Fire rains from the sky!</span>")
+	for(var/turf/turf in range(9,get_turf(target)))
+		if(prob(11))
+			new /obj/effect/temp_visual/target(turf)
+
+/mob/living/simple_animal/hostile/megafauna/dragon/proc/lava_pools(var/amount, var/delay = 0.8)
+	if(!target)
+		return
+	target.visible_message("<span class='boldwarning'>Lava starts to pool up around you!</span>")
+	while(amount > 0)
+		if(QDELETED(target))
+			break
+		var/turf/T = pick(RANGE_TURFS(1, target))
+		new /obj/effect/temp_visual/lava_warning(T, 60) // longer reset time for the lava
+		amount--
+		SLEEP_CHECK_DEATH(delay)
+
+/mob/living/simple_animal/hostile/megafauna/dragon/proc/lava_swoop(var/amount = 30)
+	if(health < maxHealth * 0.5)
+		return swoop_attack(lava_arena = TRUE, swoop_cooldown = 60)
+	INVOKE_ASYNC(src, .proc/lava_pools, amount)
+	swoop_attack(FALSE, target, 1000) // longer cooldown until it gets reset below
+	SLEEP_CHECK_DEATH(0)
+	fire_cone()
+	if(health < maxHealth*0.5)
+		SLEEP_CHECK_DEATH(10)
+		fire_cone()
+		SLEEP_CHECK_DEATH(10)
+		fire_cone()
+	SetRecoveryTime(40)
+
+/mob/living/simple_animal/hostile/megafauna/dragon/proc/mass_fire(var/spiral_count = 12, var/range = 15, var/times = 3)
+	SLEEP_CHECK_DEATH(0)
+	for(var/i = 1 to times)
+		SetRecoveryTime(50)
+		playsound(get_turf(src),'sound/magic/fireball.ogg', 200, TRUE)
+		var/increment = 360 / spiral_count
+		for(var/j = 1 to spiral_count)
+			var/list/turfs = line_target(j * increment + i * increment / 2, range, src)
+			INVOKE_ASYNC(src, .proc/fire_line, turfs)
+		SLEEP_CHECK_DEATH(25)
+	SetRecoveryTime(30)
+
+/mob/living/simple_animal/hostile/megafauna/dragon/proc/lava_arena()
+	if(!target)
+		return
+	target.visible_message("<span class='boldwarning'>[src] encases you in an arena of fire!</span>")
+	var/amount = 3
+	var/turf/center = get_turf(target)
+	var/list/walled = RANGE_TURFS(3, center) - RANGE_TURFS(2, center)
+	var/list/drakewalls = list()
+	for(var/turf/T in walled)
+		drakewalls += new /obj/effect/temp_visual/drakewall(T) // no people with lava immunity can just run away from the attack for free
+	var/list/indestructible_turfs = list()
+	for(var/turf/T in RANGE_TURFS(2, center))
+		if(istype(T, /turf/simulated/floor/indestructible))
+			continue
+		if(!istype(T, /turf/simulated/wall/indestructible))
+			T.ChangeTurf(/turf/simulated/floor/plating/asteroid/basalt/lava_land_surface)
+		else
+			indestructible_turfs += T
+	SLEEP_CHECK_DEATH(10) // give them a bit of time to realize what attack is actually happening
+
+	var/list/turfs = RANGE_TURFS(2, center)
+	while(amount > 0)
+		var/list/empty = indestructible_turfs.Copy() // can't place safe turfs on turfs that weren't changed to be open
+		var/any_attack = 0
+		for(var/turf/T in turfs)
+			for(var/mob/living/L in T.contents)
+				if(L.client)
+					empty += pick(((RANGE_TURFS(2, L) - RANGE_TURFS(1, L)) & turfs) - empty) // picks a turf within 2 of the creature not outside or in the shield
+					any_attack = 1
+			for(var/obj/mecha/M in T.contents)
+				empty += pick(((RANGE_TURFS(2, M) - RANGE_TURFS(1, M)) & turfs) - empty)
+				any_attack = 1
+		if(!any_attack)
+			for(var/obj/effect/temp_visual/drakewall/D in drakewalls)
+				qdel(D)
+			return 0 // nothing to attack in the arena time for enraged attack if we still have a target
+		for(var/turf/T in turfs)
+			if(!(T in empty))
+				new /obj/effect/temp_visual/lava_warning(T)
+			else if(!istype(T, /turf/simulated/wall/indestructible))
+				new /obj/effect/temp_visual/lava_safe(T)
+		amount--
+		SLEEP_CHECK_DEATH(24)
+	return 1 // attack finished completely
+
+/mob/living/simple_animal/hostile/megafauna/dragon/proc/arena_escape_enrage() // you ran somehow / teleported away from my arena attack now i'm mad fucker
+	SLEEP_CHECK_DEATH(0)
+	SetRecoveryTime(80)
+	visible_message("<span class='boldwarning'>[src] starts to glow vibrantly as its wounds close up!</span>")
+	adjustBruteLoss(-250) // yeah you're gonna pay for that, don't run nerd
+	add_atom_colour(rgb(255, 255, 0), TEMPORARY_COLOUR_PRIORITY)
+	move_to_delay = move_to_delay / 2
+	light_range = 10
+	SLEEP_CHECK_DEATH(10) // run.
+	mass_fire(20, 15, 3)
+	move_to_delay = initial(move_to_delay)
+	remove_atom_colour(TEMPORARY_COLOUR_PRIORITY)
+	light_range = initial(light_range)
+
+/mob/living/simple_animal/hostile/megafauna/dragon/proc/fire_cone(var/atom/at = target, var/meteors = TRUE)
+	playsound(get_turf(src),'sound/magic/fireball.ogg', 200, TRUE)
+	SLEEP_CHECK_DEATH(0)
+	if(prob(50) && meteors)
+		INVOKE_ASYNC(src, .proc/fire_rain)
+	var/range = 15
+	var/list/turfs = list()
+	turfs = line_target(-40, range, at)
+	INVOKE_ASYNC(src, .proc/fire_line, turfs)
+	turfs = line_target(0, range, at)
+	INVOKE_ASYNC(src, .proc/fire_line, turfs)
+	turfs = line_target(40, range, at)
+	INVOKE_ASYNC(src, .proc/fire_line, turfs)
+
+/mob/living/simple_animal/hostile/megafauna/dragon/proc/line_target(var/offset, var/range, var/atom/at = target)
+	if(!at)
+		return
+	var/angle = Atan2(at.x - src.x, at.y - src.y) + offset
+	var/turf/T = get_turf(src)
+	for(var/i in 1 to range)
+		var/turf/check = locate(src.x + cos(angle) * i, src.y + sin(angle) * i, src.z)
+		if(!check)
+			break
+		T = check
+	return (getline(src, T) - get_turf(src))
+
+/mob/living/simple_animal/hostile/megafauna/dragon/proc/fire_line(var/list/turfs)
+	SLEEP_CHECK_DEATH(0)
+	dragon_fire_line(src, turfs)
+
+//fire line keeps going even if dragon is deleted
+/proc/dragon_fire_line(var/source, var/list/turfs)
+	var/list/hit_list = list()
+	for(var/turf/T in turfs)
+		if(T.density)
+			break
+		new /obj/effect/hotspot(T)
+		T.hotspot_expose(700,50,1)
+		for(var/mob/living/L in T.contents)
+			if(L in hit_list || L == source)
+				continue
+			hit_list += L
+			L.adjustFireLoss(20)
+			to_chat(L, "<span class='userdanger'>You're hit by [source]'s fire breath!</span>")
+
+		// deals damage to mechs
+		for(var/obj/mecha/M in T.contents)
+			if(M in hit_list)
+				continue
+			hit_list += M
+			M.take_damage(45, BRUTE, "melee", 1)
+		sleep(1.5)
+
+/mob/living/simple_animal/hostile/megafauna/dragon/proc/swoop_attack(lava_arena = FALSE, atom/movable/manual_target, var/swoop_cooldown = 30)
+	if(stat || swooping)
+		return
+	if(manual_target)
+		target = manual_target
+	if(!target)
+		return
+	stop_automated_movement = TRUE
+	swooping |= SWOOP_DAMAGEABLE
+	density = FALSE
+	icon_state = "shadow"
+	visible_message("<span class='boldwarning'>[src] swoops up high!</span>")
+
+	var/negative
+	var/initial_x = x
+	if(target.x < initial_x) //if the target's x is lower than ours, swoop to the left
+		negative = TRUE
+	else if(target.x > initial_x)
+		negative = FALSE
+	else if(target.x == initial_x) //if their x is the same, pick a direction
+		negative = prob(50)
+	var/obj/effect/temp_visual/dragon_flight/F = new /obj/effect/temp_visual/dragon_flight(loc, negative)
+
+	negative = !negative //invert it for the swoop down later
+
+	var/oldtransform = transform
+	alpha = 255
+	animate(src, alpha = 204, transform = matrix()*0.9, time = 3, easing = BOUNCE_EASING)
+	for(var/i in 1 to 3)
+		sleep(1)
+		if(QDELETED(src) || stat == DEAD) //we got hit and died, rip us
+			qdel(F)
+			if(stat == DEAD)
+				swooping &= ~SWOOP_DAMAGEABLE
+				animate(src, alpha = 255, transform = oldtransform, time = 0, flags = ANIMATION_END_NOW) //reset immediately
+			return
+	animate(src, alpha = 100, transform = matrix()*0.7, time = 7)
+	swooping |= SWOOP_INVULNERABLE
+	mouse_opacity = MOUSE_OPACITY_TRANSPARENT
+	SLEEP_CHECK_DEATH(7)
+
+	while(target && loc != get_turf(target))
+		forceMove(get_step(src, get_dir(src, target)))
+		SLEEP_CHECK_DEATH(0.5)
+
+	// Ash drake flies onto its target and rains fire down upon them
+	var/descentTime = 10
+	var/lava_success = TRUE
+	if(lava_arena)
+		lava_success = lava_arena()
+
+
+	//ensure swoop direction continuity.
+	if(negative)
+		if(IsInRange(x, initial_x + 1, initial_x + DRAKE_SWOOP_DIRECTION_CHANGE_RANGE))
+			negative = FALSE
+	else
+		if(IsInRange(x, initial_x - DRAKE_SWOOP_DIRECTION_CHANGE_RANGE, initial_x - 1))
+			negative = TRUE
+	new /obj/effect/temp_visual/dragon_flight/end(loc, negative)
+	new /obj/effect/temp_visual/dragon_swoop(loc)
+	animate(src, alpha = 255, transform = oldtransform, descentTime)
+	SLEEP_CHECK_DEATH(descentTime)
+	swooping &= ~SWOOP_INVULNERABLE
+	mouse_opacity = initial(mouse_opacity)
+	icon_state = "dragon"
+	playsound(loc, 'sound/effects/meteorimpact.ogg', 200, TRUE)
+	for(var/mob/living/L in orange(1, src))
+		if(L.stat)
+			visible_message("<span class='warning'>[src] slams down on [L], crushing [L.p_them()]!</span>")
+			L.gib()
+		else
+			L.adjustBruteLoss(75)
+			if(L && !QDELETED(L)) // Some mobs are deleted on death
+				var/throw_dir = get_dir(src, L)
+				if(L.loc == loc)
+					throw_dir = pick(alldirs)
+				var/throwtarget = get_edge_target_turf(src, throw_dir)
+				L.throw_at(throwtarget, 3)
+				visible_message("<span class='warning'>[L] is thrown clear of [src]!</span>")
+	for(var/obj/mecha/M in orange(1, src))
+		M.take_damage(75, BRUTE, "melee", 1)
+
+	for(var/mob/M in range(7, src))
+		shake_camera(M, 15, 1)
+
+	density = TRUE
+	SLEEP_CHECK_DEATH(1)
+	swooping &= ~SWOOP_DAMAGEABLE
+	SetRecoveryTime(swoop_cooldown)
+	if(!lava_success)
+		arena_escape_enrage()
 
 /mob/living/simple_animal/hostile/megafauna/dragon/ex_act(severity, target)
-	if(severity == 3)
+	if(severity == EXPLODE_LIGHT)
 		return
 	..()
 
 /mob/living/simple_animal/hostile/megafauna/dragon/adjustHealth(amount, updating_health = TRUE)
-	if(swooping)
+	if(swooping & SWOOP_INVULNERABLE)
 		return FALSE
 	return ..()
 
+/mob/living/simple_animal/hostile/megafauna/dragon/visible_message()
+	if(swooping & SWOOP_INVULNERABLE) //to suppress attack messages without overriding every single proc that could send a message saying we got hit
+		return
+	return ..()
+
 /mob/living/simple_animal/hostile/megafauna/dragon/AttackingTarget()
 	if(!swooping)
 		return ..()
@@ -83,181 +417,161 @@ Difficulty: Medium
 /mob/living/simple_animal/hostile/megafauna/dragon/Process_Spacemove(movement_dir = 0)
 	return 1
 
-/obj/effect/temp_visual/fireball
-	icon = 'icons/obj/wizard.dmi'
-	icon_state = "fireball"
-	name = "fireball"
-	desc = "Get out of the way!"
-	layer = 6
-	randomdir = 0
-	duration = 12
-	pixel_z = 500
+/obj/effect/temp_visual/lava_warning
+	icon_state = "lavastaff_warn"
+	layer = BELOW_MOB_LAYER
+	light_range = 2
+	duration = 13
 
-/obj/effect/temp_visual/fireball/New(loc)
-	..()
-	animate(src, pixel_z = 0, time = 12)
+/obj/effect/temp_visual/lava_warning/ex_act()
+	return
 
-/obj/effect/temp_visual/target
-	icon = 'icons/mob/actions/actions.dmi'
-	icon_state = "sniper_zoom"
-	layer = MOB_LAYER - 0.1
-	luminosity = 2
-	duration = 12
+/obj/effect/temp_visual/lava_warning/Initialize(mapload, var/reset_time = 10)
+	. = ..()
+	INVOKE_ASYNC(src, .proc/fall, reset_time)
+	src.alpha = 63.75
+	animate(src, alpha = 255, time = duration)
+
+/obj/effect/temp_visual/lava_warning/proc/fall(var/reset_time)
+	var/turf/T = get_turf(src)
+	playsound(T,'sound/magic/fleshtostone.ogg', 80, TRUE)
+	sleep(duration)
+	playsound(T,'sound/magic/fireball.ogg', 200, TRUE)
+
+	for(var/mob/living/L in T.contents)
+		if(istype(L, /mob/living/simple_animal/hostile/megafauna/dragon))
+			continue
+		L.adjustFireLoss(10)
+		to_chat(L, "<span class='userdanger'>You fall directly into the pool of lava!</span>")
+
+	// deals damage to mechs
+	for(var/obj/mecha/M in T.contents)
+		M.take_damage(45, BRUTE, "melee", 1)
+
+	// changes turf to lava temporarily
+	if(!T.density && !istype(T, /turf/simulated/floor/plating/lava))
+		var/lava_turf = /turf/simulated/floor/plating/lava/smooth
+		var/reset_turf = T.type
+		T.ChangeTurf(lava_turf)
+		sleep(reset_time)
+		T.ChangeTurf(reset_turf)
+
+/obj/effect/temp_visual/drakewall
+	desc = "An ash drakes true flame."
+	name = "Fire Barrier"
+	icon = 'icons/effects/fire.dmi'
+	icon_state = "1"
+	anchored = TRUE
+	opacity = 0
+	density = TRUE
+	duration = 82
+	color = COLOR_DARK_ORANGE
+
+/obj/effect/temp_visual/drakewall/CanAtmosPass()
+	return !density
+
+/obj/effect/temp_visual/lava_safe
+	icon = 'icons/obj/hand_of_god_structures.dmi'
+	icon_state = "trap-earth"
+	layer = BELOW_MOB_LAYER
+	light_range = 2
+	duration = 13
 
 /obj/effect/temp_visual/dragon_swoop
 	name = "certain death"
 	desc = "Don't just stand there, move!"
 	icon = 'icons/effects/96x96.dmi'
 	icon_state = "landing"
-	layer = MOB_LAYER - 0.1
+	layer = BELOW_MOB_LAYER
 	pixel_x = -32
 	pixel_y = -32
 	color = "#FF0000"
 	duration = 10
 
+/obj/effect/temp_visual/dragon_flight
+	icon = 'icons/mob/lavaland/64x64megafauna.dmi'
+	icon_state = "dragon"
+	layer = ABOVE_ALL_MOB_LAYER
+	pixel_x = -16
+	duration = 10
+	randomdir = FALSE
+
+/obj/effect/temp_visual/dragon_flight/Initialize(mapload, negative)
+	. = ..()
+	INVOKE_ASYNC(src, .proc/flight, negative)
+
+/obj/effect/temp_visual/dragon_flight/proc/flight(negative)
+	if(negative)
+		animate(src, pixel_x = -DRAKE_SWOOP_HEIGHT*0.1, pixel_z = DRAKE_SWOOP_HEIGHT*0.15, time = 3, easing = BOUNCE_EASING)
+	else
+		animate(src, pixel_x = DRAKE_SWOOP_HEIGHT*0.1, pixel_z = DRAKE_SWOOP_HEIGHT*0.15, time = 3, easing = BOUNCE_EASING)
+	sleep(3)
+	icon_state = "swoop"
+	if(negative)
+		animate(src, pixel_x = -DRAKE_SWOOP_HEIGHT, pixel_z = DRAKE_SWOOP_HEIGHT, time = 7)
+	else
+		animate(src, pixel_x = DRAKE_SWOOP_HEIGHT, pixel_z = DRAKE_SWOOP_HEIGHT, time = 7)
+
+/obj/effect/temp_visual/dragon_flight/end
+	pixel_x = DRAKE_SWOOP_HEIGHT
+	pixel_z = DRAKE_SWOOP_HEIGHT
+	duration = 10
+
+/obj/effect/temp_visual/dragon_flight/end/flight(negative)
+	if(negative)
+		pixel_x = -DRAKE_SWOOP_HEIGHT
+		animate(src, pixel_x = -16, pixel_z = 0, time = 5)
+	else
+		animate(src, pixel_x = -16, pixel_z = 0, time = 5)
+
+obj/effect/temp_visual/fireball
+	icon = 'icons/obj/wizard.dmi'
+	icon_state = "fireball"
+	name = "fireball"
+	desc = "Get out of the way!"
+	layer = FLY_LAYER
+	randomdir = FALSE
+	duration = 9
+	pixel_z = 270
+
+/obj/effect/temp_visual/fireball/Initialize()
+	. = ..()
+	animate(src, pixel_z = 0, time = duration)
+
+/obj/effect/temp_visual/target
+	icon = 'icons/mob/actions/actions.dmi'
+	icon_state = "sniper_zoom"
+	layer = BELOW_MOB_LAYER
+	light_range = 2
+	duration = 9
+
 /obj/effect/temp_visual/target/ex_act()
 	return
 
-/obj/effect/temp_visual/target/New(loc)
-	..()
-	spawn(0)
-		fall()
+/obj/effect/temp_visual/target/Initialize(mapload, list/flame_hit)
+	. = ..()
+	INVOKE_ASYNC(src, .proc/fall, flame_hit)
 
-/obj/effect/temp_visual/target/proc/fall()
+/obj/effect/temp_visual/target/proc/fall(list/flame_hit)
 	var/turf/T = get_turf(src)
-	playsound(T,'sound/magic/fireball.ogg', 200, 1)
+	playsound(T,'sound/magic/fleshtostone.ogg', 80, TRUE)
 	new /obj/effect/temp_visual/fireball(T)
-	sleep(12)
-	explosion(T, 0, 0, 1, 0, 0, 0, 1, 1)
-
-/mob/living/simple_animal/hostile/megafauna/dragon/OpenFire()
-	anger_modifier = Clamp(((maxHealth - health)/50),0,20)
-	ranged_cooldown = world.time + ranged_cooldown_time
-	if(swooping)
-		fire_rain()
-		return
-
-	if(prob(15 + anger_modifier) && !client)
-		if(health < maxHealth/2)
-			spawn(0)
-				swoop_attack(1)
-		else
-			fire_rain()
-
-	else if(prob(10+anger_modifier) && !client)
-		if(health > maxHealth/2)
-			spawn(0)
-				swoop_attack(0)
-		else
-			spawn(0)
-				triple_swoop(0)
-	else
-		fire_walls()
-
-/mob/living/simple_animal/hostile/megafauna/dragon/proc/fire_rain()
-	visible_message("<span class='boldwarning'>Fire rains from the sky!</span>")
-	for(var/turf/turf in range(12,get_turf(src)))
-		if(prob(10))
-			new /obj/effect/temp_visual/target(turf)
-
-/mob/living/simple_animal/hostile/megafauna/dragon/proc/fire_walls()
-	playsound(get_turf(src),'sound/magic/fireball.ogg', 200, 1)
-
-	for(var/d in cardinal)
-		spawn(0)
-			fire_wall(d)
-
-/mob/living/simple_animal/hostile/megafauna/dragon/proc/fire_wall(dir)
-	var/list/hit_things = list(src)
-	var/turf/E = get_edge_target_turf(src, dir)
-	var/range = 10
-	var/turf/previousturf = get_turf(src)
-	for(var/turf/J in getline(src,E))
-		if(!range || !previousturf.CanAtmosPass(J))
-			break
-		range--
-		new /obj/effect/hotspot(J)
-		J.hotspot_expose(700,50,1)
-		for(var/mob/living/L in J.contents - hit_things)
-			L.adjustFireLoss(20)
+	sleep(duration)
+	if(ismineralturf(T))
+		var/turf/simulated/mineral/M = T
+		M.gets_drilled()
+	playsound(T, "explosion", 80, TRUE)
+	new /obj/effect/hotspot(T)
+	T.hotspot_expose(700, 50, 1)
+	for(var/mob/living/L in T.contents)
+		if(istype(L, /mob/living/simple_animal/hostile/megafauna/dragon))
+			continue
+		if(islist(flame_hit) && !flame_hit[L])
+			L.adjustFireLoss(40)
 			to_chat(L, "<span class='userdanger'>You're hit by the drake's fire breath!</span>")
-			hit_things += L
-		previousturf = J
-		sleep(1)
-
-/mob/living/simple_animal/hostile/megafauna/dragon/proc/triple_swoop()
-	swoop_attack()
-	swoop_attack()
-	swoop_attack()
-
-/mob/living/simple_animal/hostile/megafauna/dragon/proc/swoop_attack(fire_rain = 0, atom/movable/manual_target)
-	if(stat || swooping)
-		return
-	swoop_cooldown = world.time + 200
-	var/atom/swoop_target
-	if(manual_target)
-		swoop_target = manual_target
-	else
-		swoop_target = target
-	stop_automated_movement = TRUE
-	swooping = 1
-	density = 0
-	icon_state = "swoop"
-	visible_message("<span class='boldwarning'>[src] swoops up high!</span>")
-	if(prob(50))
-		animate(src, pixel_x = 500, pixel_z = 500, time = 10)
-	else
-		animate(src, pixel_x = -500, pixel_z = 500, time = 10)
-	sleep(30)
-
-	var/turf/tturf
-	if(fire_rain)
-		fire_rain()
-
-	icon_state = "dragon"
-	if(swoop_target && !QDELETED(swoop_target) && swoop_target.z == src.z)
-		tturf = get_turf(swoop_target)
-	else
-		tturf = get_turf(src)
-	forceMove(tturf)
-	new /obj/effect/temp_visual/dragon_swoop(tturf)
-	animate(src, pixel_x = initial(pixel_x), pixel_z = 0, time = 10)
-	sleep(10)
-	playsound(src.loc, 'sound/effects/meteorimpact.ogg', 200, 1)
-	for(var/mob/living/L in orange(1, src))
-		if(L.stat)
-			visible_message("<span class='warning'>[src] slams down on [L], crushing [L.p_them()]!</span>")
-			L.gib()
+			flame_hit[L] = TRUE
 		else
-			L.adjustBruteLoss(75)
-			if(L && !QDELETED(L)) // Some mobs are deleted on death
-				var/throw_dir = get_dir(src, L)
-				if(L.loc == loc)
-					throw_dir = pick(alldirs)
-				var/throwtarget = get_edge_target_turf(src, throw_dir)
-				L.throw_at(throwtarget, 3)
-				visible_message("<span class='warning'>[L] is thrown clear of [src]!</span>")
-
-	for(var/mob/M in range(7, src))
-		shake_camera(M, 15, 1)
-
-	stop_automated_movement = FALSE
-	swooping = 0
-	density = 1
-
-/mob/living/simple_animal/hostile/megafauna/dragon/AltClickOn(atom/movable/A)
-	if(!istype(A))
-		return
-	if(swoop_cooldown >= world.time)
-		to_chat(src, "<span class='warning'>You need to wait 20 seconds between swoop attacks!</span>")
-		return
-	swoop_attack(1, A)
-
-/obj/item/gps/internal/dragon
-	icon_state = null
-	gpstag = "Fiery Signal"
-	desc = "Here there be dragons."
-	invisibility = 100
+			L.adjustFireLoss(10) //if we've already hit them, do way less damage
 
 /mob/living/simple_animal/hostile/megafauna/dragon/lesser
 	name = "lesser ash drake"
@@ -267,9 +581,22 @@ Difficulty: Medium
 	obj_damage = 80
 	melee_damage_upper = 30
 	melee_damage_lower = 30
+	mouse_opacity = MOUSE_OPACITY_ICON
 	damage_coeff = list(BRUTE = 1, BURN = 1, TOX = 1, CLONE = 1, STAMINA = 0, OXY = 1)
 	loot = list()
 	crusher_loot = list()
+	butcher_results = list(/obj/item/stack/ore/diamond = 5, /obj/item/stack/sheet/sinew = 5, /obj/item/stack/sheet/bone = 30)
+	attack_action_types = list()
+
+/mob/living/simple_animal/hostile/megafauna/dragon/lesser/AltClickOn(atom/movable/A)
+	if(!istype(A))
+		return
+	if(player_cooldown >= world.time)
+		to_chat(src, "<span class='warning'>You need to wait [(player_cooldown - world.time) / 10] seconds before swooping again!</span>")
+		return
+	swoop_attack(FALSE, A)
+	lava_pools(10, 2) // less pools but longer delay before spawns
+	player_cooldown = world.time + 200 // needs seperate cooldown or cant use fire attacks
 
 /mob/living/simple_animal/hostile/megafauna/dragon/lesser/grant_achievement(medaltype,scoretype)
 	return

code/modules/mob/living/simple_animal/hostile/megafauna/megafauna.dm

@@ -7,11 +7,11 @@
 	sentience_type = SENTIENCE_BOSS
 	environment_smash = ENVIRONMENT_SMASH_RWALLS
 	obj_damage = 400
-	luminosity = 3
+	light_range = 3
 	faction = list("mining", "boss")
 	weather_immunities = list("lava","ash")
-	flying = 1
-	robust_searching = 1
+	flying = TRUE
+	robust_searching = TRUE
 	ranged_ignores_vision = TRUE
 	stat_attack = DEAD
 	atmos_requirements = list("min_oxy" = 0, "max_oxy" = 0, "min_tox" = 0, "max_tox" = 0, "min_co2" = 0, "max_co2" = 0, "min_n2" = 0, "max_n2" = 0)
@@ -20,6 +20,12 @@
 	maxbodytemp = INFINITY
 	vision_range = 5
 	aggro_vision_range = 18
+	move_force = MOVE_FORCE_OVERPOWERING
+	move_resist = MOVE_FORCE_OVERPOWERING
+	pull_force = MOVE_FORCE_OVERPOWERING
+	mob_size = MOB_SIZE_LARGE
+	layer = LARGE_MOB_LAYER //Looks weird with them slipping under mineral walls and cameras and shit otherwise
+	mouse_opacity = MOUSE_OPACITY_OPAQUE // Easier to click on in melee, they're giant targets anyway
 	var/list/crusher_loot
 	var/medal_type
 	var/score_type = BOSS_SCORE
@@ -27,13 +33,9 @@
 	var/anger_modifier = 0
 	var/obj/item/gps/internal_gps
 	var/internal_type
-	move_force = MOVE_FORCE_OVERPOWERING
-	move_resist = MOVE_FORCE_OVERPOWERING
-	pull_force = MOVE_FORCE_OVERPOWERING
-	mob_size = MOB_SIZE_LARGE
-	layer = LARGE_MOB_LAYER //Looks weird with them slipping under mineral walls and cameras and shit otherwise
-	mouse_opacity = MOUSE_OPACITY_OPAQUE // Easier to click on in melee, they're giant targets anyway
+	var/recovery_time = 0
 	var/true_spawn = TRUE // if this is a megafauna that should grant achievements, or have a gps signal
+	var/nest_range = 10
 	var/chosen_attack = 1 // chosen attack num
 	var/list/attack_action_types = list()
 
@@ -50,6 +52,16 @@
 	QDEL_NULL(internal_gps)
 	return ..()
 
+/mob/living/simple_animal/hostile/megafauna/Moved()
+	if(nest && nest.parent && get_dist(nest.parent, src) > nest_range)
+		var/turf/closest = get_turf(nest.parent)
+		for(var/i = 1 to nest_range)
+			closest = get_step(closest, get_dir(closest, src))
+		forceMove(closest) // someone teleported out probably and the megafauna kept chasing them
+		target = null
+		return
+	return ..()
+
 /mob/living/simple_animal/hostile/megafauna/can_die()
 	return ..() && health <= 0
 
@@ -68,6 +80,8 @@
 	loot = crusher_loot
 
 /mob/living/simple_animal/hostile/megafauna/AttackingTarget()
+	if(recovery_time >= world.time)
+		return
 	. = ..()
 	if(. && isliving(target))
 		var/mob/living/L = target
@@ -90,13 +104,14 @@
 
 /mob/living/simple_animal/hostile/megafauna/proc/devour(mob/living/L)
 	if(!L)
-		return
+		return FALSE
 	visible_message(
 		"<span class='danger'>[src] devours [L]!</span>",
 		"<span class='userdanger'>You feast on [L], restoring your health!</span>")
-	if(!is_station_level(z) && !client) //NPC monsters won't heal while on station
+	if(!is_station_level(z) || client) //NPC monsters won't heal while on station
 		adjustBruteLoss(-L.maxHealth/2)
 	L.gib()
+	return TRUE
 
 /mob/living/simple_animal/hostile/megafauna/ex_act(severity, target)
 	switch(severity)
@@ -109,6 +124,10 @@
 		if(3)
 			adjustBruteLoss(50)
 
+/mob/living/simple_animal/hostile/megafauna/proc/SetRecoveryTime(buffer_time)
+	recovery_time = world.time + buffer_time
+	ranged_cooldown = world.time + buffer_time
+
 /mob/living/simple_animal/hostile/megafauna/proc/grant_achievement(medaltype, scoretype, crusher_kill)
 	if(!medal_type || admin_spawned || !SSmedals.hub_enabled) //Don't award medals if the medal type isn't set
 		return FALSE