Add Z-Level Manager, a basic admin tool. (#30397)

* Add Z-Level Manager, a basic admin tool.

* build bundle, use ui_module/admin

* fix type restriction

* remove unnecessary params

code/modules/admin/admin_verbs.dm

@@ -72,7 +72,8 @@ GLOBAL_LIST_INIT(admin_verbs_admin, list(
 	/client/proc/ping_all_admins,
 	/client/proc/show_watchlist,
 	/client/proc/debugstatpanel,
-	/client/proc/create_rnd_restore_disk
+	/client/proc/create_rnd_restore_disk,
+	/client/proc/open_admin_zlevel_manager,
 ))
 GLOBAL_LIST_INIT(admin_verbs_ban, list(
 	/client/proc/ban_panel,

code/modules/admin/verbs/admin_zlevel_manager_verb.dm

@@ -0,0 +1,15 @@
+/client/proc/open_admin_zlevel_manager()
+	set name = "Z-Level Manager"
+	set desc = "Opens the Z-Level Manager UI"
+	set category = "Admin"
+
+	if(!check_rights(R_ADMIN))
+		return
+
+	if(!SSmapping || !SSmapping.initialized)
+		to_chat(usr, "<span class='notice'>SSmapping has not initialized yet, Z-Level Manager is not available yet.</span>")
+		return
+
+	message_admins("[key_name_admin(usr)] is using the Z-Level Manager")
+	var/datum/ui_module/admin/z_level_manager/ZLM = get_admin_ui_module(/datum/ui_module/admin/z_level_manager)
+	ZLM.ui_interact(usr)

code/modules/space_management/space_level.dm

@@ -200,3 +200,34 @@ GLOBAL_LIST_INIT(cable_typecache, typecacheof(/obj/structure/cable))
 	transition_border_east = (world.maxx - 4)
 	transition_border_south = 3
 	transition_border_west = 3
+
+// space levels have no UI of their own so borrowing this proc for serialization
+// for other UIs
+/datum/space_level/ui_data(mob/user)
+	. = list(
+		"name" = name,
+		"zpos" = zpos,
+		"linkage" = linkage,
+		"transition_tag" = transition_tag,
+		"traits" = flags,
+	)
+
+	.["neighbors"] = list()
+	for(var/direction in list(Z_LEVEL_SOUTH, Z_LEVEL_NORTH, Z_LEVEL_EAST, Z_LEVEL_WEST))
+		var/datum/space_level/neighbor = get_connection(direction)
+		if(neighbor)
+			var/dirname = dir2text(text2num(direction))
+			.["neighbors"][dirname] = neighbor.zpos
+
+	.["ruins"] = list()
+	for(var/obj/effect/landmark/ruin/ruin_landmark in GLOB.ruin_landmarks)
+		if(ruin_landmark.z == zpos)
+			.["ruins"] += list(list(
+				"name" = ruin_landmark.ruin_template.name,
+				"mappath" = ruin_landmark.ruin_template.mappath,
+				"coords" = list(
+					"x" = ruin_landmark.x,
+					"y" = ruin_landmark.y,
+					"z" = ruin_landmark.z,
+				),
+			))

code/modules/tgui/modules/z_level_manager.dm

@@ -0,0 +1,37 @@
+RESTRICT_TYPE(/datum/ui_module/admin/z_level_manager)
+
+/datum/ui_module/admin/z_level_manager
+	name = "Z-Level Manager"
+
+/datum/ui_module/admin/z_level_manager/ui_state(mob/user)
+	return GLOB.admin_state
+
+/datum/ui_module/admin/z_level_manager/ui_interact(mob/user, datum/tgui/ui)
+	ui = SStgui.try_update_ui(user, src, ui)
+	if(!ui)
+		ui = new(user, src, "ZLevelManager", name)
+		ui.set_autoupdate(FALSE)
+		ui.open()
+
+/datum/ui_module/admin/z_level_manager/ui_data(mob/user)
+	. = list()
+
+	.["levels"] = list()
+
+	for(var/zlvl in GLOB.space_manager.z_list)
+		var/datum/space_level/level = GLOB.space_manager.z_list[zlvl]
+		.["levels"]["[level.zpos]"] = level.ui_data()
+
+/datum/ui_module/admin/z_level_manager/ui_act(action, list/params, datum/tgui/ui, datum/ui_state/state)
+	if(..())
+		return
+
+	switch(action)
+		if("jump_to_coords")
+			var/x = params["x"]
+			var/y = params["y"]
+			var/z = params["z"]
+
+			usr.client.jumptocoord(x, y, z)
+
+	return TRUE