Allows nuke core containers to be broken open (#16570)

* Allows nuke core containers to be broken open

* Apply suggestions from code review

Co-authored-by: Farie82 <farie82@users.noreply.github.com>

* Improves unload, removes duplicate, better logging, changes name on cracking open

* Update code/game/objects/items/theft_items.dm

Co-authored-by: dearmochi <1496804+dearmochi@users.noreply.github.com>

* Some of sabres stuff

Co-authored-by: SabreML <57483089+SabreML@users.noreply.github.com>

* Fixes engineers / atmos techs getting objective, boldnotice

* Testing to figure out why this is conflicted

Co-authored-by: Farie82 <farie82@users.noreply.github.com>
Co-authored-by: dearmochi <1496804+dearmochi@users.noreply.github.com>
Co-authored-by: SabreML <57483089+SabreML@users.noreply.github.com>

code/game/gamemodes/steal_items.dm

@@ -145,8 +145,8 @@
 /datum/theft_objective/supermatter_sliver
 	name = "a supermatter sliver"
 	typepath = /obj/item/nuke_core/supermatter_sliver
-	protected_jobs = list("Chief Engineer", "Engineer", "Atmospheric Technician") //Unlike other steal objectives, all jobs in the department have easy access, and would not be noticed at all stealing this
-	location_override = "Engineering. You can use the box and instructions provided to harvest the sliver"
+	protected_jobs = list("Chief Engineer", "Station Engineer", "Life Support Specialist") //Unlike other steal objectives, all jobs in the department have easy access, and would not be noticed at all stealing this
+	location_override = "Engineering. You can use the box and instructions provided to harvest the sliver."
 	special_equipment = /obj/item/storage/box/syndie_kit/supermatter
 	job_possession = FALSE //The CE / engineers / atmos techs do not carry around supermater slivers.
 

code/game/objects/items/theft_items.dm

@@ -12,7 +12,6 @@
 	item_state = "plutoniumcore"
 	resistance_flags = INDESTRUCTIBLE | LAVA_PROOF | FIRE_PROOF | ACID_PROOF
 	flags_2 = RAD_NO_CONTAMINATE_2 //Don't have the item itself become irradiated when it makes radiation.
-	var/pulse = 0
 	var/cooldown = 0
 	var/pulseicon = "plutonium_core_pulse"
 
@@ -49,14 +48,42 @@
 	icon = 'icons/obj/nuke_tools.dmi'
 	icon_state = "core_container_empty"
 	item_state = "metal"
+	resistance_flags = INDESTRUCTIBLE | LAVA_PROOF | FIRE_PROOF | ACID_PROOF //Don't want people trying to break it open with acid, then destroying the core.
 	var/obj/item/nuke_core/plutonium/core
+	var/dented = FALSE
+	var/cracked = FALSE
 
 /obj/item/nuke_core_container/Destroy()
 	QDEL_NULL(core)
 	return ..()
 
+/obj/item/nuke_core_container/ex_act(severity)
+	switch(severity)
+		if(EXPLODE_DEVASTATE)
+			if(!cracked)
+				crack_open()
+		if(EXPLODE_HEAVY)
+			if(!dented)
+				dented = TRUE
+
+/obj/item/nuke_core_container/examine(mob/user)
+	. = ..()
+	if(cracked) // Cracked open.
+		. += "<span class='warning'>It is broken, and can no longer store objects safely.</span>"
+	else if(dented) // Not cracked, but dented.
+		. += "<span class='notice'>[src] looks dented. Perhaps a bigger explosion may break it.</span>"
+	else // Not cracked or dented.
+		. += "Fine print on the box reads \"Cybersun Industries secure container, guaranteed thermite proof, assistant proof, and explosive resistant.\""
+
+/obj/item/nuke_core_container/attack_hand(mob/user)
+	if(cracked && core)
+		unload(user)
+	else
+		return ..()
+
+
 /obj/item/nuke_core_container/proc/load(obj/item/nuke_core/plutonium/new_core, mob/user)
-	if(core || !istype(new_core))
+	if(core || !istype(new_core) || cracked)
 		return
 	new_core.forceMove(src)
 	core = new_core
@@ -64,6 +91,12 @@
 	to_chat(user, "<span class='warning'>Container is sealing...</span>")
 	addtimer(CALLBACK(src, .proc/seal), 10 SECONDS)
 
+/obj/item/nuke_core_container/proc/unload(mob/user)
+	core.add_fingerprint(user)
+	user.put_in_active_hand(core)
+	core = null
+	icon_state = "core_container_cracked_empty"
+
 /obj/item/nuke_core_container/proc/seal()
 	if(!QDELETED(core))
 		STOP_PROCESSING(SSobj, core)
@@ -73,7 +106,7 @@
 			to_chat(loc, "<span class='warning'>[src] is permanently sealed, [core]'s radiation is contained.</span>")
 
 /obj/item/nuke_core_container/attackby(obj/item/nuke_core/plutonium/core, mob/user)
-	if(!istype(core))
+	if(!istype(core) || cracked)
 		return ..()
 
 	if(!user.drop_item())
@@ -82,9 +115,20 @@
 	else
 		load(core, user)
 
+/obj/item/nuke_core_container/proc/crack_open()
+	visible_message("<span class='boldnotice'>[src] bursts open!</span>")
+	if(core)
+		START_PROCESSING(SSobj, core)
+		icon_state = "core_container_cracked_loaded"
+	else
+		icon_state = "core_container_cracked_empty"
+	name = "broken nuke core container"
+	cracked = TRUE
+
 /obj/item/paper/guides/antag/nuke_instructions
 	info = "How to break into a Nanotrasen nuclear device and remove its plutonium core:<br>\
 	<ul>\
+	<li>Acquire some clothing that protects you from radiation, due to the radioactivity of the core.</li>\
 	<li>Use a screwdriver with a very thin tip (provided) to unscrew the terminal's front panel.</li>\
 	<li>Dislodge and remove the front panel with a crowbar.</li>\
 	<li>Cut the inner metal plate with a welding tool.</li>\
@@ -99,7 +143,7 @@
 /obj/item/paper/guides/antag/supermatter_sliver
 	info = "How to safely extract a supermatter sliver:<br>\
 	<ul>\
-	<li>Approach an active supermatter crystal with radiation shielded personal protective equipment. DO NOT MAKE PHYSICAL CONTACT.</li>\
+	<li>Approach an active supermatter crystal with radiation shielded personal protective equipment, and active magboots. DO NOT MAKE PHYSICAL CONTACT.</li>\
 	<li>Use a supermatter scalpel (provided) to slice off a sliver of the crystal.</li>\
 	<li>Use supermatter extraction tongs (also provided) to safely pick up the sliver you sliced off.</li>\
 	<li>Physical contact of any object with the sliver will dust the object, as well as yourself.</li>\
@@ -183,7 +227,7 @@
 	return ..()
 
 /obj/item/nuke_core_container/supermatter/load(obj/item/retractor/supermatter/I, mob/user)
-	if(!istype(I) || !I.sliver)
+	if(!istype(I) || !I.sliver || sliver)
 		return
 	I.sliver.forceMove(src)
 	sliver = I.sliver
@@ -202,13 +246,56 @@
 		if(ismob(loc))
 			to_chat(loc, "<span class='warning'>[src] is permanently sealed, [sliver] is safely contained.</span>")
 
+/obj/item/nuke_core_container/supermatter/unload(obj/item/retractor/supermatter/I, mob/user)
+	if(!istype(I) || I.sliver)
+		return
+	sliver.forceMove(I)
+	I.sliver = sliver
+	sliver = null
+	I.icon_state = "supermatter_tongs_loaded"
+	I.item_state = "supermatter_tongs_loaded"
+	icon_state = "core_container_cracked_empty"
+	to_chat(user, "<span class='notice'>You carefully pick up [I.sliver] with [I].</span>")
+
 /obj/item/nuke_core_container/supermatter/attackby(obj/item/retractor/supermatter/tongs, mob/user)
 	if(istype(tongs))
-		//try to load shard into core
-		load(tongs, user)
+		if(cracked)
+			//lets take that shard out
+			unload(tongs, user)
+		else
+			//try to load shard into core
+			load(tongs, user)
 	else
 		return ..()
 
+/obj/item/nuke_core_container/supermatter/attack_hand(mob/user)
+	if(cracked && sliver) //What did we say about touching the shard...
+		if(!isliving(user) || user.status_flags & GODMODE)
+			return FALSE
+		user.visible_message("<span class='danger'>[user] reaches out and tries to pick up [sliver]. [user.p_their()] body starts to glow and bursts into flames before flashing into dust!</span>",
+				"<span class='userdanger'>You reach for [sliver] with your hands. That was dumb.</span>",
+				"<span class='italics'>Everything suddenly goes silent.</span>")
+		radiation_pulse(user, 500, 2)
+		playsound(src, 'sound/effects/supermatter.ogg', 50, TRUE)
+		message_admins("[sliver] has consumed [key_name_admin(user)] [ADMIN_JMP(src)].")
+		investigate_log("has consumed [key_name(user)].", "supermatter")
+		user.dust()
+		icon_state = "core_container_cracked_empty"
+		qdel(sliver)
+
+	else
+		return ..()
+
+/obj/item/nuke_core_container/supermatter/crack_open()
+	visible_message("<span class='boldnotice'>[src] bursts open!</span>")
+	if(sliver)
+		START_PROCESSING(SSobj, sliver)
+		icon_state = "supermatter_container_cracked_loaded"
+	else
+		icon_state = "core_container_cracked_empty"
+	name = "broken supermatter bin"
+	cracked = TRUE
+
 /obj/item/scalpel/supermatter
 	name = "supermatter scalpel"
 	desc = "A scalpel with a fragile tip of condensed hyper-noblium gas, searingly cold to the touch, that can safely shave a sliver off a supermatter crystal."
@@ -267,6 +354,8 @@
 		investigate_log("has irradiated [key_name(victim)].", "supermatter")
 	else if(istype(AM, /obj/singularity))
 		return
+	else if(istype(AM, /obj/item/nuke_core_container))
+		return
 	else
 		investigate_log("has consumed [AM].", "supermatter")
 		qdel(AM)