Adds progress bars to tasks that take time

code/__defines/appearance.dm

@@ -0,0 +1,3 @@
+// Consider these images/atoms as part of the UI/HUD
+#define APPEARANCE_UI_IGNORE_ALPHA			RESET_COLOR|RESET_TRANSFORM|NO_CLIENT_COLOR|RESET_ALPHA
+#define APPEARANCE_UI						RESET_COLOR|RESET_TRANSFORM|NO_CLIENT_COLOR

code/_helpers/mobs.dm

@@ -30,13 +30,10 @@ proc/random_hair_style(gender, species = "Human")
 	var/list/valid_hairstyles = list()
 	for(var/hairstyle in hair_styles_list)
 		var/datum/sprite_accessory/S = hair_styles_list[hairstyle]
-
-		if(gender != NEUTER && gender != PLURAL)
-			if(gender == MALE && S.gender == FEMALE)
-				continue
-			if(gender == FEMALE && S.gender == MALE)
-				continue
-
+		if(gender == MALE && S.gender == FEMALE)
+			continue
+		if(gender == FEMALE && S.gender == MALE)
+			continue
 		if( !(species in S.species_allowed))
 			continue
 		valid_hairstyles[hairstyle] = hair_styles_list[hairstyle]
@@ -52,13 +49,10 @@ proc/random_facial_hair_style(gender, species = "Human")
 	var/list/valid_facialhairstyles = list()
 	for(var/facialhairstyle in facial_hair_styles_list)
 		var/datum/sprite_accessory/S = facial_hair_styles_list[facialhairstyle]
-
-		if(gender != NEUTER && gender != PLURAL)
-			if(gender == MALE && S.gender == FEMALE)
-				continue
-			if(gender == FEMALE && S.gender == MALE)
-				continue
-
+		if(gender == MALE && S.gender == FEMALE)
+			continue
+		if(gender == FEMALE && S.gender == MALE)
+			continue
 		if( !(species in S.species_allowed))
 			continue
 
@@ -171,3 +165,93 @@ Proc for attack log creation, because really why not
 		return 0
 	var/mob/living/silicon/robot/R = thing.loc
 	return (thing in R.module.modules)
+
+/proc/get_exposed_defense_zone(var/atom/movable/target)
+	var/obj/item/weapon/grab/G = locate() in target
+	if(G && G.state >= GRAB_NECK) //works because mobs are currently not allowed to upgrade to NECK if they are grabbing two people.
+		return pick("head", "l_hand", "r_hand", "l_foot", "r_foot", "l_arm", "r_arm", "l_leg", "r_leg")
+	else
+		return pick("chest", "groin")
+
+/proc/do_mob(mob/user , mob/target, time = 30, uninterruptible = 0, progress = 1)
+	if(!user || !target)
+		return 0
+	var/user_loc = user.loc
+	var/target_loc = target.loc
+
+	var/holding = user.get_active_hand()
+	var/datum/progressbar/progbar
+	if (progress)
+		progbar = new(user, time, target)
+
+	var/endtime = world.time+time
+	var/starttime = world.time
+	. = 1
+	while (world.time < endtime)
+		sleep(1)
+		if (progress)
+			progbar.update(world.time - starttime)
+		if(!user || !target)
+			. = 0
+			break
+		if(uninterruptible)
+			continue
+
+		if(!user || user.incapacitated() || user.loc != user_loc)
+			. = 0
+			break
+
+		if(target.loc != target_loc || user.get_active_hand() != holding)
+			. = 0
+			break
+	if (progbar)
+		qdel(progbar)
+
+/proc/do_after(mob/user, delay, atom/target = null, needhand = 1, progress = 1)
+	if(!user)
+		return 0
+	var/atom/target_loc = null
+	if(target)
+		target_loc = target.loc
+
+	var/atom/original_loc = user.loc
+
+	var/holding = user.get_active_hand()
+
+	var/holdingnull = 1 //User's hand started out empty, check for an empty hand
+	if(holding)
+		holdingnull = 0 //Users hand started holding something, check to see if it's still holding that
+
+	var/datum/progressbar/progbar
+	if (progress)
+		progbar = new(user, delay, target)
+
+	var/endtime = world.time + delay
+	var/starttime = world.time
+	. = 1
+	while (world.time < endtime)
+		sleep(1)
+		if (progress)
+			progbar.update(world.time - starttime)
+
+		if(!user || user.incapacitated() || user.loc != original_loc)
+			. = 0
+			break
+
+		if(target_loc && (!target || target_loc != target.loc))
+			. = 0
+			break
+
+		if(needhand)
+			//This might seem like an odd check, but you can still need a hand even when it's empty
+			//i.e the hand is used to pull some item/tool out of the construction
+			if(!holdingnull)
+				if(!holding)
+					. = 0
+					break
+			if(user.get_active_hand() != holding)
+				. = 0
+				break
+
+	if (progbar)
+		qdel(progbar)

code/_helpers/unsorted.dm

@@ -646,47 +646,6 @@ proc/GaussRandRound(var/sigma,var/roundto)
 
 	else return get_step(ref, base_dir)
 
-/proc/do_mob(var/mob/user, var/mob/target, var/delay = 30, var/numticks = 5, var/needhand = 1) //This is quite an ugly solution but i refuse to use the old request system.
-	if(!user || !target)	return 0
-	if(numticks == 0)		return 0
-
-	var/delayfraction = round(delay/numticks)
-	var/original_user_loc = user.loc
-	var/original_target_loc = target.loc
-	var/holding = user.get_active_hand()
-
-	for(var/i = 0, i<numticks, i++)
-		sleep(delayfraction)
-
-		if(!user || user.stat || user.weakened || user.stunned || user.loc != original_user_loc)
-			return 0
-		if(!target || target.loc != original_target_loc)
-			return 0
-		if(needhand && !(user.get_active_hand() == holding))	//Sometimes you don't want the user to have to keep their active hand
-			return 0
-
-	return 1
-
-/proc/do_after(var/mob/user as mob, delay as num, var/numticks = 5, var/needhand = 1)
-	if(!user || isnull(user))
-		return 0
-	if(numticks == 0)
-		return 0
-
-	var/delayfraction = round(delay/numticks)
-	var/original_loc = user.loc
-	var/holding = user.get_active_hand()
-
-	for(var/i = 0, i<numticks, i++)
-		sleep(delayfraction)
-
-		if(!user || user.stat || user.weakened || user.stunned || user.loc != original_loc)
-			return 0
-		if(needhand && !(user.get_active_hand() == holding))	//Sometimes you don't want the user to have to keep their active hand
-			return 0
-
-	return 1
-
 //Takes: Anything that could possibly have variables and a varname to check.
 //Returns: 1 if found, 0 if not.
 /proc/hasvar(var/datum/A, var/varname)

code/datums/progressbar.dm

@@ -0,0 +1,43 @@
+/datum/progressbar
+	var/goal = 1
+	var/image/bar
+	var/shown = 0
+	var/mob/user
+	var/client/client
+
+/datum/progressbar/New(mob/user, goal_number, atom/target)
+	. = ..()
+	if(!target) target = user
+	if (!istype(target))
+		EXCEPTION("Invalid target given")
+	if (goal_number)
+		goal = goal_number
+	bar = image('icons/effects/progessbar.dmi', target, "prog_bar_0")
+	bar.appearance_flags = APPEARANCE_UI_IGNORE_ALPHA
+	bar.pixel_y = 32
+	src.user = user
+	if(user)
+		client = user.client
+
+/datum/progressbar/Destroy()
+	if (client)
+		client.images -= bar
+	qdel(bar)
+	. = ..()
+
+/datum/progressbar/proc/update(progress)
+	//world << "Update [progress] - [goal] - [(progress / goal)] - [((progress / goal) * 100)] - [round(((progress / goal) * 100), 5)]"
+	if (!user || !user.client)
+		shown = 0
+		return
+	if (user.client != client)
+		if (client)
+			client.images -= bar
+		if (user.client)
+			user.client.images += bar
+
+	progress = Clamp(progress, 0, goal)
+	bar.icon_state = "prog_bar_[round(((progress / goal) * 100), 5)]"
+	if (!shown)
+		user.client.images += bar
+		shown = 1

polaris.dme

@@ -18,6 +18,7 @@
 #include "code\world.dm"
 #include "code\__defines\_compile_options.dm"
 #include "code\__defines\admin.dm"
+#include "code\__defines\appearance.dm"
 #include "code\__defines\atmos.dm"
 #include "code\__defines\chemistry.dm"
 #include "code\__defines\damage_organs.dm"
@@ -161,6 +162,7 @@
 #include "code\datums\mixed.dm"
 #include "code\datums\modules.dm"
 #include "code\datums\organs.dm"
+#include "code\datums\progressbar.dm"
 #include "code\datums\recipe.dm"
 #include "code\datums\sun.dm"
 #include "code\datums\supplypacks.dm"