vgstation drink sliding

code/__DEFINES/maths.dm

@@ -199,4 +199,6 @@
 #define LORENTZ_CUMULATIVE_DISTRIBUTION(x, y, s) ( (1/PI)*TORADIANS(arctan((x-y)/s)) + 1/2 )
 
 #define RULE_OF_THREE(a, b, x) ((a*x)/b)
-// )
+// )
+
+#define MANHATTAN_DISTANCE(a, b) (abs(a.x - b.x) + abs(a.y - b.y))

code/__HELPERS/vector.dm

@@ -0,0 +1,57 @@
+// Basic geometry things.
+
+/vector/
+	var/x = 0
+	var/y = 0
+
+/vector/New(var/x, var/y)
+	src.x = x
+	src.y = y
+
+/vector/proc/duplicate()
+	return new /vector(x, y)
+
+/vector/proc/euclidian_norm()
+	return sqrt(x*x + y*y)
+
+/vector/proc/squared_norm()
+	return x*x + y*y
+
+/vector/proc/normalize()
+	var/norm = euclidian_norm()
+	x = x/norm
+	y = y/norm
+	return src
+
+/vector/proc/chebyshev_norm()
+	return max(abs(x), abs(y))
+
+/vector/proc/chebyshev_normalize()
+	var/norm = chebyshev_norm()
+	x = x/norm
+	y = y/norm
+	return src
+
+/vector/proc/is_integer()
+	return ISINTEGER(x) && ISINTEGER(y)
+
+/atom/movable/proc/vector_translate(var/vector/V, var/delay)
+	var/turf/T = get_turf(src)
+	var/turf/destination = locate(T.x + V.x, T.y + V.y, z)
+	var/vector/V_norm = V.duplicate()
+	V_norm.chebyshev_normalize()
+	if (!V_norm.is_integer())
+		return
+	var/turf/destination_temp
+	while (destination_temp != destination)
+		destination_temp = locate(T.x + V_norm.x, T.y + V_norm.y, z)
+		forceMove(destination_temp)
+		T = get_turf(src)
+		sleep(delay + world.tick_lag) // Shortest possible time to sleep
+
+/atom/proc/get_translated_turf(var/vector/V)
+	var/turf/T = get_turf(src)
+	return locate(T.x + V.x, T.y + V.y, z)
+
+/proc/atoms2vector(var/atom/A, var/atom/B)
+	return new /vector((B.x - A.x), (B.y - A.y)) // Vector from A -> B

code/datums/action.dm

@@ -756,3 +756,11 @@
 	target.layer = old_layer
 	target.plane = old_plane
 	current_button.appearance_cache = target.appearance
+
+/proc/get_action_of_type(mob/M, var/action_type)
+	if(!M.actions || !ispath(action_type, /datum/action))
+		return
+	for(var/datum/action/A in M.actions)
+		if(istype(A, action_type))
+			return A
+	return

code/modules/food_and_drinks/drinks/drinks.dm

@@ -107,11 +107,9 @@
 		smash(hit_atom, throwingdatum?.thrower, TRUE)
 
 /obj/item/reagent_containers/food/drinks/proc/smash(atom/target, mob/thrower, ranged = FALSE)
-	if(!isGlass)
+	if(!isGlass && !istype(src, /obj/item/reagent_containers/food/drinks/bottle)) //I don't like this but I also don't want to rework drink container hierarchy
 		return
-	if(QDELING(src) || !target)		//Invalid loc
-		return
-	if(bartender_check(target) && ranged)
+	if(QDELING(src) || (ranged && !target))
 		return
 	var/obj/item/broken_bottle/B = new (loc)
 	B.icon_state = icon_state
@@ -126,12 +124,74 @@
 		B.transform = M
 		B.pixel_x = rand(-12, 12)
 		B.pixel_y = rand(-12, 12)
-	if(prob(33))
-		new/obj/item/shard(drop_location())
+	if(isGlass)
+		if(prob(33))
+			new/obj/item/shard(drop_location())
+	else
+		B.force = 0
+		B.throwforce = 0
+		B.desc = "A carton with the bottom half burst open. Might give you a papercut."
 	playsound(src, "shatter", 70, 1)
 	transfer_fingerprints_to(B)
 	qdel(src)
 
+/obj/item/reagent_containers/food/drinks/MouseDrop(atom/over, atom/src_location, atom/over_location, src_control, over_control, params)
+	var/mob/user = usr
+	if (!istype(src_location))
+		return
+	if (!user || user.incapacitated())
+		return
+	// Attempted drink sliding
+	if (locate(/obj/structure/table) in src_location)
+		//Are we an expert slider?
+		var/datum/action/innate/A = get_action_of_type(user, /datum/action/innate/drink_fling)
+		if(A?.active)
+			if (!user.Adjacent(src))
+				return
+			var/distance = MANHATTAN_DISTANCE(over_location, src)
+			if (distance >= 8 || distance == 0) // More than a full screen to go, or trying to slide to the same tile
+				return ..()
+
+			// Geometrically checking if we're on a straight line.
+			var/vector/V = atoms2vector(src, over_location)
+			var/vector/V_norm = V.duplicate()
+			V_norm.normalize()
+			if (!V_norm.is_integer())
+				return ..() // Only a cardinal vector (north, south, east, west) can pass this test
+
+			// Checks if there's tables on the path.
+			var/turf/dest = get_translated_turf(V)
+			var/turf/temp_turf = src_location
+
+			do
+				temp_turf = temp_turf.get_translated_turf(V_norm)
+				if (!locate(/obj/structure/table) in temp_turf)
+					var/vector/V2 = atoms2vector(src, temp_turf)
+					vector_translate(V2, 0.1 SECONDS)
+					user.visible_message("<span class='warning'>\The [user] slides \the [src] down the table... and straight into the ground!</span>", "<span class='warning'>You slide \the [src] down the table, and straight into the ground!</span>")
+					smash(over_location, user, FALSE)
+					return
+			while (temp_turf != dest)
+
+			vector_translate(V, 0.1 SECONDS)
+			user.visible_message("<span class='notice'>\The [user] expertly slides \the [src] down the table.</span>", "<span class='notice'>You slide \the [src] down the table. What a pro.</span>")
+			return
+		else
+			if (!(locate(/obj/structure/table) in over_location))
+				return ..()
+			if (!user.Adjacent(src) || !src_location.Adjacent(over_location)) // Regular users can only do short slides.
+				return ..()
+			if (prob(10))
+				user.visible_message("<span class='warning'>\The [user] tries to slide \the [src] down the table, but fails miserably.</span>", "<span class='warning'>You <b>fail</b> to slide \the [src] down the table!</span>")
+				smash(over_location, user, FALSE)
+				return
+			user.visible_message("<span class='notice'>\The [user] slides \the [src] down the table.</span>", "<span class='notice'>You slide \the [src] down the table!</span>")
+			forceMove(over_location)
+			return
+	return ..()
+
+
+
 ////////////////////////////////////////////////////////////////////////////////
 /// Drinks. END
 ////////////////////////////////////////////////////////////////////////////////
@@ -290,8 +350,6 @@
 	volume = 15 //I figure if you have to craft these it should at least be slightly better than something you can get for free from a watercooler
 
 /obj/item/reagent_containers/food/drinks/sillycup/smallcarton/smash(atom/target, mob/thrower, ranged = FALSE)
-	if(bartender_check(target) && ranged)
-		return
 	var/obj/item/broken_bottle/B = new (loc)
 	B.icon_state = icon_state
 	var/icon/I = new('icons/obj/drinks.dmi', src.icon_state)

code/modules/food_and_drinks/drinks/drinks/bottle.dm

@@ -16,40 +16,6 @@
 	isGlass = TRUE
 	foodtype = ALCOHOL
 
-
-/obj/item/reagent_containers/food/drinks/bottle/smash(mob/living/target, mob/thrower, ranged = FALSE)
-	//Creates a shattering noise and replaces the bottle with a broken_bottle
-	if(bartender_check(target) && ranged)
-		return
-	var/obj/item/broken_bottle/B = new (loc)
-	if(!ranged)
-		thrower.put_in_hands(B)
-	else
-		var/matrix/M = matrix(B.transform)
-		M.Turn(rand(-170, 170))
-		B.transform = M
-		B.pixel_x = rand(-12, 12)
-		B.pixel_y = rand(-12, 12)
-	B.icon_state = icon_state
-
-	var/icon/I = new('icons/obj/drinks.dmi', src.icon_state)
-	I.Blend(B.broken_outline, ICON_OVERLAY, rand(5), 1)
-	I.SwapColor(rgb(255, 0, 220, 255), rgb(0, 0, 0, 0))
-	B.icon = I
-
-	if(isGlass)
-		if(prob(33))
-			new/obj/item/shard(drop_location())
-		playsound(src, "shatter", 70, 1)
-	else
-		B.force = 0
-		B.throwforce = 0
-		B.desc = "A carton with the bottom half burst open. Might give you a papercut."
-	B.name = "broken [name]"
-	transfer_fingerprints_to(B)
-
-	qdel(src)
-
 /obj/item/reagent_containers/food/drinks/bottle/attack(mob/living/target, mob/living/user)
 
 	if(!target)
@@ -109,7 +75,7 @@
 //Keeping this here for now, I'll ask if I should keep it here.
 /obj/item/broken_bottle
 	name = "broken bottle"
-	desc = "A bottle with a sharp broken bottom."
+	desc = "A shattered glass container with sharp edges."
 	icon = 'icons/obj/drinks.dmi'
 	icon_state = "broken_bottle"
 	force = 9

code/modules/jobs/job_types/bartender.dm

@@ -28,3 +28,7 @@
 	backpack_contents = list(/obj/item/storage/box/beanbag=1,/obj/item/book/granter/action/drink_fling=1)
 	shoes = /obj/item/clothing/shoes/laceup
 
+/datum/job/bartender/after_spawn(mob/living/H, mob/M, latejoin = FALSE)
+	. = ..()
+	var/datum/action/innate/drink_fling/D = new
+	D.Grant(H)

code/modules/reagents/reagent_containers.dm

@@ -102,15 +102,6 @@
 	. = ..()
 	SplashReagents(hit_atom, TRUE)
 
-/obj/item/reagent_containers/proc/bartender_check(atom/target)
-	. = FALSE
-	var/turf/T = get_turf(src)
-	if(!T || target.CanPass(src, T) || !thrownby || !thrownby.actions)
-		return
-	for(var/datum/action/innate/drink_fling/D in thrownby.actions)
-		if(D.active)
-			return TRUE
-
 /obj/item/reagent_containers/proc/ForceResetRotation()
 	transform = initial(transform)
 
@@ -132,12 +123,6 @@
 			log_combat(thrownby, M, "splashed", R)
 		reagents.reaction(target, TOUCH)
 
-	else if(bartender_check(target) && thrown)
-		visible_message("<span class='notice'>[src] lands onto the [target.name] without spilling a single drop.</span>")
-		transform = initial(transform)
-		addtimer(CALLBACK(src, .proc/ForceResetRotation), 1)
-		return
-
 	else
 		if(isturf(target) && reagents.reagent_list.len && thrownby)
 			log_combat(thrownby, target, "splashed (thrown) [english_list(reagents.reagent_list)]", "in [AREACOORD(target)]")

tgstation.dme

@@ -152,6 +152,7 @@
 #include "code\__HELPERS\type2type_vr.dm"
 #include "code\__HELPERS\typelists.dm"
 #include "code\__HELPERS\unsorted.dm"
+#include "code\__HELPERS\vector.dm"
 #include "code\__HELPERS\view.dm"
 #include "code\__HELPERS\sorts\__main.dm"
 #include "code\__HELPERS\sorts\InsertSort.dm"