commit

code/datums/holocall.dm

@@ -0,0 +1,159 @@
+#define HOLOPAD_MAX_DIAL_TIME 200
+
+/mob/camera/aiEye/remote/holo/setLoc()
+	. = ..()
+	var/obj/machinery/holopad/H = origin
+	H.move_hologram(eye_user, loc)
+
+//this datum manages it's own references
+
+/datum/holocall
+	var/mob/living/user	//the one that called
+	var/obj/machinery/holopad/calling_holopad	//the one that sent the call
+	var/obj/machinery/holopad/connected_holopad	//the one that answered the call (may be null)
+	var/list/dialed_holopads	//all things called, will be cleared out to just connected_holopad once answered
+
+	var/mob/camera/aiEye/remote/holo/eye	//user's eye, once connected
+	var/obj/effect/overlay/holo_pad_hologram/hologram	//user's hologram, once connected
+
+	var/call_start_time
+
+//creates a holocall made by `caller` from `calling_pad` to `callees`
+/datum/holocall/New(mob/living/caller, obj/machinery/holopad/calling_pad, list/callees)
+	call_start_time = world.time
+	user = caller
+	calling_pad.outgoing_call = src
+	calling_holopad = calling_pad
+	dialed_holopads = list()
+
+	for(var/I in callees)
+		var/obj/machinery/holopad/H = I
+		if(!QDELETED(H) && H.is_operational())
+			dialed_holopads += H
+			LAZYADD(H.holo_calls, src)
+
+	if(!dialed_holopads.len)
+		calling_pad.say("Connection failure.")
+		qdel(src)
+		return
+	
+	testing("Holocall started")
+
+//cleans up ALL references :)
+/datum/holocall/Destroy()
+	QDEL_NULL(eye)
+
+	user.reset_perspective()
+	
+	user = null
+	hologram.HC = null
+	hologram = null
+	calling_holopad.outgoing_call = null
+
+	for(var/I in dialed_holopads)
+		var/obj/machinery/holopad/H = I
+		LAZYREMOVE(H.holo_calls, src)
+	dialed_holopads.Cut()
+
+	if(calling_holopad)
+		calling_holopad.SetLightsAndPower()
+		calling_holopad = null
+	if(connected_holopad)
+		connected_holopad.SetLightsAndPower()
+		connected_holopad = null
+	
+	testing("Holocall destroyed")
+
+	return ..()
+
+//Gracefully disconnects a holopad `H` from a call. Pads not in the call are ignored. Notifies participants of the disconnection
+/datum/holocall/proc/Disconnect(obj/machinery/holopad/H)
+	testing("Holocall disconnect")
+	if(H == connected_holopad)
+		calling_holopad.say("[usr] disconnected.")
+	else if(H == calling_holopad && connected_holopad)
+		connected_holopad.say("[usr] disconnected.")
+
+	ConnectionFailure(H, TRUE)
+
+//Forcefully disconnects a holopad `H` from a call. Pads not in the call are ignored.
+/datum/holocall/proc/ConnectionFailure(obj/machinery/holopad/H, graceful = FALSE)
+	testing("Holocall connection failure: graceful [graceful]")
+	if(H == connected_holopad || H == calling_holopad)
+		if(!graceful)
+			calling_holopad.say("Connection failure.")
+		qdel(src)
+		return
+
+	LAZYREMOVE(H.holo_calls, src)
+	dialed_holopads -= H
+	if(!dialed_holopads.len)
+		if(graceful)
+			calling_holopad.say("Call rejected.")
+		testing("No recipients, terminating")
+		qdel(src)
+
+//Answers a call made to a holopad `H` which cannot be the calling holopad. Pads not in the call are ignored
+/datum/holocall/proc/Answer(obj/machinery/holopad/H)
+	testing("Holocall answer")
+	if(H == calling_holopad)
+		CRASH("How cute, a holopad tried to answer itself.")
+
+	if(!(H in dialed_holopads))
+		return
+
+	if(connected_holopad)
+		CRASH("Multi-connection holocall")
+
+	for(var/I in dialed_holopads)
+		if(I == H)
+			continue
+		Disconnect(I)
+	
+	for(var/I in H.holo_calls)
+		var/datum/holocall/HC = I
+		if(HC != src)
+			HC.Disconnect(H)
+
+	connected_holopad = H
+
+	if(!Check())
+		return
+
+	hologram = H.activate_holo(user)
+	hologram.HC = src
+
+	//eyeobj code is horrid, this is the best copypasta I could make
+	eye = new
+	eye.origin = H
+	eye.eye_initialized = TRUE
+	eye.eye_user = user
+	eye.name = "Camera Eye ([user.name])"
+	user.remote_control = eye
+	user.reset_perspective(eye)
+	eye.setLoc(H.loc)
+
+//Checks the validity of a holocall and qdels itself if it's not. Returns TRUE if valid, FALSE otherwise
+/datum/holocall/proc/Check()
+	for(var/I in dialed_holopads)
+		var/obj/machinery/holopad/H = I
+		if(!H.is_operational())
+			ConnectionFailure(H)
+	
+	if(QDELETED(src))
+		return FALSE
+
+	. = !QDELETED(user) && !user.incapacitated() && !QDELETED(calling_holopad) && calling_holopad.is_operational() && user.loc == calling_holopad.loc
+
+	if(.)
+		if(connected_holopad)
+			. = !QDELETED(connected_holopad) && connected_holopad.is_operational()
+		else
+			. = world.time < (call_start_time + HOLOPAD_MAX_DIAL_TIME)
+			if(!.)
+				calling_holopad.say("No answer recieved.")
+				calling_holopad.temp = ""
+
+	if(!.)
+		testing("Holocall Check fail")
+		qdel(src)

code/modules/language/draconic.dm

@@ -0,0 +1,20 @@
+/datum/language/draconic
+	name = "Draconic"
+	desc = "The common language of lizard-people, composed of sibilant hisses and rattles."
+	speech_verb = "hisses"
+	ask_verb = "hisses"
+	exclaim_verb = "roars"
+	key = "o"
+	flags = TONGUELESS_SPEECH
+	space_chance = 40
+	syllables = list(
+		"za", "az", "ze", "ez", "zi", "iz", "zo", "oz", "zu", "uz", "zs", "sz",
+		"ha", "ah", "he", "eh", "hi", "ih", "ho", "oh", "hu", "uh", "hs", "sh",
+		"la", "al", "le", "el", "li", "il", "lo", "ol", "lu", "ul", "ls", "sl",
+		"ka", "ak", "ke", "ek", "ki", "ik", "ko", "ok", "ku", "uk", "ks", "sk",
+		"sa", "as", "se", "es", "si", "is", "so", "os", "su", "us", "ss", "ss",
+		"ra", "ar", "re", "er", "ri", "ir", "ro", "or", "ru", "ur", "rs", "sr",
+		"a",  "a",  "e",  "e",  "i",  "i",  "o",  "o",  "u",  "u",  "s",  "s"
+	)
+	icon_state = "lizard"
+	default_priority = 90

tgstation.dme

@@ -1421,6 +1421,7 @@
 #include "code\modules\jobs\job_types\security.dm"
 #include "code\modules\jobs\job_types\silicon.dm"
 #include "code\modules\language\common.dm"
+#include "code\modules\language\draconic.dm"
 #include "code\modules\language\drone.dm"
 #include "code\modules\language\language.dm"
 #include "code\modules\language\language_holder.dm"