[READY]Parallax (#22315)

* Ports Space Parallax from vg/yogs

* KILL ME

* fuck shit

* fixes

* rgfkbjhkefrhjkfrejhkfds

* Parallax, part 2.

* Gotta get these defines in before remie notices!

* DAMN IT! SHE FOUND ONE!

* fixes orbits

* fix orbits take 2

* Fixes some things with parallax

* Refactors parallax shuttle animations.

code/__DEFINES/layers.dm

@@ -3,6 +3,9 @@
 
 #define CLICKCATCHER_PLANE -99
 
+#define PLANE_SPACE -95
+#define PLANE_SPACE_PARALLAX -90
+
 #define GAME_PLANE 0
 //#define TURF_LAYER 2 //For easy recordkeeping; this is a byond define
 #define MID_TURF_LAYER 2.02

code/__DEFINES/preferences.dm

@@ -31,3 +31,12 @@
 
 #define TOGGLES_DEFAULT_CHAT (CHAT_OOC|CHAT_DEAD|CHAT_GHOSTEARS|CHAT_GHOSTSIGHT|CHAT_PRAYER|CHAT_RADIO|CHAT_PULLR|CHAT_GHOSTWHISPER|CHAT_GHOSTPDA|CHAT_GHOSTRADIO)
 
+#define PARALLAX_INSANE -1 //for show offs
+#define PARALLAX_HIGH    0 //default.
+#define PARALLAX_MED     1
+#define PARALLAX_LOW     2
+#define PARALLAX_DISABLE 3 //this option must be the highest number
+
+#define PARALLAX_DELAY_DEFAULT world.tick_lag
+#define PARALLAX_DELAY_MED     1
+#define PARALLAX_DELAY_LOW     2

code/__DEFINES/shuttles.dm

@@ -37,3 +37,5 @@
 #define TRANSIT_FULL 3
 
 #define SHUTTLE_TRANSIT_BORDER 8
+
+#define PARALLAX_LOOP_TIME 25

code/__HELPERS/icon_smoothing.dm

@@ -156,7 +156,9 @@
 		var/list/U = list()
 		if(fixed_underlay)
 			if(fixed_underlay["space"])
-				U += image('icons/turf/space.dmi', SPACE_ICON_STATE, layer=TURF_LAYER)
+				var/image/I = image('icons/turf/space.dmi', SPACE_ICON_STATE, layer=TURF_LAYER)
+				I.plane = PLANE_SPACE
+				U += I
 			else
 				U += image(fixed_underlay["icon"], fixed_underlay["icon_state"], layer=TURF_LAYER)
 		else
@@ -167,7 +169,9 @@
 					T = get_step(src, turn(adjacencies, 225))
 
 			if(isspaceturf(T) && !istype(T, /turf/open/space/transit))
-				U += image('icons/turf/space.dmi', SPACE_ICON_STATE, layer=TURF_LAYER)
+				var/image/I = image('icons/turf/space.dmi', SPACE_ICON_STATE, layer=TURF_LAYER)
+				I.plane = PLANE_SPACE
+				U += I
 			else if(T && !T.density && !T.smooth)
 				U += T
 			else if(baseturf && !initial(baseturf.density) && !initial(baseturf.smooth))

code/_onclick/hud/ghost.dm

@@ -77,9 +77,10 @@
 /datum/hud/ghost/show_hud()
 	var/mob/dead/observer/G = mymob
 	mymob.client.screen = list()
-	if(!G.client.prefs.ghost_hud)
-		return
-	mymob.client.screen += static_inventory
+	create_parallax()
+	if(G.client.prefs.ghost_hud)
+		mymob.client.screen += static_inventory
+
 
 /mob/dead/observer/create_mob_hud()
 	if(client && !hud_used)

code/_onclick/hud/hud.dm

@@ -57,12 +57,12 @@
 	mymob = owner
 
 	ui_style_icon = ui_style
-	
+
 	hide_actions_toggle = new
 	hide_actions_toggle.InitialiseIcon(src)
-	
+
 	hand_slots = list()
-	
+
 	for(var/mytype in subtypesof(/obj/screen/plane_master))
 		var/obj/screen/plane_master/instance = new mytype()
 		plane_masters["[instance.plane]"] = instance
@@ -208,6 +208,7 @@
 	mymob.update_action_buttons(1)
 	reorganize_alerts()
 	mymob.reload_fullscreen()
+	create_parallax()
 
 
 /datum/hud/human/show_hud(version = 0,mob/viewmob)

code/_onclick/hud/parallax.dm

@@ -0,0 +1,268 @@
+
+/client
+	var/list/parallax_layers
+	var/list/parallax_layers_cached
+	var/static/list/parallax_static_layers_tail = newlist(/obj/screen/parallax_pmaster, /obj/screen/parallax_space_whitifier)
+	var/atom/movable/movingmob
+	var/turf/previous_turf
+	var/dont_animate_parallax //world.time of when we can state animate()ing parallax again
+	var/last_parallax_shift //world.time of last update
+	var/parallax_throttle = 0 //ds between updates
+	var/parallax_movedir = 0
+	var/parallax_layers_max = 3
+	var/parallax_animate_timer
+
+/datum/hud/proc/create_parallax()
+	var/client/C = mymob.client
+	if (!apply_parallax_pref())
+		return
+
+	if(!length(C.parallax_layers_cached))
+		C.parallax_layers_cached = list()
+		C.parallax_layers_cached += new /obj/screen/parallax_layer/layer_1(null, C.view)
+		C.parallax_layers_cached += new /obj/screen/parallax_layer/layer_2(null, C.view)
+
+	C.parallax_layers = C.parallax_layers_cached.Copy()
+
+	if (length(C.parallax_layers) > C.parallax_layers_max)
+		C.parallax_layers.len = C.parallax_layers_max
+
+	C.screen |= (C.parallax_layers + C.parallax_static_layers_tail)
+
+/datum/hud/proc/remove_parallax()
+	var/client/C = mymob.client
+	C.screen -= (C.parallax_layers_cached + C.parallax_static_layers_tail)
+	C.parallax_layers = null
+
+/datum/hud/proc/apply_parallax_pref()
+	var/client/C = mymob.client
+	switch(C.prefs.parallax)
+		if (PARALLAX_INSANE)
+			C.parallax_throttle = FALSE
+			C.parallax_layers_max = 4
+			return TRUE
+
+		if (PARALLAX_MED)
+			C.parallax_throttle = PARALLAX_DELAY_MED
+			C.parallax_layers_max = 2
+			return TRUE
+
+		if (PARALLAX_LOW)
+			C.parallax_throttle = PARALLAX_DELAY_LOW
+			C.parallax_layers_max = 1
+			return TRUE
+
+		if (PARALLAX_DISABLE)
+			return FALSE
+
+		else
+			C.parallax_throttle = PARALLAX_DELAY_DEFAULT
+			C.parallax_layers_max = 3
+			return TRUE
+
+/datum/hud/proc/update_parallax_pref()
+	remove_parallax()
+	create_parallax()
+
+// This sets which way the current shuttle is moving (returns true if the shuttle has stopped moving so the caller can append their animation)
+/datum/hud/proc/set_parallax_movedir(new_parallax_movedir)
+	. = FALSE
+	var/client/C = mymob.client
+	if(new_parallax_movedir == C.parallax_movedir)
+		return
+	var/animatedir = new_parallax_movedir
+	if(new_parallax_movedir == FALSE)
+		var/animate_time = 0
+		for(var/thing in C.parallax_layers)
+			var/obj/screen/parallax_layer/L = thing
+			L.icon_state = initial(L.icon_state)
+			L.update_o(C.view)
+			var/T = PARALLAX_LOOP_TIME / L.speed
+			if (T > animate_time)
+				animate_time = T
+		C.dont_animate_parallax = world.time + min(animate_time, PARALLAX_LOOP_TIME)
+		animatedir = C.parallax_movedir
+
+	var/matrix/newtransform
+	switch(animatedir)
+		if(NORTH)
+			newtransform = matrix(1, 0, 0, 0, 1, 480)
+		if(SOUTH)
+			newtransform = matrix(1, 0, 0, 0, 1,-480)
+		if(EAST)
+			newtransform = matrix(1, 0, 480, 0, 1, 0)
+		if(WEST)
+			newtransform = matrix(1, 0,-480, 0, 1, 0)
+
+	var/shortesttimer
+	for(var/thing in C.parallax_layers)
+		var/obj/screen/parallax_layer/L = thing
+
+		var/T = PARALLAX_LOOP_TIME / L.speed
+		if (isnull(shortesttimer))
+			shortesttimer = T
+		if (T < shortesttimer)
+			shortesttimer = T
+		L.transform = newtransform
+		animate(L, transform = matrix(), time = T, easing = QUAD_EASING | (new_parallax_movedir ? EASE_IN : EASE_OUT), flags = ANIMATION_END_NOW)
+		if (new_parallax_movedir)
+			L.transform = newtransform
+			animate(transform = matrix(), time = T) //queue up another animate so lag doesn't create a shutter
+
+	C.parallax_movedir = new_parallax_movedir
+	if (C.parallax_animate_timer)
+		deltimer(C.parallax_animate_timer)
+	C.parallax_animate_timer = addtimer(src, .update_parallax_motionblur, min(shortesttimer, PARALLAX_LOOP_TIME), TIMER_NORMAL, C, animatedir, new_parallax_movedir, newtransform)
+
+/datum/hud/proc/update_parallax_motionblur(client/C, animatedir, new_parallax_movedir, matrix/newtransform)
+	C.parallax_animate_timer = FALSE
+	for(var/thing in C.parallax_layers)
+		var/obj/screen/parallax_layer/L = thing
+		if (!new_parallax_movedir)
+			animate(L)
+			continue
+
+		var/newstate = initial(L.icon_state)
+		if (animatedir)
+			if(animatedir == NORTH || animatedir == SOUTH)
+				newstate += "_vertical"
+			else
+				newstate += "_horizontal"
+
+		var/T = PARALLAX_LOOP_TIME / L.speed
+
+		if (newstate in icon_states(L.icon))
+			L.icon_state = newstate
+			L.update_o(C.view)
+
+		L.transform = newtransform
+
+		animate(L, transform = matrix(), time = T, loop = -1, flags = ANIMATION_END_NOW)
+
+/datum/hud/proc/update_parallax()
+	var/client/C = mymob.client
+	var/turf/posobj = get_turf(C.eye)
+	var/area/areaobj = posobj.loc
+
+	// Update the movement direction of the parallax if necessary (for shuttles)
+	set_parallax_movedir(areaobj.parallax_movedir)
+
+	var/force
+	if(!C.previous_turf || (C.previous_turf.z != posobj.z))
+		C.previous_turf = posobj
+		force = TRUE
+
+	if (!force && world.time < C.last_parallax_shift+C.parallax_throttle)
+		return
+
+	//Doing it this way prevents parallax layers from "jumping" when you change Z-Levels.
+	var/offset_x = posobj.x - C.previous_turf.x
+	var/offset_y = posobj.y - C.previous_turf.y
+
+	if(!offset_x && !offset_y && !force)
+		return
+
+	var/last_delay = world.time - C.last_parallax_shift
+	last_delay = min(last_delay, C.parallax_throttle)
+	C.previous_turf = posobj
+	C.last_parallax_shift = world.time
+
+	for(var/thing in C.parallax_layers)
+		var/obj/screen/parallax_layer/L = thing
+		if (L.view_sized != C.view)
+			L.update_o(C.view)
+		var/change_x = offset_x * L.speed
+		L.offset_x -= change_x
+		var/change_y = offset_y * L.speed
+		L.offset_y -= change_y
+		if(L.offset_x > 240)
+			L.offset_x -= 480
+		if(L.offset_x < -240)
+			L.offset_x += 480
+		if(L.offset_y > 240)
+			L.offset_y -= 480
+		if(L.offset_y < -240)
+			L.offset_y += 480
+
+
+		if(!areaobj.parallax_movedir && C.dont_animate_parallax <= world.time && (offset_x || offset_y) && abs(offset_x) <= max(C.parallax_throttle/world.tick_lag+1,1) && abs(offset_y) <= max(C.parallax_throttle/world.tick_lag+1,1) && (round(abs(change_x)) > 1 || round(abs(change_y)) > 1))
+			L.transform = matrix(1, 0, offset_x*L.speed, 0, 1, offset_y*L.speed)
+			animate(L, transform=matrix(), time = last_delay)
+
+		L.screen_loc = "CENTER-7:[round(L.offset_x,1)],CENTER-7:[round(L.offset_y,1)]"
+
+/atom/movable/proc/update_parallax_contents()
+	if(length(client_mobs_in_contents))
+		for(var/thing in client_mobs_in_contents)
+			var/mob/M = thing
+			if(M && M.client && M.hud_used && length(M.client.parallax_layers))
+				M.hud_used.update_parallax()
+
+/obj/screen/parallax_layer
+	icon = 'icons/effects/parallax.dmi'
+	var/speed = 1
+	var/offset_x = 0
+	var/offset_y = 0
+	var/view_sized
+	blend_mode = BLEND_ADD
+	plane = PLANE_SPACE_PARALLAX
+	screen_loc = "CENTER-7,CENTER-7"
+	mouse_opacity = 0
+
+
+/obj/screen/parallax_layer/New(view)
+	..()
+	if (!view)
+		view = world.view
+	update_o(view)
+
+/obj/screen/parallax_layer/proc/update_o(view)
+	if (!view)
+		view = world.view
+	var/list/new_overlays = list()
+	var/count = Ceiling(view/(480/world.icon_size))+1
+	for(var/x in -count to count)
+		for(var/y in -count to count)
+			if(x == 0 && y == 0)
+				continue
+			var/image/I = image(icon, null, icon_state)
+			I.transform = matrix(1, 0, x*480, 0, 1, y*480)
+			new_overlays += I
+
+	overlays = new_overlays
+	view_sized = view
+
+/obj/screen/parallax_layer/layer_1
+	icon_state = "layer1"
+	speed = 0.6
+	layer = 1
+
+/obj/screen/parallax_layer/layer_2
+	icon_state = "layer2"
+	speed = 1
+	layer = 2
+
+/obj/screen/parallax_pmaster
+	appearance_flags = PLANE_MASTER
+	plane = PLANE_SPACE_PARALLAX
+	blend_mode = BLEND_MULTIPLY
+	mouse_opacity = FALSE
+	screen_loc = "CENTER-7,CENTER-7"
+
+/obj/screen/parallax_space_whitifier
+	appearance_flags = PLANE_MASTER
+	plane = PLANE_SPACE
+	color = list(
+		0, 0, 0, 0,
+		0, 0, 0, 0,
+		0, 0, 0, 0,
+		1, 1, 1, 1,
+		0, 0, 0, 0
+		)
+	screen_loc = "CENTER-7,CENTER-7"
+
+
+#undef LOOP_NONE
+#undef LOOP_NORMAL
+#undef LOOP_REVERSE
+#undef LOOP_TIME

code/_onclick/observer.dm

@@ -15,6 +15,7 @@
 	// Otherwise jump
 	else if(A.loc)
 		loc = get_turf(A)
+		update_parallax_contents()
 
 /mob/dead/observer/ClickOn(var/atom/A, var/params)
 	if(client.click_intercept)

code/controllers/subsystem/parallax.dm

@@ -0,0 +1,42 @@
+var/datum/subsystem/parallax/SSparallax
+
+/datum/subsystem/parallax
+	name = "parallax"
+	wait = 2
+	flags = SS_POST_FIRE_TIMING | SS_FIRE_IN_LOBBY | SS_BACKGROUND | SS_NO_INIT
+	priority = 65
+	var/list/currentrun
+
+/datum/subsystem/parallax/New()
+	NEW_SS_GLOBAL(SSparallax)
+	return ..()
+
+/datum/subsystem/parallax/fire(resumed = 0)
+	if (!resumed)
+		src.currentrun = clients.Copy()
+
+	//cache for sanic speed (lists are references anyways)
+	var/list/currentrun = src.currentrun
+
+	while(length(currentrun))
+		var/client/C = currentrun[currentrun.len]
+		currentrun.len--
+		if (!C || !C.eye)
+			if (MC_TICK_CHECK)
+				return
+			continue
+		var/atom/movable/A = C.eye
+		if(!A)
+			return
+		for (A; isloc(A.loc) && !isturf(A.loc); A = A.loc);
+
+		if(A != C.movingmob)
+			if(C.movingmob != null)
+				C.movingmob.client_mobs_in_contents -= C.mob
+				UNSETEMPTY(C.movingmob.client_mobs_in_contents)
+			LAZYINITLIST(A.client_mobs_in_contents)
+			A.client_mobs_in_contents += C.mob
+			C.movingmob = A
+		if (MC_TICK_CHECK)
+			return
+	currentrun = null

code/controllers/subsystem/shuttles.dm

@@ -448,11 +448,15 @@ var/datum/subsystem/shuttle/SSshuttle
 	if(!midpoint)
 		return FALSE
 	//world << "Making transit dock at [COORD(midpoint)]"
+	var/area/shuttle/transit/A = new()
+	A.parallax_movedir = travel_dir
 	var/obj/docking_port/stationary/transit/new_transit_dock = new(midpoint)
 	new_transit_dock.assigned_turfs = proposed_zone
 	new_transit_dock.name = "Transit for [M.id]/[M.name]"
 	new_transit_dock.turf_type = transit_path
 	new_transit_dock.owner = M
+	new_transit_dock.assigned_area = A
+
 
 	// Add 180, because ports point inwards, rather than outwards
 	new_transit_dock.setDir(angle2dir(dock_angle))
@@ -461,6 +465,7 @@ var/datum/subsystem/shuttle/SSshuttle
 		var/turf/T = i
 		T.ChangeTurf(transit_path)
 		T.flags &= ~(UNUSED_TRANSIT_TURF)
+		A.contents += T
 
 	M.assigned_transit = new_transit_dock
 	return TRUE

code/game/area/areas.dm

@@ -48,6 +48,8 @@
 	var/area/master				// master area used for power calcluations
 	var/list/related			// the other areas of the same type as this
 
+	var/parallax_movedir = 0
+
 	var/global/global_uid = 0
 	var/uid
 	var/list/ambientsounds = list('sound/ambience/ambigen1.ogg','sound/ambience/ambigen3.ogg',\

code/game/area/areas/shuttles.dm

@@ -11,6 +11,10 @@
 	valid_territory = 0
 	icon_state = "shuttle"
 
+/area/shuttle/transit
+	name = "Hyperspace"
+	desc = "Weeeeee"
+
 /area/shuttle/arrival
 	name = "Arrival Shuttle"
 

code/game/atoms_movable.dm

@@ -19,6 +19,7 @@
 	var/inertia_move_delay = 5
 	var/pass_flags = 0
 	var/moving_diagonally = 0 //0: not doing a diagonal move. 1 and 2: doing the first/second step of the diagonal move
+	var/list/client_mobs_in_contents // This contains all the client mobs within this container
 	glide_size = 8
 	appearance_flags = TILE_BOUND
 
@@ -83,6 +84,8 @@
 	if (!inertia_moving)
 		inertia_next_move = world.time + inertia_move_delay
 		newtonian_move(Dir)
+	if (length(client_mobs_in_contents))
+		update_parallax_contents()
 	return 1
 
 /atom/movable/Destroy()

code/game/turfs/simulated/floor/fancy_floor.dm

@@ -137,6 +137,7 @@
 	icon_state = "0"
 	floor_tile = /obj/item/stack/tile/fakespace
 	broken_states = list("damaged")
+	plane = PLANE_SPACE
 
 /turf/open/floor/fakespace/New()
 	..()

code/game/turfs/space/space.dm

@@ -13,7 +13,7 @@
 	var/destination_y
 
 	var/global/datum/gas_mixture/space/space_gas = new
-
+	plane = PLANE_SPACE
 
 /turf/open/space/New()
 	icon_state = SPACE_ICON_STATE

code/modules/client/client_procs.dm

@@ -262,6 +262,9 @@ var/next_external_rsc = 0
 		admins -= src
 	directory -= ckey
 	clients -= src
+	if(movingmob != null)
+		movingmob.client_mobs_in_contents -= mob
+		UNSETEMPTY(movingmob.client_mobs_in_contents)
 	return ..()
 
 /client/Destroy()

code/modules/client/preferences.dm

@@ -5,6 +5,7 @@ var/list/preferences_datums = list()
 
 
 /datum/preferences
+	var/client/parent
 	//doohickeys for savefiles
 	var/path
 	var/default_slot = 1				//Holder so it doesn't default to slot 1, rather the last one used
@@ -94,7 +95,10 @@ var/list/preferences_datums = list()
 
 	var/clientfps = 0
 
+	var/parallax = PARALLAX_HIGH
+
 /datum/preferences/New(client/C)
+	parent = C
 	custom_names["ai"] = pick(ai_names)
 	custom_names["cyborg"] = pick(ai_names)
 	custom_names["clown"] = pick(clown_names)
@@ -411,9 +415,23 @@ var/list/preferences_datums = list()
 							p_map = VM.friendlyname
 					else
 						p_map += " (No longer exists)"
-				dat += "<b>Preferred Map:</b> <a href='?_src_=prefs;preference=preferred_map;task=input'>[p_map]</a>"
+				dat += "<b>Preferred Map:</b> <a href='?_src_=prefs;preference=preferred_map;task=input'>[p_map]</a><br>"
 
-			dat += "<b>FPS:</b> <a href='?_src_=prefs;preference=clientfps;task=input'>[clientfps]</a>"
+			dat += "<b>FPS:</b> <a href='?_src_=prefs;preference=clientfps;task=input'>[clientfps]</a><br>"
+
+			dat += "<b>Parallax (Fancy Space):</b> <a href='?_src_=prefs;preference=parallaxdown' oncontextmenu='window.location.href=\"?_src_=prefs;preference=parallaxup\";return false;'>"
+			switch (parallax)
+				if (PARALLAX_LOW)
+					dat += "Low"
+				if (PARALLAX_MED)
+					dat += "Medium"
+				if (PARALLAX_INSANE)
+					dat += "Insane"
+				if (PARALLAX_DISABLE)
+					dat += "Disabled"
+				else
+					dat += "High"
+			dat += "</a><br>"
 
 			dat += "</td><td width='300px' height='300px' valign='top'>"
 
@@ -1168,6 +1186,16 @@ var/list/preferences_datums = list()
 				if("allow_midround_antag")
 					toggles ^= MIDROUND_ANTAG
 
+				if("parallaxup")
+					parallax = Wrap(parallax + 1, PARALLAX_INSANE, PARALLAX_DISABLE + 1)
+					if (parent && parent.mob && parent.mob.hud_used)
+						parent.mob.hud_used.update_parallax_pref()
+
+				if("parallaxdown")
+					parallax = Wrap(parallax - 1, PARALLAX_INSANE, PARALLAX_DISABLE + 1)
+					if (parent && parent.mob && parent.mob.hud_used)
+						parent.mob.hud_used.update_parallax_pref()
+
 				if("save")
 					save_preferences()
 					save_character()

code/modules/client/preferences_savefile.dm

@@ -175,6 +175,7 @@ SAVEFILE UPDATING/VERSIONING - 'Simplified', or rather, more coder-friendly ~Car
 	S["inquisitive_ghost"]	>> inquisitive_ghost
 	S["uses_glasses_colour"]>> uses_glasses_colour
 	S["clientfps"]			>> clientfps
+	S["parallax"]			>> parallax
 
 	//try to fix any outdated data if necessary
 	if(needs_update >= 0)
@@ -191,6 +192,7 @@ SAVEFILE UPDATING/VERSIONING - 'Simplified', or rather, more coder-friendly ~Car
 	default_slot	= sanitize_integer(default_slot, 1, max_save_slots, initial(default_slot))
 	toggles			= sanitize_integer(toggles, 0, 65535, initial(toggles))
 	clientfps		= sanitize_integer(clientfps, 0, 1000, 0)
+	parallax		= sanitize_integer(parallax, PARALLAX_INSANE, PARALLAX_DISABLE, PARALLAX_HIGH)
 	ghost_form		= sanitize_inlist(ghost_form, ghost_forms, initial(ghost_form))
 	ghost_orbit 	= sanitize_inlist(ghost_orbit, ghost_orbits, initial(ghost_orbit))
 	ghost_accs		= sanitize_inlist(ghost_accs, ghost_accs_options, GHOST_ACCS_DEFAULT_OPTION)
@@ -229,6 +231,7 @@ SAVEFILE UPDATING/VERSIONING - 'Simplified', or rather, more coder-friendly ~Car
 	S["inquisitive_ghost"]	<< inquisitive_ghost
 	S["uses_glasses_colour"]<< uses_glasses_colour
 	S["clientfps"]			<< clientfps
+	S["parallax"]			<< parallax
 
 	return 1
 

code/modules/mob/dead/observer/observer.dm

@@ -278,7 +278,7 @@ This is the proc mobs get to turn into a ghost. Forked from ghostize due to comp
 		loc = NewLoc
 		for(var/obj/effect/step_trigger/S in NewLoc)
 			S.Crossed(src)
-
+		update_parallax_contents()
 		return
 	loc = get_turf(src) //Get out of closets and such as a ghost
 	if((direct & NORTH) && y < world.maxy)
@@ -368,6 +368,7 @@ This is the proc mobs get to turn into a ghost. Forked from ghostize due to comp
 		usr << "No area available."
 
 	usr.loc = pick(L)
+	update_parallax_contents()
 
 /mob/dead/observer/verb/follow()
 	set category = "Ghost"
@@ -441,6 +442,7 @@ This is the proc mobs get to turn into a ghost. Forked from ghostize due to comp
 
 			if(T && isturf(T))	//Make sure the turf exists, then move the source to that destination.
 				A.loc = T
+				A.update_parallax_contents()
 			else
 				A << "This mob is not located in the game world."
 

code/modules/mob/living/silicon/ai/freelook/chunk.dm

@@ -114,8 +114,8 @@
 		var/turf/t = turf
 		if(obscuredTurfs[t])
 			if(!t.obscured)
-				t.obscured = image('icons/effects/cameravis.dmi', t, null, 16)
-
+				t.obscured = image('icons/effects/cameravis.dmi', t, null, LIGHTING_LAYER+1)
+				t.obscured.plane = LIGHTING_PLANE+1
 			obscured += t.obscured
 			for(var/eye in seenby)
 				var/mob/camera/aiEye/m = eye
@@ -169,7 +169,8 @@
 	for(var/turf in obscuredTurfs)
 		var/turf/t = turf
 		if(!t.obscured)
-			t.obscured = image('icons/effects/cameravis.dmi', t, "black", 16)
+			t.obscured = image('icons/effects/cameravis.dmi', t, null, LIGHTING_LAYER+1)
+			t.obscured.plane = LIGHTING_PLANE+1
 		obscured += t.obscured
 
 #undef UPDATE_BUFFER

code/modules/mob/living/silicon/ai/freelook/eye.dm

@@ -24,6 +24,7 @@
 		cameranet.visibility(src)
 		if(ai.client)
 			ai.client.eye = src
+		update_parallax_contents()
 		//Holopad
 		if(istype(ai.current, /obj/machinery/holopad))
 			var/obj/machinery/holopad/H = ai.current

code/modules/orbit/orbit.dm

@@ -51,8 +51,8 @@
 	if (!targetloc || (!lock && orbiter.loc != lastloc && orbiter.loc != targetloc))
 		orbiter.stop_orbit()
 		return
-
 	orbiter.loc = targetloc
+	orbiter.update_parallax_contents()
 	lastloc = orbiter.loc
 
 

code/modules/shuttle/emergency.dm

@@ -341,9 +341,21 @@
 				launch_status = ENDGAME_LAUNCHED
 				setTimer(SSshuttle.emergencyEscapeTime)
 				priority_announce("The Emergency Shuttle has left the station. Estimate [timeLeft(600)] minutes until the shuttle docks at Central Command.", null, null, "Priority")
+
 		if(SHUTTLE_STRANDED)
 			SSshuttle.checkHostileEnvironment()
+
 		if(SHUTTLE_ESCAPE)
+			if(areaInstance.parallax_movedir && time_left <= PARALLAX_LOOP_TIME)
+				parallax_slowdown()
+				for(var/area/shuttle/escape/E in world)
+					E << 'sound/effects/hyperspace_end.ogg'
+				for(var/A in SSshuttle.mobile)
+					var/obj/docking_port/mobile/M = A
+					if(M.launch_status == ENDGAME_LAUNCHED)
+						if(istype(M, /obj/docking_port/mobile/pod))
+							M.parallax_slowdown()
+
 			if(time_left <= 0)
 				//move each escape pod to its corresponding escape dock
 				for(var/A in SSshuttle.mobile)
@@ -354,9 +366,6 @@
 						else
 							continue //Mapping a new docking point for each ship mappers could potentially want docking with centcomm would take up lots of space, just let them keep flying off into the sunset for their greentext
 
-				for(var/area/shuttle/escape/E in world)
-					E << 'sound/effects/hyperspace_end.ogg'
-
 				// now move the actual emergency shuttle to centcomm
 				// unless the shuttle is "hijacked"
 				var/destination_dock = "emergency_away"
@@ -367,7 +376,6 @@
 						supervisor.", "SYSTEM ERROR:", alert=TRUE)
 
 				dock_id(destination_dock)
-
 				mode = SHUTTLE_ENDGAME
 				timer = 0
 

code/modules/shuttle/on_move.dm

@@ -2,6 +2,8 @@
 	if(rotation)
 		shuttleRotate(rotation)
 	loc = T1
+	if (length(client_mobs_in_contents))
+		update_parallax_contents()
 	return 1
 
 /obj/onShuttleMove()

code/modules/shuttle/shuttle.dm

@@ -162,6 +162,7 @@
 	name = "In Transit"
 	turf_type = /turf/open/space/transit
 	var/list/turf/assigned_turfs = list()
+	var/area/shuttle/transit/assigned_area
 	var/obj/docking_port/mobile/owner
 
 /obj/docking_port/stationary/transit/New()
@@ -458,8 +459,10 @@
 			A0 = new area_type(null)
 		for(var/turf/T0 in L0)
 			A0.contents += T0
-
-
+	if (istype(S1, /obj/docking_port/stationary/transit))
+		areaInstance.parallax_movedir = preferred_direction
+	else
+		areaInstance.parallax_movedir = FALSE
 	remove_ripples()
 
 	//move or squish anything in the way ship at destination
@@ -559,7 +562,7 @@
 
 //used by shuttle subsystem to check timers
 /obj/docking_port/mobile/proc/check()
-	check_ripples()
+	check_effects()
 
 	if(mode == SHUTTLE_IGNITING)
 		check_transit_zone()
@@ -591,12 +594,28 @@
 	timer = 0
 	destination = null
 
-/obj/docking_port/mobile/proc/check_ripples()
+/obj/docking_port/mobile/proc/check_effects()
 	if(!ripples.len)
 		if((mode == SHUTTLE_CALL) || (mode == SHUTTLE_RECALL))
 			if(timeLeft(1) <= SHUTTLE_RIPPLE_TIME)
 				create_ripples(destination)
 
+	var/obj/docking_port/stationary/S0 = get_docked()
+	if(areaInstance.parallax_movedir && istype(S0, /obj/docking_port/stationary/transit) && timeLeft(1) <= PARALLAX_LOOP_TIME)
+		parallax_slowdown()
+
+/obj/docking_port/mobile/proc/parallax_slowdown()
+	areaInstance.parallax_movedir = FALSE
+	if(assigned_transit && assigned_transit.assigned_area)
+		assigned_transit.assigned_area.parallax_movedir = FALSE
+	var/list/L0 = return_ordered_turfs(x, y, z, dir, areaInstance)
+	for (var/thing in L0)
+		var/turf/T = thing
+		for (var/thing2 in T)
+			var/atom/movable/AM = thing2
+			if (length(AM.client_mobs_in_contents))
+				AM.update_parallax_contents()
+
 /obj/docking_port/mobile/proc/check_transit_zone()
 	if(assigned_transit)
 		return TRANSIT_READY

tgstation.dme

@@ -130,6 +130,7 @@
 #include "code\_onclick\hud\monkey.dm"
 #include "code\_onclick\hud\movable_screen_objects.dm"
 #include "code\_onclick\hud\other_mobs.dm"
+#include "code\_onclick\hud\parallax.dm"
 #include "code\_onclick\hud\plane_master.dm"
 #include "code\_onclick\hud\revenanthud.dm"
 #include "code\_onclick\hud\robot.dm"
@@ -160,6 +161,7 @@
 #include "code\controllers\subsystem\npcpool.dm"
 #include "code\controllers\subsystem\orbit.dm"
 #include "code\controllers\subsystem\pai.dm"
+#include "code\controllers\subsystem\parallax.dm"
 #include "code\controllers\subsystem\persistence.dm"
 #include "code\controllers\subsystem\pool.dm"
 #include "code\controllers\subsystem\radio.dm"