Merge branch 'master' of https://github.com/Citadel-Station-13/Citadel-Station-13 into Ghommie-cit265

2019-12-23 05:02:31 +01:00
parent 9db79ff958 e39f9732e0
commit d88f50ac15
168 changed files with 3390 additions and 1416 deletions
@@ -0,0 +1,42 @@
+/datum/component/shrink
+	var/olddens
+	var/oldopac
+	dupe_mode = COMPONENT_DUPE_HIGHLANDER
+
+/datum/component/shrink/Initialize(shrink_time)
+	if(!isatom(parent))
+		return COMPONENT_INCOMPATIBLE
+	var/atom/parent_atom = parent
+	parent_atom.transform = parent_atom.transform.Scale(0.5,0.5)
+	olddens = parent_atom.density
+	oldopac = parent_atom.opacity
+	parent_atom.density = 0
+	parent_atom.opacity = 0
+	if(isliving(parent_atom))
+		var/mob/living/L = parent_atom
+		L.add_movespeed_modifier(MOVESPEED_ID_SHRINK_RAY, update=TRUE, priority=100, multiplicative_slowdown=4)
+		if(iscarbon(L))
+			var/mob/living/carbon/C = L
+			C.unequip_everything()
+			C.visible_message("<span class='warning'>[C]'s belongings fall off of [C.p_them()] as they shrink down!</span>",
+			"<span class='userdanger'>Your belongings fall away as everything grows bigger!</span>")
+			if(ishuman(C))
+				var/mob/living/carbon/human/H = C
+				H.physiology.damage_resistance -= 100//carbons take double damage while shrunk
+	parent_atom.visible_message("<span class='warning'>[parent_atom] shrinks down to a tiny size!</span>",
+	"<span class='userdanger'>Everything grows bigger!</span>")
+	QDEL_IN(src, shrink_time)
+
+
+/datum/component/shrink/Destroy()
+	var/atom/parent_atom = parent
+	parent_atom.transform = parent_atom.transform.Scale(2,2)
+	parent_atom.density = olddens
+	parent_atom.opacity = oldopac
+	if(isliving(parent_atom))
+		var/mob/living/L = parent_atom
+		L.remove_movespeed_modifier(MOVESPEED_ID_SHRINK_RAY)
+		if(ishuman(L))
+			var/mob/living/carbon/human/H = L
+			H.physiology.damage_resistance += 100
+	..()
@@ -0,0 +1,25 @@
+/datum/component/sizzle
+	var/mutable_appearance/sizzling
+	var/sizzlealpha = 0
+	dupe_mode = COMPONENT_DUPE_UNIQUE_PASSARGS
+
+/datum/component/sizzle/Initialize()
+	if(!isatom(parent))
+		return COMPONENT_INCOMPATIBLE
+	setup_sizzle()
+
+/datum/component/sizzle/InheritComponent(datum/component/C, i_am_original)
+	var/atom/food = parent
+	sizzlealpha += 5
+	sizzling.alpha = sizzlealpha
+	food.cut_overlay(sizzling)
+	food.add_overlay(sizzling)
+
+/datum/component/sizzle/proc/setup_sizzle()
+	var/atom/food = parent
+	var/icon/grill_marks = icon(initial(food.icon), initial(food.icon_state))	//we only want to apply grill marks to the initial icon_state for each object
+	grill_marks.Blend("#fff", ICON_ADD) 	//fills the icon_state with white (except where it's transparent)
+	grill_marks.Blend(icon('icons/obj/kitchen.dmi', "grillmarks"), ICON_MULTIPLY) //adds grill marks and the remaining white areas become transparent
+	sizzling = new(grill_marks)
+	sizzling.alpha = sizzlealpha
+	food.add_overlay(sizzling)